File:  [gforth] / gforth / configure.in
Revision 1.127: download - view: text, annotated - select for diffs
Fri Aug 8 05:56:37 2003 UTC (20 years, 7 months ago) by anton
Branches: MAIN
CVS tags: HEAD
fixed Windows PATHSEP bug
Makefile now tolerates ";" as PATHSEP
eliminatd some warnings

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000,2003 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation; either version 2
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program; if not, write to the Free Software
   19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: 
   22: dnl We use some automake macros here,
   23: dnl but don't use automake for creating Makefile.in
   24: AC_INIT([gforth],[0.6.1-20030806],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
   25: AC_PREREQ(2.54)
   26: #snapshots have numbers major.minor.release-YYYYMMDD
   27: #note that lexicographic ordering must be heeded.
   28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   29: UPDATED="August 6, 2003"
   30: AC_SUBST(UPDATED)
   31: AC_CONFIG_HEADERS(engine/config.h)
   32: 
   33: #suppress the "-g -O2" default
   34: test "$CFLAGS" || CFLAGS=-O2
   35: 
   36: #default setting that may be changed later:
   37: test "$no_dynamic_default" || no_dynamic_default=0
   38: 
   39: AC_ARG_ENABLE(force-reg,
   40: [  --enable-force-reg	  Use explicit register declarations if they appear in
   41: 			  the machine.h file. This can cause a good speedup,
   42: 			  but also incorrect code with some gcc versions on
   43: 			  some processors (default disabled).],
   44: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)]))
   45: 
   46: AC_ARG_WITH(debug,
   47: [  --with-debug		  specifies option -g to compile with debug info
   48:   --without-debug	  omits the -g switch and creates smaller images on
   49: 			  machines where "strip" has problems with gcc style
   50: 			  debugging informations.],
   51: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   52: 
   53: dnl PEEPHOLE="yes"
   54: dnl AC_ARG_WITH(peephole,
   55: dnl [  --with-peephole	Enable peephole optimization (default)
   56: dnl   --without-peephole	disables peephole optimization. Creates smaller,
   57: dnl 			but slower images.],
   58: dnl PEEPHOLE="$withval")
   59: 
   60: #variables mentioned in INSTALL
   61: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
   62: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
   63: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
   64: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
   65: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
   66: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
   67: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
   68: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
   69: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
   70: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
   71: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
   72: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
   73: 
   74: #set up feature test macros, so the tests get them right:
   75: # turn on all POSIX, SUSv3, and GNU features if available
   76: AC_GNU_SOURCE
   77: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
   78: 
   79: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
   80: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
   81: dnl but not for _XOPEN_SOURCE)
   82: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
   83: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
   84: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
   85: # turn on large file support with 64-bit off_t where available
   86: AC_SYS_LARGEFILE
   87: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
   88: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
   89: 
   90: #currently we force direct threading this way.  Eventually we should
   91: #setup in the arch and engine files right
   92: 
   93: AC_PROG_CC
   94: 
   95: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
   96: 
   97: AC_SUBST(CC)
   98: AC_SUBST(DEBUGFLAG)
   99: 
  100: dnl gcc-3.2 seems to work fine now
  101: dnl AC_MSG_CHECKING(gcc version)
  102: dnl gcc_version=`$CC -v 2>&1|grep 'gcc version'|sed 's/.*gcc version //'`
  103: dnl AC_MSG_RESULT($gcc_version)
  104: dnl if expr "$gcc_version" \> 3.0.4 >/dev/null && expr "$gcc_version" \< 3.2.1 >/dev/null
  105: dnl then
  106: dnl    no_dynamic_default=1
  107: dnl    AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  108: dnl fi
  109: 
  110: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  111: OLDLDFLAGS=$LDFLAGS
  112: LDFLAGS="$LDFLAGS -export-dynamic"
  113: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  114: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  115: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  116: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  117: AC_MSG_RESULT($ac_export_dynamic)
  118: 
  119: #terminology is a bit unusual here: The host is the system on which
  120: #gforth will run; the system on which configure will run is the `build'
  121: AC_CANONICAL_HOST
  122: case "$host_cpu" in
  123: 	hppa*)
  124: 		machine=hppa
  125: 		$srcdir/mkinstalldirs arch/hppa
  126: 		AC_LIBOBJ(../arch/hppa/cache)
  127: 		#LDFLAGS="$LDFLAGS -Xlinker -N"
  128: 		LIBS="$LIBS -L/lib/pa1.1/"
  129: 		;;
  130: 	sparc*)
  131: 		machine=sparc
  132: 		;;
  133: 	i386)
  134: 		machine=386
  135: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  136: 		;;
  137: 	i486)
  138: 		machine=386
  139: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
  140: 		;;
  141: 	i*86)
  142: 		machine=386
  143: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  144: 		CFLAGS_1="$CFLAGS"
  145: 		CFLAGS="$CFLAGS -march=pentium"
  146: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  147: 		;;
  148: #generic should work for IA64
  149: #	ia64*)
  150: #		machine=ia64
  151: #		;;
  152:         m68k)
  153: 		machine=m68k
  154: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  155: 		if test "$host_os" = "nextstep3"
  156: 		then
  157: 			AC_LIBOBJ(termios)
  158: 		fi
  159: 		;;
  160: 	mips*)
  161: 		machine=mips
  162: 		#dynamic native code has the following problems on MIPS:
  163: 		#
  164: 		#1) J/JAL seems relocatable, but is are only
  165: 		#relocatable within a 256MB-segment.  While we try to
  166: 		#get the linker to arrange this, there is no guarantee
  167: 		#that this will succeed (and if the user uses a lot of
  168: 		#memory, it is likely to fail).
  169: 		#
  170: 		#2) The way we generate dynamic native code may
  171: 		#violate MIPS architectural restrictions (in
  172: 		#particular, the delay slots of LW, MFLO, etc.)
  173: 		#
  174: 		#Therefore we disable dynamic native code by default:
  175: 		no_dynamic_default=1
  176: 		AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  177: 		;;
  178: 	alpha*)
  179: 		machine=alpha
  180: 		#full IEEE FP support for more uniformity across platforms:
  181: 		CFLAGS="$CFLAGS -mieee"
  182: 		;;
  183: 	power*|rs6000)
  184: 		machine=power
  185: 		$srcdir/mkinstalldirs arch/power
  186: 		AC_CHECK_FUNC(_sync_cache_range,true,AC_LIBOBJ(../arch/power/_sync_cache_range))
  187: 		#long long is broken on (at least) gcc-2.95.* for PPC
  188: 		test x$ac_cv_sizeof_long_long = x && ac_cv_sizeof_long_long=0
  189: 		;;
  190: 	*)
  191: 		AC_MSG_WARN([Using a generic machine description])
  192: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  193: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  194: 		machine=generic
  195: 		#I-cache flushing would be needed for dynamic code generation
  196: 		no_dynamic_default=1
  197: 		AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  198: esac
  199: AC_SUBST(host)
  200: 
  201: dnl the following macro produces a warning with autoconf-2.1
  202: AC_CHECK_SIZEOF(char *)
  203: case "$ac_cv_sizeof_char_p" in
  204:   2)
  205:     wordsize=16
  206:     ;;
  207:   4)
  208:     wordsize=32
  209:     ;;
  210:   8)
  211:     wordsize=64
  212:     ;;
  213: esac
  214: 
  215: AC_CHECK_SIZEOF(char)
  216: AC_CHECK_SIZEOF(short)
  217: AC_CHECK_SIZEOF(int)
  218: AC_CHECK_SIZEOF(long)
  219: AC_CHECK_SIZEOF(long long)
  220: AC_CHECK_SIZEOF(intptr_t)
  221: AC_CHECK_SIZEOF(int128_t)
  222: 
  223: AC_MSG_CHECKING([for a C type for cells])
  224: ac_cv_int_type_cell=none
  225: case "$ac_cv_sizeof_char_p" in
  226:   $ac_cv_sizeof_int)
  227:     ac_cv_int_type_cell=int
  228:     ;;
  229:   $ac_cv_sizeof_short)
  230:     ac_cv_int_type_cell=short
  231:     ;;
  232:   $ac_cv_sizeof_char)
  233:     ac_cv_int_type_cell=char
  234:     ;;
  235:   $ac_cv_sizeof_long)
  236:     ac_cv_int_type_cell=long
  237:     ;;
  238:   $ac_cv_sizeof_long_long)
  239:     ac_cv_int_type_cell="long long"
  240:     ;;
  241:   $ac_cv_sizeof_intptr_t)
  242:     ac_cv_int_type_cell="intptr_t"
  243:     ;;
  244:   $ac_cv_sizeof_int128_t)
  245:     ac_cv_int_type_cell="int128_t"
  246:     ;;
  247: esac
  248: AC_MSG_RESULT($ac_cv_int_type_cell)
  249: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  250: 
  251: AC_MSG_CHECKING([for a C type for double-cells])
  252: ac_cv_int_type_double_cell=none
  253: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  254:   $ac_cv_sizeof_short)
  255:     ac_cv_int_type_double_cell=short
  256:     ;;
  257:   $ac_cv_sizeof_int)
  258:     ac_cv_int_type_double_cell=int
  259:     ;;
  260:   $ac_cv_sizeof_long)
  261:     ac_cv_int_type_double_cell=long
  262:     ;;
  263:   $ac_cv_sizeof_long_long)
  264:     ac_cv_int_type_double_cell="long long"
  265:     ;;
  266:   $ac_cv_sizeof_intptr_t)
  267:     ac_cv_int_type_double_cell="intptr_t"
  268:     ;;
  269:   $ac_cv_sizeof_int128_t)
  270:     ac_cv_int_type_double_cell="int128_t"
  271:     ;;
  272: esac
  273: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  274: if test "$ac_cv_int_type_double_cell" = none; then
  275: 	AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
  276: 	AC_LIBOBJ(dblsub)
  277: 	AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
  278: else
  279: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  280: fi
  281: 
  282: AC_TYPE_OFF_T
  283: AC_CHECK_SIZEOF(off_t)
  284: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
  285: ac_small_off_t=$?
  286: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
  287: 
  288: ENGINE_FLAGS=
  289: AC_SUBST(ENGINE_FLAGS)
  290: 
  291: # Try if GCC understands -fno-gcse
  292: 
  293: AC_MSG_CHECKING([if $CC understands -fno-gcse])
  294: CFLAGS_1="$CFLAGS"
  295: CFLAGS="$CFLAGS -fno-gcse"
  296: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
  297: CFLAGS="$CFLAGS_1"
  298: AC_MSG_RESULT($ac_nogcse)
  299: 
  300: # Try if GCC understands -fno-strict-aliasing
  301: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
  302: CFLAGS_1="$CFLAGS"
  303: CFLAGS="$CFLAGS -fno-strict-aliasing"
  304: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
  305: CFLAGS="$CFLAGS_1"
  306: AC_MSG_RESULT($ac_nostrictaliasing)
  307: 
  308: # Try if GCC understands -fno-crossjumping
  309: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
  310: CFLAGS_1="$CFLAGS"
  311: CFLAGS="$CFLAGS -fno-crossjumping"
  312: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
  313: CFLAGS="$CFLAGS_1"
  314: AC_MSG_RESULT($ac_nocrossjumping)
  315: 
  316: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  317: AC_SUBST(asm_fs)
  318: 
  319: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  320: AC_SUBST(disasm_fs)
  321: 
  322: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
  323: 
  324: case "$host_os" in
  325: 	*win32|cygwin)
  326: 		DIRSEP="\\\\"
  327: 		PATHSEP=";"
  328: 		;;
  329: 	*darwin*)
  330: 		#Darwin uses some funny preprocessor by default; eliminate it:
  331: 		AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
  332: 		CFLAGS="$CFLAGS -no-cpp-precomp"
  333: 		DIRSEP="/"
  334: 		PATHSEP=":"
  335: 		;;
  336: 	*)
  337: 		DIRSEP="/"
  338: 		PATHSEP=":"
  339: 		;;
  340: esac
  341: AC_SUBST(DIRSEP)
  342: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  343: AC_SUBST(PATHSEP)
  344: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  345: 
  346: 
  347: dnl Now a little support for DOS/DJGCC
  348: AC_SUBST(GFORTH_EXE)
  349: GFORTH_EXE=""
  350: AC_SUBST(GFORTHFAST_EXE)
  351: GFORTHFAST_EXE=""
  352: AC_SUBST(GFORTHITC_EXE)
  353: GFORTHITC_EXE=""
  354: AC_SUBST(GFORTHDITC_EXE)
  355: GFORTHDITC_EXE=""
  356: 
  357: AC_SUBST(FORTHSIZES)
  358: 
  359: dnl if test "$PEEPHOLE" = "yes"
  360: dnl then
  361: dnl    PEEPHOLEFLAG="true"
  362: dnl    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  363: dnl else
  364: dnl    PEEPHOLEFLAG="false"
  365: dnl fi
  366: PEEPHOLEFLAG="true"
  367: AC_SUBST(PEEPHOLEFLAG)
  368: 
  369: dnl copy commands for systems that don't have links
  370: AC_SUBST(LINK_KERNL)
  371: LINK_KERNL=""
  372: 
  373: #if test $host_os=dos
  374: #then
  375: #  echo Configuring for DOS!!!
  376: #  MAKE_EXE="coff2exe gforth"
  377: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  378: #fi
  379: 
  380: dnl the following macro produces a warning with autoconf-2.1
  381: AC_C_BIGENDIAN
  382: AC_SUBST(KERNEL)
  383: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  384: if test $ac_cv_c_bigendian = yes; then
  385:   bytesex=b
  386:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  387: else
  388:   bytesex=l
  389:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  390: fi
  391: 
  392: #check how to do asm(".skip 16")
  393: AC_MSG_CHECKING([if and how we can waste code space])
  394: skipcode=no
  395: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  396: do
  397: 	AC_TRY_RUN(
  398: int foo(int);
  399: main()
  400: {
  401:   exit(foo(0)!=16);
  402: }
  403: int foo(int x)
  404: {
  405:   if (x) {
  406:   label1:
  407:     asm("$i");
  408:   label2:
  409:   }
  410:   return (&&label2)-(&&label1);
  411: }
  412: 	,skipcode=$i; break
  413: 	,,)
  414: done	
  415: AC_MSG_RESULT($skipcode)
  416: if test "$skipcode" = no
  417: then 
  418:     no_dynamic_default=1
  419:     AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
  420:     AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  421: else
  422:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  423: fi
  424: 
  425: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  426: 
  427: dnl Checks for programs.
  428: AC_PROG_LN_S
  429: AC_PROG_INSTALL
  430: 
  431: dnl Checks for library functions
  432: dnl This check is just for making later checks link with libm.
  433: dnl using sin here is no good idea since it is built-into gcc and typechecked
  434: AC_CHECK_LIB(m,asin)
  435: AC_CHECK_LIB(dl,dlopen)
  436: dnl check for ffcall libraries
  437: dnl unfortunately, these four calls are separated out into a library each.
  438: AC_CHECK_LIB(avcall,__builtin_avcall)
  439: AC_CHECK_LIB(callback,__vacall_r)
  440: AC_CHECK_LIB(vacall,vacall)
  441: AC_CHECK_LIB(trampoline,alloc_trampoline)
  442: FFCALLFLAG="false"
  443: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
  444: AC_SUBST(FFCALLFLAG)
  445: if test "$host_os" != "nextstep3"
  446: then
  447: 	AC_FUNC_MEMCMP
  448: fi
  449: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  450: AC_FUNC_FSEEKO
  451: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
  452: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
  453: AC_DECL_SYS_SIGLIST
  454: AC_CHECK_FUNC(getopt_long,true,AC_LIBOBJ(getopt); AC_LIBOBJ(getopt1))
  455: AC_CHECK_FUNCS(expm1 log1p)
  456: AC_REPLACE_FUNCS(rint ecvt)
  457: dnl No check for select, because our replacement is no good under
  458: dnl anything but DOS
  459: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
  460: AC_FUNC_FNMATCH
  461: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
  462: AC_CHECK_FUNCS(mmap sysconf getpagesize)
  463: AM_PATH_LISPDIR
  464: 
  465: kernel_fi=kernl${wordsize}${bytesex}.fi
  466: AC_SUBST(kernel_fi)
  467: 
  468: #this breaks bindists
  469: #dnl replace srource directory by absolute value
  470: #if test $srcdir = "."; then srcdir=`pwd` 
  471: #fi
  472: 
  473: AC_SUBST(machine)
  474: AC_CONFIG_FILES([
  475: Makefile
  476: Makedist
  477: gforthmi
  478: vmgen
  479: machpc.fs
  480: engine/Makefile
  481: doc/version.texi ])
  482: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
  483: chmod +x gforthmi
  484: chmod +x vmgen
  485: test -d kernel||mkdir kernel]],[[]])
  486: AC_OUTPUT
  487: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>