File:  [gforth] / gforth / configure.in
Revision 1.145: download - view: text, annotated - select for diffs
Fri Jan 21 09:42:12 2005 UTC (14 years, 8 months ago) by pazsan
Branches: MAIN
CVS tags: HEAD
Added --enable-force-ll switch

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation; either version 2
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program; if not, write to the Free Software
   19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: 
   22: dnl We use some automake macros here,
   23: dnl but don't use automake for creating Makefile.in
   24: AC_INIT([gforth],[0.6.2-20030910],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
   25: AC_PREREQ(2.54)
   26: #snapshots have numbers major.minor.release-YYYYMMDD
   27: #note that lexicographic ordering must be heeded.
   28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   29: UPDATED="September 10, 2003"
   30: AC_SUBST(UPDATED)
   31: AC_CONFIG_HEADERS(engine/config.h)
   32: 
   33: #suppress the "-g -O2" default
   34: test "$CFLAGS" || CFLAGS=-O2
   35: 
   36: AC_ARG_ENABLE(force-reg,
   37: [  --enable-force-reg	  Use explicit register declarations if they appear in
   38: 			  the machine.h file. This can cause a good speedup,
   39: 			  but also incorrect code with some gcc versions on
   40: 			  some processors (default disabled).],
   41: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)]))
   42: AC_ARG_ENABLE(force-ll,
   43: [  --enable-force-ll	  Use explicit long long declarations if they appear in
   44: 			  the machine.h file. This can cause a good speedup,
   45: 			  but also incorrect code with some gcc versions on
   46: 			  some processors (default disabled).],
   47: AC_DEFINE(FORCE_LL,,[Define if you want to use explicit long long declarations for better performance (does not work with all GCC versions on all machines)]))
   48: AC_SUBST(PROFEXES)
   49: AC_SUBST(PROFOBJS)
   50: AC_ARG_ENABLE(prof,
   51: [  --enable-prof          Build gforth-prof, which outputs frequently occuring
   52:                           sequences of primitives.],
   53: PROFEXES="gforth-prof\$(EXE)"; PROFOBJS="engine-prof.o main-prof.o profile.o")
   54: 
   55: AC_ARG_WITH(debug,
   56: [  --with-debug		  specifies option -g to compile with debug info
   57:   --without-debug	  omits the -g switch and creates smaller images on
   58: 			  machines where "strip" has problems with gcc style
   59: 			  debugging informations.],
   60: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   61: 
   62: dnl PEEPHOLE="yes"
   63: dnl AC_ARG_WITH(peephole,
   64: dnl [  --with-peephole	Enable peephole optimization (default)
   65: dnl   --without-peephole	disables peephole optimization. Creates smaller,
   66: dnl 			but slower images.],
   67: dnl PEEPHOLE="$withval")
   68: 
   69: #variables mentioned in INSTALL
   70: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
   71: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
   72: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
   73: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
   74: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
   75: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
   76: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
   77: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
   78: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
   79: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
   80: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
   81: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
   82: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
   83: AC_ARG_VAR(skip_code, [assembly code for skipping 16 bytes of code])
   84: 
   85: #set up feature test macros, so the tests get them right:
   86: # turn on all POSIX, SUSv3, and GNU features if available
   87: AC_GNU_SOURCE
   88: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
   89: 
   90: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
   91: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
   92: dnl but not for _XOPEN_SOURCE)
   93: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
   94: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
   95: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
   96: # turn on large file support with 64-bit off_t where available
   97: AC_SYS_LARGEFILE
   98: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
   99: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
  100: 
  101: #currently we force direct threading this way.  Eventually we should
  102: #setup in the arch and engine files right
  103: 
  104: AC_PROG_CC
  105: 
  106: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
  107: 
  108: AC_SUBST(CC)
  109: AC_SUBST(DEBUGFLAG)
  110: 
  111: AC_MSG_CHECKING(make type)
  112: make_type=`make -v 2>&1|grep 'ake version'|sed 's/ version .*//'`
  113: 
  114: GNUMAKE='#'
  115: test "$make_type" = "GNU Make" && GNUMAKE=''
  116: 
  117: AC_MSG_RESULT($make_type)
  118: 
  119: AC_SUBST(GNUMAKE)
  120: 
  121: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  122: OLDLDFLAGS=$LDFLAGS
  123: LDFLAGS="$LDFLAGS -export-dynamic"
  124: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  125: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  126: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  127: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  128: AC_MSG_RESULT($ac_export_dynamic)
  129: 
  130: #terminology is a bit unusual here: The host is the system on which
  131: #gforth will run; the system on which configure will run is the `build'
  132: AC_CANONICAL_HOST
  133: case "$host_cpu" in
  134: 	arm*)
  135: 		machine=arm
  136: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  137: 		if test -z $no_dynamic_default; then
  138: 		    no_dynamic_default=1
  139: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  140: 		fi
  141: 		;;
  142: 	hppa*)
  143: 		machine=hppa
  144: 		$srcdir/mkinstalldirs arch/hppa
  145: 		AC_LIBOBJ(../arch/hppa/cache)
  146: 		#-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
  147: 		LDFLAGS="$LDFLAGS -Xlinker -N"
  148: 		LIBS="$LIBS -L/lib/pa1.1/"
  149: 		;;
  150: 	sparc*)
  151: 		machine=sparc
  152: 		;;
  153: 	i386)
  154: 		machine=386
  155: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  156: 		;;
  157: 	i486)
  158: 		machine=386
  159: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
  160: 		;;
  161: 	i*86)
  162: 		machine=386
  163: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  164: 		CFLAGS_1="$CFLAGS"
  165: 		CFLAGS="$CFLAGS -march=pentium"
  166: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  167: 		;;
  168: 	x86_64)
  169: 		machine=amd64
  170: 		ac_includes_default="$ac_includes_default
  171: #include \"arch/generic/128bit.h\""
  172: 		;;
  173: 	ia64*)
  174: 		machine=ia64
  175: 		AC_LIBOBJ(../arch/ia64/flush_icache_block)
  176: 		test "$skipcode" || skipcode="nop.i 0"
  177: 		#".skip 16" passes the test below,
  178: 		# but gives an assembler error in engine
  179: 		;;
  180:         m68k)
  181: 		machine=m68k
  182: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  183: 		if test "$host_os" = "nextstep3"
  184: 		then
  185: 			AC_LIBOBJ(termios)
  186: 		fi
  187: 		;;
  188: 	mips*)
  189: 		machine=mips
  190: 		#dynamic native code has the following problems on MIPS:
  191: 		#
  192: 		#1) J/JAL seems relocatable, but is are only
  193: 		#relocatable within a 256MB-segment.  While we try to
  194: 		#get the linker to arrange this, there is no guarantee
  195: 		#that this will succeed (and if the user uses a lot of
  196: 		#memory, it is likely to fail).
  197: 		#
  198: 		#2) The way we generate dynamic native code may
  199: 		#violate MIPS architectural restrictions (in
  200: 		#particular, the delay slots of LW, MFLO, etc.)
  201: 		#
  202: 		#Therefore we disable dynamic native code by default:
  203: 		if test -z $no_dynamic_default; then
  204: 		    no_dynamic_default=1
  205: 		    AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
  206: 		fi
  207: 		;;
  208: 	alpha*)
  209: 		machine=alpha
  210: 		#full IEEE FP support for more uniformity across platforms:
  211: 		CFLAGS="$CFLAGS -mieee"
  212: 		;;
  213: 	power*|rs6000)
  214: 		machine=power
  215: 		$srcdir/mkinstalldirs arch/power
  216: 		AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
  217: 		#long long is broken on (at least) gcc-2.95.* for PPC
  218: 		test x$ac_cv_sizeof_long_long = x && ac_cv_sizeof_long_long=0
  219: 		;;
  220: 	*)
  221: 		AC_MSG_WARN([Using a generic machine description])
  222: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  223: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  224: 		machine=generic
  225: 		#I-cache flushing would be needed for dynamic code generation
  226: 		if test -z $no_dynamic_default; then
  227: 		    no_dynamic_default=1
  228: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  229: 		fi
  230: esac
  231: AC_SUBST(host)
  232: 
  233: dnl the following macro produces a warning with autoconf-2.1
  234: AC_CHECK_SIZEOF(char *)
  235: case "$ac_cv_sizeof_char_p" in
  236:   2)
  237:     wordsize=16
  238:     ;;
  239:   4)
  240:     wordsize=32
  241:     ;;
  242:   8)
  243:     wordsize=64
  244:     ;;
  245: esac
  246: 
  247: AC_CHECK_SIZEOF(char)
  248: AC_CHECK_SIZEOF(short)
  249: AC_CHECK_SIZEOF(int)
  250: AC_CHECK_SIZEOF(long)
  251: AC_CHECK_SIZEOF(long long)
  252: AC_CHECK_SIZEOF(intptr_t)
  253: AC_CHECK_SIZEOF(int128_t)
  254: AC_CHECK_SIZEOF(uint128_t)
  255: 
  256: AC_MSG_CHECKING([for a C type for cells])
  257: ac_cv_int_type_cell=none
  258: case "$ac_cv_sizeof_char_p" in
  259:   $ac_cv_sizeof_int)
  260:     ac_cv_int_type_cell=int
  261:     ;;
  262:   $ac_cv_sizeof_short)
  263:     ac_cv_int_type_cell=short
  264:     ;;
  265:   $ac_cv_sizeof_char)
  266:     ac_cv_int_type_cell=char
  267:     ;;
  268:   $ac_cv_sizeof_long)
  269:     ac_cv_int_type_cell=long
  270:     ;;
  271:   $ac_cv_sizeof_long_long)
  272:     ac_cv_int_type_cell="long long"
  273:     ;;
  274:   $ac_cv_sizeof_intptr_t)
  275:     ac_cv_int_type_cell="intptr_t"
  276:     ;;
  277:   $ac_cv_sizeof_int128_t)
  278:     ac_cv_int_type_cell="int128_t"
  279:     ;;
  280: esac
  281: AC_MSG_RESULT($ac_cv_int_type_cell)
  282: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  283: 
  284: AC_MSG_CHECKING([for a C type for double-cells])
  285: ac_cv_int_type_double_cell=none
  286: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  287:   $ac_cv_sizeof_short)
  288:     ac_cv_int_type_double_cell=short
  289:     ;;
  290:   $ac_cv_sizeof_int)
  291:     ac_cv_int_type_double_cell=int
  292:     ;;
  293:   $ac_cv_sizeof_long)
  294:     ac_cv_int_type_double_cell=long
  295:     ;;
  296:   $ac_cv_sizeof_long_long)
  297:     ac_cv_int_type_double_cell="long long"
  298:     ;;
  299:   $ac_cv_sizeof_intptr_t)
  300:     ac_cv_int_type_double_cell="intptr_t"
  301:     ;;
  302:   $ac_cv_sizeof_int128_t)
  303:     ac_cv_int_type_double_cell="int128_t"
  304:     ;;
  305: esac
  306: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  307: 
  308: AC_MSG_CHECKING([for a C type for unsigned double-cells])
  309: ac_cv_int_type_double_ucell=none
  310: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  311:   $ac_cv_sizeof_short)
  312:     ac_cv_int_type_double_ucell="unsigned short"
  313:     ;;
  314:   $ac_cv_sizeof_int)
  315:     ac_cv_int_type_double_ucell="unsigned int"
  316:     ;;
  317:   $ac_cv_sizeof_long)
  318:     ac_cv_int_type_double_ucell="unsigned long"
  319:     ;;
  320:   $ac_cv_sizeof_long_long)
  321:     ac_cv_int_type_double_ucell="unsigned long long"
  322:     ;;
  323:   $ac_cv_sizeof_intptr_t)
  324:     ac_cv_int_type_double_ucell="unsigned intptr_t"
  325:     ;;
  326:   $ac_cv_sizeof_uint128_t)
  327:     ac_cv_int_type_double_ucell="uint128_t"
  328:     ;;
  329: esac
  330: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
  331: 
  332: if test "$ac_cv_int_type_double_cell" = none || \
  333:    test "$ac_cv_int_type_double_ucell" = none
  334: then
  335: 	AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
  336: 	AC_LIBOBJ(dblsub)
  337: 	AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
  338: else
  339: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  340: 	AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
  341: fi
  342: 
  343: AC_TYPE_OFF_T
  344: AC_CHECK_SIZEOF(off_t)
  345: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
  346: ac_small_off_t=$?
  347: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
  348: 
  349: ENGINE_FLAGS=
  350: AC_SUBST(ENGINE_FLAGS)
  351: 
  352: # Try if GCC understands -fno-gcse
  353: 
  354: AC_MSG_CHECKING([if $CC understands -fno-gcse])
  355: CFLAGS_1="$CFLAGS"
  356: CFLAGS="$CFLAGS -fno-gcse"
  357: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
  358: CFLAGS="$CFLAGS_1"
  359: AC_MSG_RESULT($ac_nogcse)
  360: 
  361: # Try if GCC understands -fno-strict-aliasing
  362: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
  363: CFLAGS_1="$CFLAGS"
  364: CFLAGS="$CFLAGS -fno-strict-aliasing"
  365: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
  366: CFLAGS="$CFLAGS_1"
  367: AC_MSG_RESULT($ac_nostrictaliasing)
  368: 
  369: # Try if GCC understands -fno-crossjumping
  370: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
  371: CFLAGS_1="$CFLAGS"
  372: CFLAGS="$CFLAGS -fno-crossjumping"
  373: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
  374: CFLAGS="$CFLAGS_1"
  375: AC_MSG_RESULT($ac_nocrossjumping)
  376: 
  377: # Try if GCC understands -fno-reorder-blocks
  378: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
  379: CFLAGS_1="$CFLAGS"
  380: CFLAGS="$CFLAGS -fno-reorder-blocks"
  381: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
  382: CFLAGS="$CFLAGS_1"
  383: AC_MSG_RESULT($ac_noreorder_blocks)
  384: 
  385: # Try if GCC understands __attribute__((unused))
  386: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
  387: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
  388: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
  389: AC_MSG_RESULT($MAYBE_UNUSED)
  390: 
  391: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  392: AC_SUBST(asm_fs)
  393: 
  394: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  395: AC_SUBST(disasm_fs)
  396: 
  397: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
  398: 
  399: case "$host_os" in
  400: 	*win32|cygwin)
  401: 		DIRSEP="\\\\"
  402: 		PATHSEP=";"
  403: 		#we want the builtins of command.com/cmd.exe and its
  404: 		# handling of .com files.
  405: 		#$COMSPEC contains the name of the Windows shell;
  406: 		# the ./ is there, because the bash does not recognize
  407: 		# absolute DOS filenames
  408: 		DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
  409: 		;;
  410: 	*darwin*)
  411: 		#Darwin uses some funny preprocessor by default; eliminate it:
  412: 		AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
  413: 		CFLAGS="$CFLAGS -no-cpp-precomp"
  414: 		DIRSEP="/"
  415: 		PATHSEP=":"
  416: 		DEFAULTSYSTEMPREFIX=""
  417: 		;;
  418: 	*)
  419: 		DIRSEP="/"
  420: 		PATHSEP=":"
  421: 		DEFAULTSYSTEMPREFIX=""
  422: 		;;
  423: esac
  424: AC_SUBST(DIRSEP)
  425: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  426: AC_SUBST(PATHSEP)
  427: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  428: AC_SUBST(DEFAULTSYSTEMPREFIX)
  429: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
  430: 
  431: dnl Now a little support for DOS/DJGCC
  432: AC_SUBST(GFORTH_EXE)
  433: GFORTH_EXE=""
  434: AC_SUBST(GFORTHFAST_EXE)
  435: GFORTHFAST_EXE=""
  436: AC_SUBST(GFORTHITC_EXE)
  437: GFORTHITC_EXE=""
  438: AC_SUBST(GFORTHDITC_EXE)
  439: GFORTHDITC_EXE=""
  440: 
  441: AC_SUBST(FORTHSIZES)
  442: 
  443: dnl if test "$PEEPHOLE" = "yes"
  444: dnl then
  445: dnl    PEEPHOLEFLAG="true"
  446: dnl    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  447: dnl else
  448: dnl    PEEPHOLEFLAG="false"
  449: dnl fi
  450: PEEPHOLEFLAG="true"
  451: AC_SUBST(PEEPHOLEFLAG)
  452: 
  453: dnl copy commands for systems that don't have links
  454: AC_SUBST(LINK_KERNL)
  455: LINK_KERNL=""
  456: 
  457: #if test $host_os=dos
  458: #then
  459: #  echo Configuring for DOS!!!
  460: #  MAKE_EXE="coff2exe gforth"
  461: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  462: #fi
  463: 
  464: dnl the following macro produces a warning with autoconf-2.1
  465: AC_C_BIGENDIAN
  466: AC_SUBST(KERNEL)
  467: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  468: if test $ac_cv_c_bigendian = yes; then
  469:   bytesex=b
  470:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  471: else
  472:   bytesex=l
  473:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  474: fi
  475: 
  476: #check how to do asm(".skip 16")
  477: AC_MSG_CHECKING([if and how we can waste code space])
  478: if test -z "$skipcode"; then
  479:     for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  480:     do
  481: 	AC_TRY_RUN(
  482: [int foo(int,int,int);
  483: main()
  484: {
  485:   exit(foo(0,0,0)!=16);
  486: }
  487: int foo(int x, int y, int z)
  488: {
  489:   static void *labels[]={&&label1, &&label2};
  490:   if (x) {
  491:     y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
  492:   label1:
  493:     asm(".skip 16"); /* or ".space 16" or somesuch */
  494:   label2: ;
  495:   }
  496:   {
  497:   if (y) goto *labels[z]; /* workaround for gcc PR12108 */
  498:   return labels[1]-labels[0];
  499:   }
  500: }]
  501: 	,skipcode=$i; break
  502: 	,,)
  503:     done
  504: fi
  505: AC_MSG_RESULT($skipcode)
  506: if test "$skipcode" = no
  507: then 
  508:     if test -z $no_dynamic_default; then
  509: 	no_dynamic_default=1
  510: 	AC_MSG_WARN(Disabling default dynamic native code generation)
  511:     fi
  512:     AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
  513: else
  514:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  515: fi
  516: 
  517: test "$no_dynamic_default" || no_dynamic_default=0
  518: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  519: 
  520: dnl Checks for programs.
  521: AC_PROG_LN_S
  522: AC_PROG_INSTALL
  523: 
  524: dnl Checks for library functions
  525: dnl This check is just for making later checks link with libm.
  526: dnl using sin here is no good idea since it is built-into gcc and typechecked
  527: AC_CHECK_LIB(m,asin)
  528: AC_CHECK_LIB(dl,dlopen)
  529: dnl check for ffcall libraries
  530: dnl unfortunately, these four calls are separated out into a library each.
  531: AC_CHECK_LIB(avcall,__builtin_avcall)
  532: AC_CHECK_LIB(callback,__vacall_r)
  533: AC_CHECK_LIB(vacall,vacall)
  534: AC_CHECK_LIB(trampoline,alloc_trampoline)
  535: FFCALLFLAG="false"
  536: OLDCALLFLAG="true"
  537: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
  538: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
  539: AC_SUBST(FFCALLFLAG)
  540: AC_SUBST(OLDCALLFLAG)
  541: if test "$host_os" != "nextstep3"
  542: then
  543: 	AC_FUNC_MEMCMP
  544: fi
  545: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  546: AC_FUNC_FSEEKO
  547: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
  548: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
  549: AC_DECL_SYS_SIGLIST
  550: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
  551: AC_CHECK_FUNCS(expm1 log1p)
  552: AC_REPLACE_FUNCS(rint ecvt)
  553: dnl No check for select, because our replacement is no good under
  554: dnl anything but DOS
  555: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
  556: AC_FUNC_FNMATCH
  557: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
  558: AC_CHECK_FUNCS(mmap sysconf getpagesize)
  559: AM_PATH_LISPDIR
  560: 
  561: kernel_fi=kernl${wordsize}${bytesex}.fi
  562: AC_SUBST(kernel_fi)
  563: 
  564: #this breaks bindists
  565: #dnl replace srource directory by absolute value
  566: #if test $srcdir = "."; then srcdir=`pwd` 
  567: #fi
  568: 
  569: AC_SUBST(machine)
  570: AC_CONFIG_FILES([
  571: Makefile
  572: Makedist
  573: gforthmi
  574: vmgen
  575: machpc.fs
  576: engine/Makefile
  577: doc/version.texi ])
  578: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
  579: chmod +x gforthmi
  580: chmod +x vmgen
  581: test -d kernel||mkdir kernel]],[[]])
  582: AC_OUTPUT
  583: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>