1: dnl Process this file with autoconf to produce a configure script.
2:
3: #Copyright (C) 1995,1996,1997,1998,2000,2003 Free Software Foundation, Inc.
4:
5: #This file is part of Gforth.
6:
7: #Gforth is free software; you can redistribute it and/or
8: #modify it under the terms of the GNU General Public License
9: #as published by the Free Software Foundation; either version 2
10: #of the License, or (at your option) any later version.
11:
12: #This program is distributed in the hope that it will be useful,
13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
15: #GNU General Public License for more details.
16:
17: #You should have received a copy of the GNU General Public License
18: #along with this program; if not, write to the Free Software
19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21:
22: dnl We use some automake macros here,
23: dnl but don't use automake for creating Makefile.in
24: AC_INIT([gforth],[0.6.1],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
25: AC_PREREQ(2.54)
26: #snapshots have numbers major.minor.release-YYYYMMDD
27: #note that lexicographic ordering must be heeded.
28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
29: UPDATED="March 11, 2003"
30: AC_SUBST(UPDATED)
31: AC_CONFIG_HEADERS(engine/config.h)
32:
33: #suppress the "-g -O2" default
34: test "$CFLAGS" || CFLAGS=-O2
35:
36: #default setting that may be changed later:
37: no_dynamic_default=0
38:
39: AC_ARG_ENABLE(force-reg,
40: [ --enable-force-reg Use explicit register declarations if they appear in
41: the machine.h file. This can cause a good speedup,
42: but also incorrect code with some gcc versions on
43: some processors (default disabled).],
44: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)]))
45:
46: AC_ARG_WITH(debug,
47: [ --with-debug specifies option -g to compile with debug info
48: --without-debug omits the -g switch and creates smaller images on
49: machines where "strip" has problems with gcc style
50: debugging informations.],
51: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
52:
53: AC_ARG_WITH(dynamic,
54: [ --with-dynamic Gforth defaults to dynamic super instructions,
55: --without-dynamic this may cause problems with newer GCCs and global
56: CSE, so if you see troubles, turn it off.],
57: if test "$withval" = "no"; then no_dynamic_default=1; fi)
58:
59: dnl PEEPHOLE="yes"
60: dnl AC_ARG_WITH(peephole,
61: dnl [ --with-peephole Enable peephole optimization (default)
62: dnl --without-peephole disables peephole optimization. Creates smaller,
63: dnl but slower images.],
64: dnl PEEPHOLE="$withval")
65:
66: #variables mentioned in INSTALL
67: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x).])
68: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
69: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
70: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
71: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
72: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
73: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
74: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
75: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
76: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
77: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no)?])
78:
79: #set up feature test macros, so the tests get them right:
80: # turn on all POSIX, SUSv3, and GNU features if available
81: AC_GNU_SOURCE
82: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
83:
84: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
85: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
86: dnl but not for _XOPEN_SOURCE)
87: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
88: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
89: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
90: # turn on large file support with 64-bit off_t where available
91: AC_SYS_LARGEFILE
92: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
93: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
94:
95: #currently we force direct threading this way. Eventually we should
96: #setup in the arch and engine files right
97:
98: AC_PROG_CC
99:
100: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
101:
102: AC_SUBST(CC)
103: AC_SUBST(DEBUGFLAG)
104:
105: dnl gcc-3.2 seems to work fine now
106: dnl AC_MSG_CHECKING(gcc version)
107: dnl gcc_version=`$CC -v 2>&1|grep 'gcc version'|sed 's/.*gcc version //'`
108: dnl AC_MSG_RESULT($gcc_version)
109: dnl if expr "$gcc_version" \> 3.0.4 >/dev/null && expr "$gcc_version" \< 3.2.1 >/dev/null
110: dnl then
111: dnl no_dynamic_default=1
112: dnl AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
113: dnl fi
114:
115: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
116: OLDLDFLAGS=$LDFLAGS
117: LDFLAGS="$LDFLAGS -export-dynamic"
118: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
119: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
120: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
121: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
122: AC_MSG_RESULT($ac_export_dynamic)
123:
124: #terminology is a bit unusual here: The host is the system on which
125: #gforth will run; the system on which configure will run is the `build'
126: AC_CANONICAL_HOST
127: case "$host_cpu" in
128: hppa*)
129: machine=hppa
130: $srcdir/mkinstalldirs arch/hppa
131: AC_LIBOBJ(../arch/hppa/cache)
132: #LDFLAGS="$LDFLAGS -Xlinker -N"
133: LIBS="$LIBS -L/lib/pa1.1/"
134: ;;
135: sparc*)
136: machine=sparc
137: ;;
138: i386)
139: machine=386
140: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
141: ;;
142: i486)
143: machine=386
144: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
145: ;;
146: i*86)
147: machine=386
148: CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
149: CFLAGS_1="$CFLAGS"
150: CFLAGS="$CFLAGS -march=pentium"
151: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
152: ;;
153: #generic should work for IA64
154: # ia64*)
155: # machine=ia64
156: # ;;
157: m68k)
158: machine=m68k
159: CFLAGS="$CFLAGS -fomit-frame-pointer"
160: if test "$host_os" = "nextstep3"
161: then
162: AC_LIBOBJ(termios)
163: fi
164: ;;
165: mips*)
166: machine=mips
167: #dynamic native code has the following problems on MIPS:
168: #
169: #1) J/JAL seems relocatable, but is are only
170: #relocatable within a 256MB-segment. While we try to
171: #get the linker to arrange this, there is no guarantee
172: #that this will succeed (and if the user uses a lot of
173: #memory, it is likely to fail).
174: #
175: #2) The way we generate dynamic native code may
176: #violate MIPS architectural restrictions (in
177: #particular, the delay slots of LW, MFLO, etc.)
178: #
179: #Therefore we disable dynamic native code by default:
180: no_dynamic_default=1
181: AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
182: ;;
183: alpha*)
184: machine=alpha
185: #full IEEE FP support for more uniformity across platforms:
186: CFLAGS="$CFLAGS -mieee"
187: ;;
188: power*|rs6000)
189: machine=power
190: $srcdir/mkinstalldirs arch/power
191: AC_CHECK_FUNC(_sync_cache_range,true,AC_LIBOBJ(../arch/power/_sync_cache_range))
192: #long long is broken on (at least) gcc-2.95.* for PPC
193: test x$ac_cv_sizeof_long_long = x && ac_cv_sizeof_long_long=0
194: ;;
195: *)
196: AC_MSG_WARN([Using a generic machine description])
197: AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
198: AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
199: machine=generic
200: #I-cache flushing would be needed for dynamic code generation
201: no_dynamic_default=1
202: AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
203: esac
204: AC_SUBST(host)
205:
206: dnl the following macro produces a warning with autoconf-2.1
207: AC_CHECK_SIZEOF(char *)
208: case "$ac_cv_sizeof_char_p" in
209: 2)
210: wordsize=16
211: ;;
212: 4)
213: wordsize=32
214: ;;
215: 8)
216: wordsize=64
217: ;;
218: esac
219:
220: AC_CHECK_SIZEOF(char)
221: AC_CHECK_SIZEOF(short)
222: AC_CHECK_SIZEOF(int)
223: AC_CHECK_SIZEOF(long)
224: AC_CHECK_SIZEOF(long long)
225: AC_CHECK_SIZEOF(intptr_t)
226: AC_CHECK_SIZEOF(int128_t)
227:
228: AC_MSG_CHECKING([for a C type for cells])
229: ac_cv_int_type_cell=none
230: case "$ac_cv_sizeof_char_p" in
231: $ac_cv_sizeof_int)
232: ac_cv_int_type_cell=int
233: ;;
234: $ac_cv_sizeof_short)
235: ac_cv_int_type_cell=short
236: ;;
237: $ac_cv_sizeof_char)
238: ac_cv_int_type_cell=char
239: ;;
240: $ac_cv_sizeof_long)
241: ac_cv_int_type_cell=long
242: ;;
243: $ac_cv_sizeof_long_long)
244: ac_cv_int_type_cell="long long"
245: ;;
246: $ac_cv_sizeof_intptr_t)
247: ac_cv_int_type_cell="intptr_t"
248: ;;
249: $ac_cv_sizeof_int128_t)
250: ac_cv_int_type_cell="int128_t"
251: ;;
252: esac
253: AC_MSG_RESULT($ac_cv_int_type_cell)
254: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
255:
256: AC_MSG_CHECKING([for a C type for double-cells])
257: ac_cv_int_type_double_cell=none
258: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
259: $ac_cv_sizeof_short)
260: ac_cv_int_type_double_cell=short
261: ;;
262: $ac_cv_sizeof_int)
263: ac_cv_int_type_double_cell=int
264: ;;
265: $ac_cv_sizeof_long)
266: ac_cv_int_type_double_cell=long
267: ;;
268: $ac_cv_sizeof_long_long)
269: ac_cv_int_type_double_cell="long long"
270: ;;
271: $ac_cv_sizeof_intptr_t)
272: ac_cv_int_type_double_cell="intptr_t"
273: ;;
274: $ac_cv_sizeof_int128_t)
275: ac_cv_int_type_double_cell="int128_t"
276: ;;
277: esac
278: AC_MSG_RESULT($ac_cv_int_type_double_cell)
279: if test "$ac_cv_int_type_double_cell" = none; then
280: AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
281: AC_LIBOBJ(dblsub)
282: AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
283: else
284: AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
285: fi
286:
287: AC_TYPE_OFF_T
288: AC_CHECK_SIZEOF(off_t)
289: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
290: ac_small_off_t=$?
291: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
292:
293: ENGINE_FLAGS=
294: AC_SUBST(ENGINE_FLAGS)
295:
296: # Try if GCC understands -fno-gcse
297:
298: AC_MSG_CHECKING([if $CC understands -fno-gcse])
299: CFLAGS_1="$CFLAGS"
300: CFLAGS="$CFLAGS -fno-gcse"
301: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
302: CFLAGS="$CFLAGS_1"
303: AC_MSG_RESULT($ac_nogcse)
304:
305: # Try if GCC understands -fno-strict-aliasing
306: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
307: CFLAGS_1="$CFLAGS"
308: CFLAGS="$CFLAGS -fno-strict-aliasing"
309: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
310: CFLAGS="$CFLAGS_1"
311: AC_MSG_RESULT($ac_nostrictaliasing)
312:
313: # Try if GCC understands -fno-cross-jump
314: AC_MSG_CHECKING([if $CC understands -fno-cross-jump])
315: CFLAGS_1="$CFLAGS"
316: CFLAGS="$CFLAGS -fno-cross-jump"
317: AC_TRY_COMPILE(,,ac_nocrossjump=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-cross-jump",ac_nocrossjump=no)
318: CFLAGS="$CFLAGS_1"
319: AC_MSG_RESULT($ac_nocrossjump)
320:
321: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
322: AC_SUBST(asm_fs)
323:
324: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
325: AC_SUBST(disasm_fs)
326:
327: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
328:
329: case "$host_os" in
330: *win32|cygwin)
331: DIRSEP="\\\\"
332: ;;
333: *darwin*)
334: #Darwin uses some funny preprocessor by default; eliminate it:
335: AC_MSG_NOTICE([using -traditional-cpp on Darwin])
336: CFLAGS="$CFLAGS -no-cpp-precomp"
337: DIRSEP="/"
338: ;;
339: *)
340: DIRSEP="/"
341: ;;
342: esac
343: AC_SUBST(DIRSEP)
344: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
345:
346: dnl Now a little support for DOS/DJGCC
347: AC_SUBST(GFORTH_EXE)
348: GFORTH_EXE=""
349: AC_SUBST(GFORTHFAST_EXE)
350: GFORTHFAST_EXE=""
351: AC_SUBST(GFORTHITC_EXE)
352: GFORTHITC_EXE=""
353: AC_SUBST(GFORTHDITC_EXE)
354: GFORTHDITC_EXE=""
355:
356: PATHSEP=":"
357: AC_SUBST(PATHSEP)
358: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
359:
360: AC_SUBST(FORTHSIZES)
361:
362: dnl if test "$PEEPHOLE" = "yes"
363: dnl then
364: dnl PEEPHOLEFLAG="true"
365: dnl AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
366: dnl else
367: dnl PEEPHOLEFLAG="false"
368: dnl fi
369: PEEPHOLEFLAG="true"
370: AC_SUBST(PEEPHOLEFLAG)
371:
372: dnl copy commands for systems that don't have links
373: AC_SUBST(LINK_KERNL)
374: LINK_KERNL=""
375:
376: #if test $host_os=dos
377: #then
378: # echo Configuring for DOS!!!
379: # MAKE_EXE="coff2exe gforth"
380: # LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
381: #fi
382:
383: dnl the following macro produces a warning with autoconf-2.1
384: AC_C_BIGENDIAN
385: AC_SUBST(KERNEL)
386: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
387: if test $ac_cv_c_bigendian = yes; then
388: bytesex=b
389: KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
390: else
391: bytesex=l
392: KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
393: fi
394:
395: #check how to do asm(".skip 16")
396: AC_MSG_CHECKING([if and how we can waste code space])
397: skipcode=no
398: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
399: do
400: AC_TRY_RUN(
401: int foo(int);
402: main()
403: {
404: exit(foo(0)!=16);
405: }
406: int foo(int x)
407: {
408: if (x) {
409: label1:
410: asm("$i");
411: label2:
412: }
413: return (&&label2)-(&&label1);
414: }
415: ,skipcode=$i; break
416: ,,)
417: done
418: AC_MSG_RESULT($skipcode)
419: if test "$skipcode" = no
420: then
421: no_dynamic_default=1
422: AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
423: AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
424: else
425: AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
426: fi
427:
428: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
429:
430: dnl Checks for programs.
431: AC_PROG_LN_S
432: AC_PROG_INSTALL
433:
434: dnl Checks for library functions
435: dnl This check is just for making later checks link with libm.
436: dnl using sin here is no good idea since it is built-into gcc and typechecked
437: AC_CHECK_LIB(m,asin)
438: AC_CHECK_LIB(dl,dlopen)
439: if test "$host_os" != "nextstep3"
440: then
441: AC_FUNC_MEMCMP
442: fi
443: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
444: AC_FUNC_FSEEKO
445: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
446: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
447: AC_DECL_SYS_SIGLIST
448: AC_CHECK_FUNC(getopt_long,true,AC_LIBOBJ(getopt); AC_LIBOBJ(getopt1))
449: AC_CHECK_FUNCS(expm1 log1p)
450: AC_REPLACE_FUNCS(rint ecvt)
451: dnl No check for select, because our replacement is no good under
452: dnl anything but DOS
453: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
454: AC_FUNC_FNMATCH
455: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
456: AC_CHECK_FUNCS(mmap sysconf getpagesize)
457: AM_PATH_LISPDIR
458:
459: kernel_fi=kernl${wordsize}${bytesex}.fi
460: AC_SUBST(kernel_fi)
461:
462: #this breaks bindists
463: #dnl replace srource directory by absolute value
464: #if test $srcdir = "."; then srcdir=`pwd`
465: #fi
466:
467: AC_SUBST(machine)
468: AC_CONFIG_FILES([
469: Makefile
470: Makedist
471: gforthmi
472: vmgen
473: machpc.fs
474: engine/Makefile
475: doc/version.texi ])
476: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
477: chmod +x gforthmi
478: chmod +x vmgen
479: test -d kernel||mkdir kernel]],[[]])
480: AC_OUTPUT
481:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>