1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation; either version 2
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program; if not, write to the Free Software
19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21:
22: dnl We use some automake macros here,
23: dnl but don't use automake for creating Makefile.in
24: AC_INIT([gforth],[0.6.2-20030910],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
25: AC_PREREQ(2.54)
26: #snapshots have numbers major.minor.release-YYYYMMDD
27: #note that lexicographic ordering must be heeded.
28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
29: UPDATED="September 10, 2003"
30: AC_SUBST(UPDATED)
31: AC_CONFIG_HEADERS(engine/config.h)
32:
33: #suppress the "-g -O2" default
34: test "$CFLAGS" || CFLAGS=-O2
35:
36: AC_ARG_ENABLE(force-reg,
37: [ --enable-force-reg Use explicit register declarations if they appear in
38: the machine.h file. This can cause a good speedup,
39: but also incorrect code with some gcc versions on
40: some processors (default disabled).],
41: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)]))
42: AC_SUBST(PROFEXES)
43: AC_SUBST(PROFOBJS)
44: AC_ARG_ENABLE(prof,
45: [ --enable-prof Build gforth-prof, which outputs frequently occuring
46: sequences of primitives.],
47: PROFEXES="gforth-prof\$(EXE)"; PROFOBJS="engine-prof.o main-prof.o profile.o")
48:
49: AC_ARG_WITH(debug,
50: [ --with-debug specifies option -g to compile with debug info
51: --without-debug omits the -g switch and creates smaller images on
52: machines where "strip" has problems with gcc style
53: debugging informations.],
54: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
55:
56: dnl PEEPHOLE="yes"
57: dnl AC_ARG_WITH(peephole,
58: dnl [ --with-peephole Enable peephole optimization (default)
59: dnl --without-peephole disables peephole optimization. Creates smaller,
60: dnl but slower images.],
61: dnl PEEPHOLE="$withval")
62:
63: #variables mentioned in INSTALL
64: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
65: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
66: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
67: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
68: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
69: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
70: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
71: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
72: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
73: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
74: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
75: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
76: AC_ARG_VAR(skip_code, [assembly code for skipping 16 bytes of code])
77:
78: #set up feature test macros, so the tests get them right:
79: # turn on all POSIX, SUSv3, and GNU features if available
80: AC_GNU_SOURCE
81: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
82:
83: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
84: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
85: dnl but not for _XOPEN_SOURCE)
86: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
87: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
88: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
89: # turn on large file support with 64-bit off_t where available
90: AC_SYS_LARGEFILE
91: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
92: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
93:
94: #currently we force direct threading this way. Eventually we should
95: #setup in the arch and engine files right
96:
97: AC_PROG_CC
98:
99: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
100:
101: AC_SUBST(CC)
102: AC_SUBST(DEBUGFLAG)
103:
104: AC_MSG_CHECKING(make type)
105: make_type=`make -v 2>&1|grep 'ake version'|sed 's/ version .*//'`
106:
107: GNUMAKE='#'
108: test "$make_type" = "GNU Make" && GNUMAKE=''
109:
110: AC_MSG_RESULT($make_type)
111:
112: AC_SUBST(GNUMAKE)
113:
114: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
115: OLDLDFLAGS=$LDFLAGS
116: LDFLAGS="$LDFLAGS -export-dynamic"
117: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
118: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
119: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
120: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
121: AC_MSG_RESULT($ac_export_dynamic)
122:
123: #terminology is a bit unusual here: The host is the system on which
124: #gforth will run; the system on which configure will run is the `build'
125: AC_CANONICAL_HOST
126: case "$host_cpu" in
127: arm*)
128: machine=arm
129: CFLAGS="$CFLAGS -fomit-frame-pointer"
130: if test -z $no_dynamic_default; then
131: no_dynamic_default=1
132: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
133: fi
134: ;;
135: hppa*)
136: machine=hppa
137: $srcdir/mkinstalldirs arch/hppa
138: AC_LIBOBJ(../arch/hppa/cache)
139: #-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
140: LDFLAGS="$LDFLAGS -Xlinker -N"
141: LIBS="$LIBS -L/lib/pa1.1/"
142: ;;
143: sparc*)
144: machine=sparc
145: ;;
146: i386)
147: machine=386
148: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
149: ;;
150: i486)
151: machine=386
152: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
153: ;;
154: i*86)
155: machine=386
156: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
157: CFLAGS_1="$CFLAGS"
158: CFLAGS="$CFLAGS -march=pentium"
159: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
160: ;;
161: x86_64)
162: machine=amd64
163: ;;
164: ia64*)
165: machine=ia64
166: AC_LIBOBJ(../arch/ia64/flush_icache_block)
167: test "$skipcode" || skipcode="nop.i 0"
168: #".skip 16" passes the test below,
169: # but gives an assembler error in engine
170: ;;
171: m68k)
172: machine=m68k
173: CFLAGS="$CFLAGS -fomit-frame-pointer"
174: if test "$host_os" = "nextstep3"
175: then
176: AC_LIBOBJ(termios)
177: fi
178: ;;
179: mips*)
180: machine=mips
181: #dynamic native code has the following problems on MIPS:
182: #
183: #1) J/JAL seems relocatable, but is are only
184: #relocatable within a 256MB-segment. While we try to
185: #get the linker to arrange this, there is no guarantee
186: #that this will succeed (and if the user uses a lot of
187: #memory, it is likely to fail).
188: #
189: #2) The way we generate dynamic native code may
190: #violate MIPS architectural restrictions (in
191: #particular, the delay slots of LW, MFLO, etc.)
192: #
193: #Therefore we disable dynamic native code by default:
194: if test -z $no_dynamic_default; then
195: no_dynamic_default=1
196: AC_MSG_WARN([Disabling default dynamic native code generation (relocation and delay slot issues)])
197: fi
198: ;;
199: alpha*)
200: machine=alpha
201: #full IEEE FP support for more uniformity across platforms:
202: CFLAGS="$CFLAGS -mieee"
203: ;;
204: power*|rs6000)
205: machine=power
206: $srcdir/mkinstalldirs arch/power
207: AC_CHECK_FUNC(_sync_cache_range,true,AC_LIBOBJ(../arch/power/_sync_cache_range))
208: #long long is broken on (at least) gcc-2.95.* for PPC
209: test x$ac_cv_sizeof_long_long = x && ac_cv_sizeof_long_long=0
210: ;;
211: *)
212: AC_MSG_WARN([Using a generic machine description])
213: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
214: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
215: machine=generic
216: #I-cache flushing would be needed for dynamic code generation
217: if test -z $no_dynamic_default; then
218: no_dynamic_default=1
219: AC_MSG_WARN([No I-cache flush code known, disabling dynamic native code generation])
220: fi
221: esac
222: AC_SUBST(host)
223:
224: dnl the following macro produces a warning with autoconf-2.1
225: AC_CHECK_SIZEOF(char *)
226: case "$ac_cv_sizeof_char_p" in
227: 2)
228: wordsize=16
229: ;;
230: 4)
231: wordsize=32
232: ;;
233: 8)
234: wordsize=64
235: ;;
236: esac
237:
238: AC_CHECK_SIZEOF(char)
239: AC_CHECK_SIZEOF(short)
240: AC_CHECK_SIZEOF(int)
241: AC_CHECK_SIZEOF(long)
242: AC_CHECK_SIZEOF(long long)
243: AC_CHECK_SIZEOF(intptr_t)
244: AC_CHECK_SIZEOF(int128_t)
245:
246: AC_MSG_CHECKING([for a C type for cells])
247: ac_cv_int_type_cell=none
248: case "$ac_cv_sizeof_char_p" in
249: $ac_cv_sizeof_int)
250: ac_cv_int_type_cell=int
251: ;;
252: $ac_cv_sizeof_short)
253: ac_cv_int_type_cell=short
254: ;;
255: $ac_cv_sizeof_char)
256: ac_cv_int_type_cell=char
257: ;;
258: $ac_cv_sizeof_long)
259: ac_cv_int_type_cell=long
260: ;;
261: $ac_cv_sizeof_long_long)
262: ac_cv_int_type_cell="long long"
263: ;;
264: $ac_cv_sizeof_intptr_t)
265: ac_cv_int_type_cell="intptr_t"
266: ;;
267: $ac_cv_sizeof_int128_t)
268: ac_cv_int_type_cell="int128_t"
269: ;;
270: esac
271: AC_MSG_RESULT($ac_cv_int_type_cell)
272: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
273:
274: AC_MSG_CHECKING([for a C type for double-cells])
275: ac_cv_int_type_double_cell=none
276: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
277: $ac_cv_sizeof_short)
278: ac_cv_int_type_double_cell=short
279: ;;
280: $ac_cv_sizeof_int)
281: ac_cv_int_type_double_cell=int
282: ;;
283: $ac_cv_sizeof_long)
284: ac_cv_int_type_double_cell=long
285: ;;
286: $ac_cv_sizeof_long_long)
287: ac_cv_int_type_double_cell="long long"
288: ;;
289: $ac_cv_sizeof_intptr_t)
290: ac_cv_int_type_double_cell="intptr_t"
291: ;;
292: $ac_cv_sizeof_int128_t)
293: ac_cv_int_type_double_cell="int128_t"
294: ;;
295: esac
296: AC_MSG_RESULT($ac_cv_int_type_double_cell)
297: if test "$ac_cv_int_type_double_cell" = none; then
298: AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
299: AC_LIBOBJ(dblsub)
300: AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
301: else
302: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
303: fi
304:
305: AC_TYPE_OFF_T
306: AC_CHECK_SIZEOF(off_t)
307: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
308: ac_small_off_t=$?
309: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
310:
311: ENGINE_FLAGS=
312: AC_SUBST(ENGINE_FLAGS)
313:
314: # Try if GCC understands -fno-gcse
315:
316: AC_MSG_CHECKING([if $CC understands -fno-gcse])
317: CFLAGS_1="$CFLAGS"
318: CFLAGS="$CFLAGS -fno-gcse"
319: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
320: CFLAGS="$CFLAGS_1"
321: AC_MSG_RESULT($ac_nogcse)
322:
323: # Try if GCC understands -fno-strict-aliasing
324: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
325: CFLAGS_1="$CFLAGS"
326: CFLAGS="$CFLAGS -fno-strict-aliasing"
327: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
328: CFLAGS="$CFLAGS_1"
329: AC_MSG_RESULT($ac_nostrictaliasing)
330:
331: # Try if GCC understands -fno-crossjumping
332: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
333: CFLAGS_1="$CFLAGS"
334: CFLAGS="$CFLAGS -fno-crossjumping"
335: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
336: CFLAGS="$CFLAGS_1"
337: AC_MSG_RESULT($ac_nocrossjumping)
338:
339: # Try if GCC understands __attribute__((unused))
340: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
341: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
342: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
343: AC_MSG_RESULT($MAYBE_UNUSED)
344:
345: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
346: AC_SUBST(asm_fs)
347:
348: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
349: AC_SUBST(disasm_fs)
350:
351: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
352:
353: case "$host_os" in
354: *win32|cygwin)
355: DIRSEP="\\\\"
356: PATHSEP=";"
357: ;;
358: *darwin*)
359: #Darwin uses some funny preprocessor by default; eliminate it:
360: AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
361: CFLAGS="$CFLAGS -no-cpp-precomp"
362: DIRSEP="/"
363: PATHSEP=":"
364: ;;
365: *)
366: DIRSEP="/"
367: PATHSEP=":"
368: ;;
369: esac
370: AC_SUBST(DIRSEP)
371: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
372: AC_SUBST(PATHSEP)
373: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
374:
375:
376: dnl Now a little support for DOS/DJGCC
377: AC_SUBST(GFORTH_EXE)
378: GFORTH_EXE=""
379: AC_SUBST(GFORTHFAST_EXE)
380: GFORTHFAST_EXE=""
381: AC_SUBST(GFORTHITC_EXE)
382: GFORTHITC_EXE=""
383: AC_SUBST(GFORTHDITC_EXE)
384: GFORTHDITC_EXE=""
385:
386: AC_SUBST(FORTHSIZES)
387:
388: dnl if test "$PEEPHOLE" = "yes"
389: dnl then
390: dnl PEEPHOLEFLAG="true"
391: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
392: dnl else
393: dnl PEEPHOLEFLAG="false"
394: dnl fi
395: PEEPHOLEFLAG="true"
396: AC_SUBST(PEEPHOLEFLAG)
397:
398: dnl copy commands for systems that don't have links
399: AC_SUBST(LINK_KERNL)
400: LINK_KERNL=""
401:
402: #if test $host_os=dos
403: #then
404: # echo Configuring for DOS!!!
405: # MAKE_EXE="coff2exe gforth"
406: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
407: #fi
408:
409: dnl the following macro produces a warning with autoconf-2.1
410: AC_C_BIGENDIAN
411: AC_SUBST(KERNEL)
412: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
413: if test $ac_cv_c_bigendian = yes; then
414: bytesex=b
415: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
416: else
417: bytesex=l
418: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
419: fi
420:
421: #check how to do asm(".skip 16")
422: AC_MSG_CHECKING([if and how we can waste code space])
423: if test -z "$skipcode"; then
424: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
425: do
426: AC_TRY_RUN(
427: [int foo(int,int,int);
428: main()
429: {
430: exit(foo(0,0,0)!=16);
431: }
432: int foo(int x, int y, int z)
433: {
434: static void *labels[]={&&label1, &&label2};
435: if (x) {
436: y++; /* workaround for http://gcc.gnu.org/bugzilla/show_bug.cgi?id=12108 */
437: label1:
438: asm(".skip 16"); /* or ".space 16" or somesuch */
439: label2: ;
440: }
441: {
442: if (y) goto *labels[z]; /* workaround for gcc PR12108 */
443: return labels[1]-labels[0];
444: }
445: }]
446: ,skipcode=$i; break
447: ,,)
448: done
449: fi
450: AC_MSG_RESULT($skipcode)
451: if test "$skipcode" = no
452: then
453: if test -z $no_dynamic_default; then
454: no_dynamic_default=1
455: AC_MSG_WARN(Disabling default dynamic native code generation)
456: fi
457: AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
458: else
459: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
460: fi
461:
462: test "$no_dynamic_default" || no_dynamic_default=0
463: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
464:
465: dnl Checks for programs.
466: AC_PROG_LN_S
467: AC_PROG_INSTALL
468:
469: dnl Checks for library functions
470: dnl This check is just for making later checks link with libm.
471: dnl using sin here is no good idea since it is built-into gcc and typechecked
472: AC_CHECK_LIB(m,asin)
473: AC_CHECK_LIB(dl,dlopen)
474: dnl check for ffcall libraries
475: dnl unfortunately, these four calls are separated out into a library each.
476: AC_CHECK_LIB(avcall,__builtin_avcall)
477: AC_CHECK_LIB(callback,__vacall_r)
478: AC_CHECK_LIB(vacall,vacall)
479: AC_CHECK_LIB(trampoline,alloc_trampoline)
480: FFCALLFLAG="false"
481: OLDCALLFLAG="true"
482: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
483: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
484: AC_SUBST(FFCALLFLAG)
485: AC_SUBST(OLDCALLFLAG)
486: if test "$host_os" != "nextstep3"
487: then
488: AC_FUNC_MEMCMP
489: fi
490: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
491: AC_FUNC_FSEEKO
492: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
493: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
494: AC_DECL_SYS_SIGLIST
495: AC_CHECK_FUNC(getopt_long,true,AC_LIBOBJ(getopt); AC_LIBOBJ(getopt1))
496: AC_CHECK_FUNCS(expm1 log1p)
497: AC_REPLACE_FUNCS(rint ecvt)
498: dnl No check for select, because our replacement is no good under
499: dnl anything but DOS
500: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
501: AC_FUNC_FNMATCH
502: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
503: AC_CHECK_FUNCS(mmap sysconf getpagesize)
504: AM_PATH_LISPDIR
505:
506: kernel_fi=kernl${wordsize}${bytesex}.fi
507: AC_SUBST(kernel_fi)
508:
509: #this breaks bindists
510: #dnl replace srource directory by absolute value
511: #if test $srcdir = "."; then srcdir=`pwd`
512: #fi
513:
514: AC_SUBST(machine)
515: AC_CONFIG_FILES([
516: Makefile
517: Makedist
518: gforthmi
519: vmgen
520: machpc.fs
521: engine/Makefile
522: doc/version.texi ])
523: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
524: chmod +x gforthmi
525: chmod +x vmgen
526: test -d kernel||mkdir kernel]],[[]])
527: AC_OUTPUT
528:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>