File:  [gforth] / gforth / configure.in
Revision 1.134: download - view: text, annotated - select for diffs
Mon Sep 8 10:14:19 2003 UTC (20 years, 6 months ago) by anton
Branches: MAIN
CVS tags: HEAD
added support for dynamic code generation on HPPA
some Benchmark results
explicit register allocation for AMD64

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000,2003 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation; either version 2
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program; if not, write to the Free Software
   19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: 
   22: dnl We use some automake macros here,
   23: dnl but don't use automake for creating Makefile.in
   24: AC_INIT([gforth],[0.6.2],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
   25: AC_PREREQ(2.54)
   26: #snapshots have numbers major.minor.release-YYYYMMDD
   27: #note that lexicographic ordering must be heeded.
   28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   29: UPDATED="August 25, 2003"
   30: AC_SUBST(UPDATED)
   31: AC_CONFIG_HEADERS(engine/config.h)
   32: 
   33: #suppress the "-g -O2" default
   34: test "$CFLAGS" || CFLAGS=-O2
   35: 
   36: #default setting that may be changed later:
   37: test "$no_dynamic_default" || no_dynamic_default=0
   38: 
   39: AC_ARG_ENABLE(force-reg,
   40: [  --enable-force-reg	  Use explicit register declarations if they appear in
   41: 			  the machine.h file. This can cause a good speedup,
   42: 			  but also incorrect code with some gcc versions on
   43: 			  some processors (default disabled).],
   44: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)]))
   45: 
   46: AC_ARG_WITH(debug,
   47: [  --with-debug		  specifies option -g to compile with debug info
   48:   --without-debug	  omits the -g switch and creates smaller images on
   49: 			  machines where "strip" has problems with gcc style
   50: 			  debugging informations.],
   51: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   52: 
   53: dnl PEEPHOLE="yes"
   54: dnl AC_ARG_WITH(peephole,
   55: dnl [  --with-peephole	Enable peephole optimization (default)
   56: dnl   --without-peephole	disables peephole optimization. Creates smaller,
   57: dnl 			but slower images.],
   58: dnl PEEPHOLE="$withval")
   59: 
   60: #variables mentioned in INSTALL
   61: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
   62: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
   63: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
   64: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
   65: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
   66: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
   67: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
   68: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
   69: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
   70: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
   71: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
   72: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
   73: 
   74: #set up feature test macros, so the tests get them right:
   75: # turn on all POSIX, SUSv3, and GNU features if available
   76: AC_GNU_SOURCE
   77: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
   78: 
   79: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
   80: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
   81: dnl but not for _XOPEN_SOURCE)
   82: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
   83: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
   84: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
   85: # turn on large file support with 64-bit off_t where available
   86: AC_SYS_LARGEFILE
   87: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
   88: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
   89: 
   90: #currently we force direct threading this way.  Eventually we should
   91: #setup in the arch and engine files right
   92: 
   93: AC_PROG_CC
   94: 
   95: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
   96: 
   97: AC_SUBST(CC)
   98: AC_SUBST(DEBUGFLAG)
   99: 
  100: AC_MSG_CHECKING(make type)
  101: make_type=`make -v 2>&1|grep 'ake version'|sed 's/ version .*//'`
  102: 
  103: GNUMAKE='#'
  104: test "$make_type" = "GNU Make" && GNUMAKE=''
  105: 
  106: AC_MSG_RESULT($make_type)
  107: 
  108: AC_SUBST(GNUMAKE)
  109: 
  110: dnl gcc-3.2 seems to work fine now
  111: dnl AC_MSG_CHECKING(gcc version)
  112: dnl gcc_version=`$CC -v 2>&1|grep 'gcc version'|sed 's/.*gcc version //'`
  113: dnl AC_MSG_RESULT($gcc_version)
  114: dnl if expr "$gcc_version" \> 3.0.4 >/dev/null && expr "$gcc_version" \< 3.2.1 >/dev/null
  115: dnl then
  116: dnl    no_dynamic_default=1
  117: dnl    AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  118: dnl fi
  119: 
  120: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  121: OLDLDFLAGS=$LDFLAGS
  122: LDFLAGS="$LDFLAGS -export-dynamic"
  123: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  124: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  125: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  126: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  127: AC_MSG_RESULT($ac_export_dynamic)
  128: 
  129: #terminology is a bit unusual here: The host is the system on which
  130: #gforth will run; the system on which configure will run is the `build'
  131: AC_CANONICAL_HOST
  132: case "$host_cpu" in
  133: 	hppa*)
  134: 		machine=hppa
  135: 		$srcdir/mkinstalldirs arch/hppa
  136: 		AC_LIBOBJ(../arch/hppa/cache)
  137: 		#-N needed for --dynamic <M4U3b.3790$9d.317@news.cpqcorp.net>
  138: 		LDFLAGS="$LDFLAGS -Xlinker -N"
  139: 		LIBS="$LIBS -L/lib/pa1.1/"
  140: 		;;
  141: 	sparc*)
  142: 		machine=sparc
  143: 		;;
  144: 	i386)
  145: 		machine=386
  146: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  147: 		;;
  148: 	i486)
  149: 		machine=386
  150: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
  151: 		;;
  152: 	i*86)
  153: 		machine=386
  154: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  155: 		CFLAGS_1="$CFLAGS"
  156: 		CFLAGS="$CFLAGS -march=pentium"
  157: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  158: 		;;
  159: 	x86_64)
  160: 		machine=amd64
  161: 		;;
  162: #generic should work for IA64
  163: #	ia64*)
  164: #		machine=ia64
  165: #		;;
  166:         m68k)
  167: 		machine=m68k
  168: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  169: 		if test "$host_os" = "nextstep3"
  170: 		then
  171: 			AC_LIBOBJ(termios)
  172: 		fi
  173: 		;;
  174: 	mips*)
  175: 		machine=mips
  176: 		#dynamic native code has the following problems on MIPS:
  177: 		#
  178: 		#1) J/JAL seems relocatable, but is are only
  179: 		#relocatable within a 256MB-segment.  While we try to
  180: 		#get the linker to arrange this, there is no guarantee
  181: 		#that this will succeed (and if the user uses a lot of
  182: 		#memory, it is likely to fail).
  183: 		#
  184: 		#2) The way we generate dynamic native code may
  185: 		#violate MIPS architectural restrictions (in
  186: 		#particular, the delay slots of LW, MFLO, etc.)
  187: 		#
  188: 		#Therefore we disable dynamic native code by default:
  189: 		no_dynamic_default=1
  190: 		AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  191: 		;;
  192: 	alpha*)
  193: 		machine=alpha
  194: 		#full IEEE FP support for more uniformity across platforms:
  195: 		CFLAGS="$CFLAGS -mieee"
  196: 		;;
  197: 	power*|rs6000)
  198: 		machine=power
  199: 		$srcdir/mkinstalldirs arch/power
  200: 		AC_CHECK_FUNC(_sync_cache_range,true,AC_LIBOBJ(../arch/power/_sync_cache_range))
  201: 		#long long is broken on (at least) gcc-2.95.* for PPC
  202: 		test x$ac_cv_sizeof_long_long = x && ac_cv_sizeof_long_long=0
  203: 		;;
  204: 	*)
  205: 		AC_MSG_WARN([Using a generic machine description])
  206: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  207: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  208: 		machine=generic
  209: 		#I-cache flushing would be needed for dynamic code generation
  210: 		no_dynamic_default=1
  211: 		AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  212: esac
  213: AC_SUBST(host)
  214: 
  215: dnl the following macro produces a warning with autoconf-2.1
  216: AC_CHECK_SIZEOF(char *)
  217: case "$ac_cv_sizeof_char_p" in
  218:   2)
  219:     wordsize=16
  220:     ;;
  221:   4)
  222:     wordsize=32
  223:     ;;
  224:   8)
  225:     wordsize=64
  226:     ;;
  227: esac
  228: 
  229: AC_CHECK_SIZEOF(char)
  230: AC_CHECK_SIZEOF(short)
  231: AC_CHECK_SIZEOF(int)
  232: AC_CHECK_SIZEOF(long)
  233: AC_CHECK_SIZEOF(long long)
  234: AC_CHECK_SIZEOF(intptr_t)
  235: AC_CHECK_SIZEOF(int128_t)
  236: 
  237: AC_MSG_CHECKING([for a C type for cells])
  238: ac_cv_int_type_cell=none
  239: case "$ac_cv_sizeof_char_p" in
  240:   $ac_cv_sizeof_int)
  241:     ac_cv_int_type_cell=int
  242:     ;;
  243:   $ac_cv_sizeof_short)
  244:     ac_cv_int_type_cell=short
  245:     ;;
  246:   $ac_cv_sizeof_char)
  247:     ac_cv_int_type_cell=char
  248:     ;;
  249:   $ac_cv_sizeof_long)
  250:     ac_cv_int_type_cell=long
  251:     ;;
  252:   $ac_cv_sizeof_long_long)
  253:     ac_cv_int_type_cell="long long"
  254:     ;;
  255:   $ac_cv_sizeof_intptr_t)
  256:     ac_cv_int_type_cell="intptr_t"
  257:     ;;
  258:   $ac_cv_sizeof_int128_t)
  259:     ac_cv_int_type_cell="int128_t"
  260:     ;;
  261: esac
  262: AC_MSG_RESULT($ac_cv_int_type_cell)
  263: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  264: 
  265: AC_MSG_CHECKING([for a C type for double-cells])
  266: ac_cv_int_type_double_cell=none
  267: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  268:   $ac_cv_sizeof_short)
  269:     ac_cv_int_type_double_cell=short
  270:     ;;
  271:   $ac_cv_sizeof_int)
  272:     ac_cv_int_type_double_cell=int
  273:     ;;
  274:   $ac_cv_sizeof_long)
  275:     ac_cv_int_type_double_cell=long
  276:     ;;
  277:   $ac_cv_sizeof_long_long)
  278:     ac_cv_int_type_double_cell="long long"
  279:     ;;
  280:   $ac_cv_sizeof_intptr_t)
  281:     ac_cv_int_type_double_cell="intptr_t"
  282:     ;;
  283:   $ac_cv_sizeof_int128_t)
  284:     ac_cv_int_type_double_cell="int128_t"
  285:     ;;
  286: esac
  287: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  288: if test "$ac_cv_int_type_double_cell" = none; then
  289: 	AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
  290: 	AC_LIBOBJ(dblsub)
  291: 	AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
  292: else
  293: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  294: fi
  295: 
  296: AC_TYPE_OFF_T
  297: AC_CHECK_SIZEOF(off_t)
  298: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
  299: ac_small_off_t=$?
  300: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
  301: 
  302: ENGINE_FLAGS=
  303: AC_SUBST(ENGINE_FLAGS)
  304: 
  305: # Try if GCC understands -fno-gcse
  306: 
  307: AC_MSG_CHECKING([if $CC understands -fno-gcse])
  308: CFLAGS_1="$CFLAGS"
  309: CFLAGS="$CFLAGS -fno-gcse"
  310: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
  311: CFLAGS="$CFLAGS_1"
  312: AC_MSG_RESULT($ac_nogcse)
  313: 
  314: # Try if GCC understands -fno-strict-aliasing
  315: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
  316: CFLAGS_1="$CFLAGS"
  317: CFLAGS="$CFLAGS -fno-strict-aliasing"
  318: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
  319: CFLAGS="$CFLAGS_1"
  320: AC_MSG_RESULT($ac_nostrictaliasing)
  321: 
  322: # Try if GCC understands -fno-crossjumping
  323: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
  324: CFLAGS_1="$CFLAGS"
  325: CFLAGS="$CFLAGS -fno-crossjumping"
  326: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
  327: CFLAGS="$CFLAGS_1"
  328: AC_MSG_RESULT($ac_nocrossjumping)
  329: 
  330: # Try if GCC understands __attribute__((unused))
  331: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
  332: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
  333: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
  334: AC_MSG_RESULT($MAYBE_UNUSED)
  335: 
  336: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  337: AC_SUBST(asm_fs)
  338: 
  339: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  340: AC_SUBST(disasm_fs)
  341: 
  342: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
  343: 
  344: case "$host_os" in
  345: 	*win32|cygwin)
  346: 		DIRSEP="\\\\"
  347: 		PATHSEP=";"
  348: 		;;
  349: 	*darwin*)
  350: 		#Darwin uses some funny preprocessor by default; eliminate it:
  351: 		AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
  352: 		CFLAGS="$CFLAGS -no-cpp-precomp"
  353: 		DIRSEP="/"
  354: 		PATHSEP=":"
  355: 		;;
  356: 	*)
  357: 		DIRSEP="/"
  358: 		PATHSEP=":"
  359: 		;;
  360: esac
  361: AC_SUBST(DIRSEP)
  362: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  363: AC_SUBST(PATHSEP)
  364: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  365: 
  366: 
  367: dnl Now a little support for DOS/DJGCC
  368: AC_SUBST(GFORTH_EXE)
  369: GFORTH_EXE=""
  370: AC_SUBST(GFORTHFAST_EXE)
  371: GFORTHFAST_EXE=""
  372: AC_SUBST(GFORTHITC_EXE)
  373: GFORTHITC_EXE=""
  374: AC_SUBST(GFORTHDITC_EXE)
  375: GFORTHDITC_EXE=""
  376: 
  377: AC_SUBST(FORTHSIZES)
  378: 
  379: dnl if test "$PEEPHOLE" = "yes"
  380: dnl then
  381: dnl    PEEPHOLEFLAG="true"
  382: dnl    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  383: dnl else
  384: dnl    PEEPHOLEFLAG="false"
  385: dnl fi
  386: PEEPHOLEFLAG="true"
  387: AC_SUBST(PEEPHOLEFLAG)
  388: 
  389: dnl copy commands for systems that don't have links
  390: AC_SUBST(LINK_KERNL)
  391: LINK_KERNL=""
  392: 
  393: #if test $host_os=dos
  394: #then
  395: #  echo Configuring for DOS!!!
  396: #  MAKE_EXE="coff2exe gforth"
  397: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  398: #fi
  399: 
  400: dnl the following macro produces a warning with autoconf-2.1
  401: AC_C_BIGENDIAN
  402: AC_SUBST(KERNEL)
  403: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  404: if test $ac_cv_c_bigendian = yes; then
  405:   bytesex=b
  406:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  407: else
  408:   bytesex=l
  409:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  410: fi
  411: 
  412: #check how to do asm(".skip 16")
  413: AC_MSG_CHECKING([if and how we can waste code space])
  414: skipcode=no
  415: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  416: do
  417: 	AC_TRY_RUN(
  418: int foo(int);
  419: main()
  420: {
  421:   exit(foo(0)!=16);
  422: }
  423: int foo(int x)
  424: {
  425:   if (x) {
  426:   label1:
  427:     asm("$i");
  428:   label2:
  429:   }
  430:   return (&&label2)-(&&label1);
  431: }
  432: 	,skipcode=$i; break
  433: 	,,)
  434: done	
  435: AC_MSG_RESULT($skipcode)
  436: if test "$skipcode" = no
  437: then 
  438:     no_dynamic_default=1
  439:     AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
  440:     AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  441: else
  442:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  443: fi
  444: 
  445: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  446: 
  447: dnl Checks for programs.
  448: AC_PROG_LN_S
  449: AC_PROG_INSTALL
  450: 
  451: dnl Checks for library functions
  452: dnl This check is just for making later checks link with libm.
  453: dnl using sin here is no good idea since it is built-into gcc and typechecked
  454: AC_CHECK_LIB(m,asin)
  455: AC_CHECK_LIB(dl,dlopen)
  456: dnl check for ffcall libraries
  457: dnl unfortunately, these four calls are separated out into a library each.
  458: AC_CHECK_LIB(avcall,__builtin_avcall)
  459: AC_CHECK_LIB(callback,__vacall_r)
  460: AC_CHECK_LIB(vacall,vacall)
  461: AC_CHECK_LIB(trampoline,alloc_trampoline)
  462: FFCALLFLAG="false"
  463: OLDCALLFLAG="true"
  464: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
  465: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
  466: AC_SUBST(FFCALLFLAG)
  467: AC_SUBST(OLDCALLFLAG)
  468: if test "$host_os" != "nextstep3"
  469: then
  470: 	AC_FUNC_MEMCMP
  471: fi
  472: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  473: AC_FUNC_FSEEKO
  474: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
  475: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
  476: AC_DECL_SYS_SIGLIST
  477: AC_CHECK_FUNC(getopt_long,true,AC_LIBOBJ(getopt); AC_LIBOBJ(getopt1))
  478: AC_CHECK_FUNCS(expm1 log1p)
  479: AC_REPLACE_FUNCS(rint ecvt)
  480: dnl No check for select, because our replacement is no good under
  481: dnl anything but DOS
  482: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
  483: AC_FUNC_FNMATCH
  484: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
  485: AC_CHECK_FUNCS(mmap sysconf getpagesize)
  486: AM_PATH_LISPDIR
  487: 
  488: kernel_fi=kernl${wordsize}${bytesex}.fi
  489: AC_SUBST(kernel_fi)
  490: 
  491: #this breaks bindists
  492: #dnl replace srource directory by absolute value
  493: #if test $srcdir = "."; then srcdir=`pwd` 
  494: #fi
  495: 
  496: AC_SUBST(machine)
  497: AC_CONFIG_FILES([
  498: Makefile
  499: Makedist
  500: gforthmi
  501: vmgen
  502: machpc.fs
  503: engine/Makefile
  504: doc/version.texi ])
  505: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
  506: chmod +x gforthmi
  507: chmod +x vmgen
  508: test -d kernel||mkdir kernel]],[[]])
  509: AC_OUTPUT
  510: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>