File:  [gforth] / gforth / configure.in
Revision 1.144: download - view: text, annotated - select for diffs
Mon Jan 17 16:52:46 2005 UTC (14 years, 8 months ago) by pazsan
Branches: MAIN
CVS tags: HEAD
Added expanding mul support for AMD64

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000,2003,2004 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation; either version 2
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program; if not, write to the Free Software
   19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: 
   22: dnl We use some automake macros here,
   23: dnl but don't use automake for creating Makefile.in
   24: AC_INIT([gforth],[0.6.2-20030910],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
   25: AC_PREREQ(2.54)
   26: #snapshots have numbers major.minor.release-YYYYMMDD
   27: #note that lexicographic ordering must be heeded.
   28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   29: UPDATED="September 10, 2003"
   30: AC_SUBST(UPDATED)
   31: AC_CONFIG_HEADERS(engine/config.h)
   32: 
   33: #suppress the "-g -O2" default
   34: test "$CFLAGS" || CFLAGS=-O2
   35: 
   36: AC_ARG_ENABLE(force-reg,
   37: [  --enable-force-reg	  Use explicit register declarations if they appear in
   38: 			  the machine.h file. This can cause a good speedup,
   39: 			  but also incorrect code with some gcc versions on
   40: 			  some processors (default disabled).],
   41: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)]))
   42: AC_SUBST(PROFEXES)
   43: AC_SUBST(PROFOBJS)
   44: AC_ARG_ENABLE(prof,
   45: [  --enable-prof          Build gforth-prof, which outputs frequently occuring
   46:                           sequences of primitives.],
   47: PROFEXES="gforth-prof\$(EXE)"; PROFOBJS="engine-prof.o main-prof.o profile.o")
   48: 
   49: AC_ARG_WITH(debug,
   50: [  --with-debug		  specifies option -g to compile with debug info
   51:   --without-debug	  omits the -g switch and creates smaller images on
   52: 			  machines where "strip" has problems with gcc style
   53: 			  debugging informations.],
   54: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   55: 
   56: dnl PEEPHOLE="yes"
   57: dnl AC_ARG_WITH(peephole,
   58: dnl [  --with-peephole	Enable peephole optimization (default)
   59: dnl   --without-peephole	disables peephole optimization. Creates smaller,
   60: dnl 			but slower images.],
   61: dnl PEEPHOLE="$withval")
   62: 
   63: #variables mentioned in INSTALL
   64: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
   65: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
   66: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
   67: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
   68: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
   69: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
   70: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
   71: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
   72: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
   73: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
   74: AC_ARG_VAR(ac_cv_sizeof_uint128_t, [sizeof(uint128_t)])
   75: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
   76: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
   77: AC_ARG_VAR(skip_code, [assembly code for skipping 16 bytes of code])
   78: 
   79: #set up feature test macros, so the tests get them right:
   80: # turn on all POSIX, SUSv3, and GNU features if available
   81: AC_GNU_SOURCE
   82: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
   83: 
   84: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
   85: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
   86: dnl but not for _XOPEN_SOURCE)
   87: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
   88: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
   89: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
   90: # turn on large file support with 64-bit off_t where available
   91: AC_SYS_LARGEFILE
   92: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
   93: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
   94: 
   95: #currently we force direct threading this way.  Eventually we should
   96: #setup in the arch and engine files right
   97: 
   98: AC_PROG_CC
   99: 
  100: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
  101: 
  102: AC_SUBST(CC)
  103: AC_SUBST(DEBUGFLAG)
  104: 
  105: AC_MSG_CHECKING(make type)
  106: make_type=`make -v 2>&1|grep 'ake version'|sed 's/ version .*//'`
  107: 
  108: GNUMAKE='#'
  109: test "$make_type" = "GNU Make" && GNUMAKE=''
  110: 
  111: AC_MSG_RESULT($make_type)
  112: 
  113: AC_SUBST(GNUMAKE)
  114: 
  115: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  116: OLDLDFLAGS=$LDFLAGS
  117: LDFLAGS="$LDFLAGS -export-dynamic"
  118: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  119: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  120: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  121: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  122: AC_MSG_RESULT($ac_export_dynamic)
  123: 
  124: #terminology is a bit unusual here: The host is the system on which
  125: #gforth will run; the system on which configure will run is the `build'
  126: AC_CANONICAL_HOST
  127: case "$host_cpu" in
  128: 	arm*)
  129: 		machine=arm
  130: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  131: 		if test -z $no_dynamic_default; then
  132: 		    no_dynamic_default=1
  133: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  134: 		fi
  135: 		;;
  136: 	hppa*)
  137: 		machine=hppa
  138: 		$srcdir/mkinstalldirs arch/hppa
  139: 		AC_LIBOBJ(../arch/hppa/cache)
  140: 		#-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
  141: 		LDFLAGS="$LDFLAGS -Xlinker -N"
  142: 		LIBS="$LIBS -L/lib/pa1.1/"
  143: 		;;
  144: 	sparc*)
  145: 		machine=sparc
  146: 		;;
  147: 	i386)
  148: 		machine=386
  149: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  150: 		;;
  151: 	i486)
  152: 		machine=386
  153: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
  154: 		;;
  155: 	i*86)
  156: 		machine=386
  157: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  158: 		CFLAGS_1="$CFLAGS"
  159: 		CFLAGS="$CFLAGS -march=pentium"
  160: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  161: 		;;
  162: 	x86_64)
  163: 		machine=amd64
  164: 		ac_includes_default="$ac_includes_default
  165: #include \"arch/generic/128bit.h\""
  166: 		;;
  167: 	ia64*)
  168: 		machine=ia64
  169: 		AC_LIBOBJ(../arch/ia64/flush_icache_block)
  170: 		test "$skipcode" || skipcode="nop.i 0"
  171: 		#".skip 16" passes the test below,
  172: 		# but gives an assembler error in engine
  173: 		;;
  174:         m68k)
  175: 		machine=m68k
  176: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  177: 		if test "$host_os" = "nextstep3"
  178: 		then
  179: 			AC_LIBOBJ(termios)
  180: 		fi
  181: 		;;
  182: 	mips*)
  183: 		machine=mips
  184: 		#dynamic native code has the following problems on MIPS:
  185: 		#
  186: 		#1) J/JAL seems relocatable, but is are only
  187: 		#relocatable within a 256MB-segment.  While we try to
  188: 		#get the linker to arrange this, there is no guarantee
  189: 		#that this will succeed (and if the user uses a lot of
  190: 		#memory, it is likely to fail).
  191: 		#
  192: 		#2) The way we generate dynamic native code may
  193: 		#violate MIPS architectural restrictions (in
  194: 		#particular, the delay slots of LW, MFLO, etc.)
  195: 		#
  196: 		#Therefore we disable dynamic native code by default:
  197: 		if test -z $no_dynamic_default; then
  198: 		    no_dynamic_default=1
  199: 		    AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
  200: 		fi
  201: 		;;
  202: 	alpha*)
  203: 		machine=alpha
  204: 		#full IEEE FP support for more uniformity across platforms:
  205: 		CFLAGS="$CFLAGS -mieee"
  206: 		;;
  207: 	power*|rs6000)
  208: 		machine=power
  209: 		$srcdir/mkinstalldirs arch/power
  210: 		AC_CHECK_FUNC(_sync_cache_range,[true],[AC_LIBOBJ(../arch/power/_sync_cache_range)])
  211: 		#long long is broken on (at least) gcc-2.95.* for PPC
  212: 		test x$ac_cv_sizeof_long_long = x && ac_cv_sizeof_long_long=0
  213: 		;;
  214: 	*)
  215: 		AC_MSG_WARN([Using a generic machine description])
  216: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  217: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  218: 		machine=generic
  219: 		#I-cache flushing would be needed for dynamic code generation
  220: 		if test -z $no_dynamic_default; then
  221: 		    no_dynamic_default=1
  222: 		    AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
  223: 		fi
  224: esac
  225: AC_SUBST(host)
  226: 
  227: dnl the following macro produces a warning with autoconf-2.1
  228: AC_CHECK_SIZEOF(char *)
  229: case "$ac_cv_sizeof_char_p" in
  230:   2)
  231:     wordsize=16
  232:     ;;
  233:   4)
  234:     wordsize=32
  235:     ;;
  236:   8)
  237:     wordsize=64
  238:     ;;
  239: esac
  240: 
  241: AC_CHECK_SIZEOF(char)
  242: AC_CHECK_SIZEOF(short)
  243: AC_CHECK_SIZEOF(int)
  244: AC_CHECK_SIZEOF(long)
  245: AC_CHECK_SIZEOF(long long)
  246: AC_CHECK_SIZEOF(intptr_t)
  247: AC_CHECK_SIZEOF(int128_t)
  248: AC_CHECK_SIZEOF(uint128_t)
  249: 
  250: AC_MSG_CHECKING([for a C type for cells])
  251: ac_cv_int_type_cell=none
  252: case "$ac_cv_sizeof_char_p" in
  253:   $ac_cv_sizeof_int)
  254:     ac_cv_int_type_cell=int
  255:     ;;
  256:   $ac_cv_sizeof_short)
  257:     ac_cv_int_type_cell=short
  258:     ;;
  259:   $ac_cv_sizeof_char)
  260:     ac_cv_int_type_cell=char
  261:     ;;
  262:   $ac_cv_sizeof_long)
  263:     ac_cv_int_type_cell=long
  264:     ;;
  265:   $ac_cv_sizeof_long_long)
  266:     ac_cv_int_type_cell="long long"
  267:     ;;
  268:   $ac_cv_sizeof_intptr_t)
  269:     ac_cv_int_type_cell="intptr_t"
  270:     ;;
  271:   $ac_cv_sizeof_int128_t)
  272:     ac_cv_int_type_cell="int128_t"
  273:     ;;
  274: esac
  275: AC_MSG_RESULT($ac_cv_int_type_cell)
  276: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  277: 
  278: AC_MSG_CHECKING([for a C type for double-cells])
  279: ac_cv_int_type_double_cell=none
  280: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  281:   $ac_cv_sizeof_short)
  282:     ac_cv_int_type_double_cell=short
  283:     ;;
  284:   $ac_cv_sizeof_int)
  285:     ac_cv_int_type_double_cell=int
  286:     ;;
  287:   $ac_cv_sizeof_long)
  288:     ac_cv_int_type_double_cell=long
  289:     ;;
  290:   $ac_cv_sizeof_long_long)
  291:     ac_cv_int_type_double_cell="long long"
  292:     ;;
  293:   $ac_cv_sizeof_intptr_t)
  294:     ac_cv_int_type_double_cell="intptr_t"
  295:     ;;
  296:   $ac_cv_sizeof_int128_t)
  297:     ac_cv_int_type_double_cell="int128_t"
  298:     ;;
  299: esac
  300: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  301: 
  302: AC_MSG_CHECKING([for a C type for unsigned double-cells])
  303: ac_cv_int_type_double_ucell=none
  304: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  305:   $ac_cv_sizeof_short)
  306:     ac_cv_int_type_double_ucell="unsigned short"
  307:     ;;
  308:   $ac_cv_sizeof_int)
  309:     ac_cv_int_type_double_ucell="unsigned int"
  310:     ;;
  311:   $ac_cv_sizeof_long)
  312:     ac_cv_int_type_double_ucell="unsigned long"
  313:     ;;
  314:   $ac_cv_sizeof_long_long)
  315:     ac_cv_int_type_double_ucell="unsigned long long"
  316:     ;;
  317:   $ac_cv_sizeof_intptr_t)
  318:     ac_cv_int_type_double_ucell="unsigned intptr_t"
  319:     ;;
  320:   $ac_cv_sizeof_uint128_t)
  321:     ac_cv_int_type_double_ucell="uint128_t"
  322:     ;;
  323: esac
  324: AC_MSG_RESULT($ac_cv_int_type_double_ucell)
  325: 
  326: if test "$ac_cv_int_type_double_cell" = none || \
  327:    test "$ac_cv_int_type_double_ucell" = none
  328: then
  329: 	AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
  330: 	AC_LIBOBJ(dblsub)
  331: 	AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
  332: else
  333: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  334: 	AC_DEFINE_UNQUOTED(DOUBLE_UCELL_TYPE,$ac_cv_int_type_double_ucell,[an unsigned integer type that is twice as long as a pointer])
  335: fi
  336: 
  337: AC_TYPE_OFF_T
  338: AC_CHECK_SIZEOF(off_t)
  339: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
  340: ac_small_off_t=$?
  341: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
  342: 
  343: ENGINE_FLAGS=
  344: AC_SUBST(ENGINE_FLAGS)
  345: 
  346: # Try if GCC understands -fno-gcse
  347: 
  348: AC_MSG_CHECKING([if $CC understands -fno-gcse])
  349: CFLAGS_1="$CFLAGS"
  350: CFLAGS="$CFLAGS -fno-gcse"
  351: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
  352: CFLAGS="$CFLAGS_1"
  353: AC_MSG_RESULT($ac_nogcse)
  354: 
  355: # Try if GCC understands -fno-strict-aliasing
  356: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
  357: CFLAGS_1="$CFLAGS"
  358: CFLAGS="$CFLAGS -fno-strict-aliasing"
  359: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
  360: CFLAGS="$CFLAGS_1"
  361: AC_MSG_RESULT($ac_nostrictaliasing)
  362: 
  363: # Try if GCC understands -fno-crossjumping
  364: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
  365: CFLAGS_1="$CFLAGS"
  366: CFLAGS="$CFLAGS -fno-crossjumping"
  367: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
  368: CFLAGS="$CFLAGS_1"
  369: AC_MSG_RESULT($ac_nocrossjumping)
  370: 
  371: # Try if GCC understands -fno-reorder-blocks
  372: AC_MSG_CHECKING([if $CC understands -fno-reorder-blocks])
  373: CFLAGS_1="$CFLAGS"
  374: CFLAGS="$CFLAGS -fno-reorder-blocks"
  375: AC_TRY_COMPILE(,,ac_noreorder_blocks=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-reorder-blocks",ac_noreorder_blocks=no)
  376: CFLAGS="$CFLAGS_1"
  377: AC_MSG_RESULT($ac_noreorder_blocks)
  378: 
  379: # Try if GCC understands __attribute__((unused))
  380: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
  381: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
  382: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
  383: AC_MSG_RESULT($MAYBE_UNUSED)
  384: 
  385: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  386: AC_SUBST(asm_fs)
  387: 
  388: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  389: AC_SUBST(disasm_fs)
  390: 
  391: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
  392: 
  393: case "$host_os" in
  394: 	*win32|cygwin)
  395: 		DIRSEP="\\\\"
  396: 		PATHSEP=";"
  397: 		#we want the builtins of command.com/cmd.exe and its
  398: 		# handling of .com files.
  399: 		#$COMSPEC contains the name of the Windows shell;
  400: 		# the ./ is there, because the bash does not recognize
  401: 		# absolute DOS filenames
  402: 		DEFAULTSYSTEMPREFIX="./$COMSPEC /c "
  403: 		;;
  404: 	*darwin*)
  405: 		#Darwin uses some funny preprocessor by default; eliminate it:
  406: 		AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
  407: 		CFLAGS="$CFLAGS -no-cpp-precomp"
  408: 		DIRSEP="/"
  409: 		PATHSEP=":"
  410: 		DEFAULTSYSTEMPREFIX=""
  411: 		;;
  412: 	*)
  413: 		DIRSEP="/"
  414: 		PATHSEP=":"
  415: 		DEFAULTSYSTEMPREFIX=""
  416: 		;;
  417: esac
  418: AC_SUBST(DIRSEP)
  419: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  420: AC_SUBST(PATHSEP)
  421: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  422: AC_SUBST(DEFAULTSYSTEMPREFIX)
  423: AC_DEFINE_UNQUOTED(DEFAULTSYSTEMPREFIX,"$DEFAULTSYSTEMPREFIX",[default for environment variable GFORTHSYSTEMPREFIX])
  424: 
  425: dnl Now a little support for DOS/DJGCC
  426: AC_SUBST(GFORTH_EXE)
  427: GFORTH_EXE=""
  428: AC_SUBST(GFORTHFAST_EXE)
  429: GFORTHFAST_EXE=""
  430: AC_SUBST(GFORTHITC_EXE)
  431: GFORTHITC_EXE=""
  432: AC_SUBST(GFORTHDITC_EXE)
  433: GFORTHDITC_EXE=""
  434: 
  435: AC_SUBST(FORTHSIZES)
  436: 
  437: dnl if test "$PEEPHOLE" = "yes"
  438: dnl then
  439: dnl    PEEPHOLEFLAG="true"
  440: dnl    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  441: dnl else
  442: dnl    PEEPHOLEFLAG="false"
  443: dnl fi
  444: PEEPHOLEFLAG="true"
  445: AC_SUBST(PEEPHOLEFLAG)
  446: 
  447: dnl copy commands for systems that don't have links
  448: AC_SUBST(LINK_KERNL)
  449: LINK_KERNL=""
  450: 
  451: #if test $host_os=dos
  452: #then
  453: #  echo Configuring for DOS!!!
  454: #  MAKE_EXE="coff2exe gforth"
  455: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  456: #fi
  457: 
  458: dnl the following macro produces a warning with autoconf-2.1
  459: AC_C_BIGENDIAN
  460: AC_SUBST(KERNEL)
  461: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  462: if test $ac_cv_c_bigendian = yes; then
  463:   bytesex=b
  464:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  465: else
  466:   bytesex=l
  467:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  468: fi
  469: 
  470: #check how to do asm(".skip 16")
  471: AC_MSG_CHECKING([if and how we can waste code space])
  472: if test -z "$skipcode"; then
  473:     for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  474:     do
  475: 	AC_TRY_RUN(
  476: [int foo(int,int,int);
  477: main()
  478: {
  479:   exit(foo(0,0,0)!=16);
  480: }
  481: int foo(int x, int y, int z)
  482: {
  483:   static void *labels[]={&&label1, &&label2};
  484:   if (x) {
  485:     y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
  486:   label1:
  487:     asm(".skip 16"); /* or ".space 16" or somesuch */
  488:   label2: ;
  489:   }
  490:   {
  491:   if (y) goto *labels[z]; /* workaround for gcc PR12108 */
  492:   return labels[1]-labels[0];
  493:   }
  494: }]
  495: 	,skipcode=$i; break
  496: 	,,)
  497:     done
  498: fi
  499: AC_MSG_RESULT($skipcode)
  500: if test "$skipcode" = no
  501: then 
  502:     if test -z $no_dynamic_default; then
  503: 	no_dynamic_default=1
  504: 	AC_MSG_WARN(Disabling default dynamic native code generation)
  505:     fi
  506:     AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
  507: else
  508:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  509: fi
  510: 
  511: test "$no_dynamic_default" || no_dynamic_default=0
  512: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  513: 
  514: dnl Checks for programs.
  515: AC_PROG_LN_S
  516: AC_PROG_INSTALL
  517: 
  518: dnl Checks for library functions
  519: dnl This check is just for making later checks link with libm.
  520: dnl using sin here is no good idea since it is built-into gcc and typechecked
  521: AC_CHECK_LIB(m,asin)
  522: AC_CHECK_LIB(dl,dlopen)
  523: dnl check for ffcall libraries
  524: dnl unfortunately, these four calls are separated out into a library each.
  525: AC_CHECK_LIB(avcall,__builtin_avcall)
  526: AC_CHECK_LIB(callback,__vacall_r)
  527: AC_CHECK_LIB(vacall,vacall)
  528: AC_CHECK_LIB(trampoline,alloc_trampoline)
  529: FFCALLFLAG="false"
  530: OLDCALLFLAG="true"
  531: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
  532: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
  533: AC_SUBST(FFCALLFLAG)
  534: AC_SUBST(OLDCALLFLAG)
  535: if test "$host_os" != "nextstep3"
  536: then
  537: 	AC_FUNC_MEMCMP
  538: fi
  539: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  540: AC_FUNC_FSEEKO
  541: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
  542: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
  543: AC_DECL_SYS_SIGLIST
  544: AC_CHECK_FUNC(getopt_long,[true],[AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
  545: AC_CHECK_FUNCS(expm1 log1p)
  546: AC_REPLACE_FUNCS(rint ecvt)
  547: dnl No check for select, because our replacement is no good under
  548: dnl anything but DOS
  549: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
  550: AC_FUNC_FNMATCH
  551: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
  552: AC_CHECK_FUNCS(mmap sysconf getpagesize)
  553: AM_PATH_LISPDIR
  554: 
  555: kernel_fi=kernl${wordsize}${bytesex}.fi
  556: AC_SUBST(kernel_fi)
  557: 
  558: #this breaks bindists
  559: #dnl replace srource directory by absolute value
  560: #if test $srcdir = "."; then srcdir=`pwd` 
  561: #fi
  562: 
  563: AC_SUBST(machine)
  564: AC_CONFIG_FILES([
  565: Makefile
  566: Makedist
  567: gforthmi
  568: vmgen
  569: machpc.fs
  570: engine/Makefile
  571: doc/version.texi ])
  572: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
  573: chmod +x gforthmi
  574: chmod +x vmgen
  575: test -d kernel||mkdir kernel]],[[]])
  576: AC_OUTPUT
  577: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>