File:  [gforth] / gforth / configure.in
Revision 1.108: download - view: text, annotated - select for diffs
Mon Jan 27 22:00:10 2003 UTC (21 years, 1 month ago) by anton
Branches: MAIN
CVS tags: HEAD
some changes for cygwin

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation; either version 2
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program; if not, write to the Free Software
   19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: dnl We use some automake macros here,
   22: dnl but don't use automake for creating Makefile.in
   23: AC_INIT([gforth],[0.5.9-20030127],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
   24: #snapshots have numbers major.minor.release-YYYYMMDD
   25: #note that lexicographic ordering must be heeded.
   26: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   27: UPDATED="27 January 2003"
   28: AC_SUBST(UPDATED)
   29: AC_CONFIG_HEADERS(engine/config.h)
   30: 
   31: #default setting that may be changed later:
   32: no_dynamic_default=0
   33: 
   34: AC_ARG_ENABLE(force-reg,
   35: [  --enable-force-reg	  Use explicit register declarations if they appear in
   36: 			  the machine.h file. This can cause a good speedup,
   37: 			  but also incorrect code with some gcc versions on
   38: 			  some processors (default disabled).],
   39: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)]))
   40: 
   41: AC_ARG_WITH(debug,
   42: [  --with-debug     specifies option -g to compile with debug info (default)
   43:   --without-debug  omits the -g switch and creates smaller images on
   44:                    machines where "strip" has problems with gcc style
   45:                    debugging informations.],
   46: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   47: 
   48: dnl PEEPHOLE="yes"
   49: dnl AC_ARG_WITH(peephole,
   50: dnl [  --with-peephole	Enable peephole optimization (default)
   51: dnl   --without-peephole	disables peephole optimization. Creates smaller,
   52: dnl 			but slower images.],
   53: dnl PEEPHOLE="$withval")
   54: 
   55: #variables mentioned in INSTALL
   56: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x).])
   57: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
   58: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
   59: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
   60: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
   61: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
   62: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
   63: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
   64: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
   65: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
   66: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no)?])
   67: 
   68: #set up feature test macros, so the tests get them right:
   69: # turn on all POSIX, SUSv3, and GNU features if available
   70: AC_GNU_SOURCE
   71: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
   72: 
   73: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
   74: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
   75: dnl but not for _XOPEN_SOURCE)
   76: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
   77: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
   78: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
   79: # turn on large file support with 64-bit off_t where available
   80: AC_SYS_LARGEFILE
   81: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
   82: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
   83: 
   84: #currently we force direct threading this way.  Eventually we should
   85: #setup in the arch and engine files right
   86: 
   87: CFLAGS=$CFLAGS
   88: 
   89: AC_PROG_CC
   90: 
   91: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
   92: 
   93: AC_SUBST(CC)
   94: AC_SUBST(DEBUGFLAG)
   95: 
   96: dnl gcc-3.2 seems to work fine now
   97: dnl AC_MSG_CHECKING(gcc version)
   98: dnl gcc_version=`$CC -v 2>&1|grep 'gcc version'|sed 's/.*gcc version //'`
   99: dnl AC_MSG_RESULT($gcc_version)
  100: dnl if expr "$gcc_version" \> 3.0.4 >/dev/null && expr "$gcc_version" \< 3.2.1 >/dev/null
  101: dnl then
  102: dnl    no_dynamic_default=1
  103: dnl    AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  104: dnl fi
  105: 
  106: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  107: OLDLDFLAGS=$LDFLAGS
  108: LDFLAGS="$LDFLAGS -export-dynamic"
  109: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  110: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  111: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  112: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  113: AC_MSG_RESULT($ac_export_dynamic)
  114: 
  115: #terminology is a bit unusual here: The host is the system on which
  116: #gforth will run; the system on which configure will run is the `build'
  117: AC_CANONICAL_HOST
  118: case "$host_cpu" in
  119: 	hppa*)
  120: 		machine=hppa
  121: 		$srcdir/mkinstalldirs arch/hppa
  122: 		AC_LIBOBJ(../arch/hppa/cache)
  123: 		LDFLAGS="$LDFLAGS -Xlinker -N"
  124: 		LIBS="$LIBS -L/lib/pa1.1/"
  125: 		;;
  126: 	sparc*)
  127: 		machine=sparc
  128: 		;;
  129: 	i386)
  130: 		machine=386
  131: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  132: 		;;
  133: 	i486)
  134: 		machine=386
  135: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
  136: 		;;
  137: 	i*86)
  138: 		machine=386
  139: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  140: 		CFLAGS_1="$CFLAGS"
  141: 		CFLAGS="$CFLAGS -march=pentium"
  142: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  143: 		;;
  144: #generic should work for IA64
  145: #	ia64*)
  146: #		machine=ia64
  147: #		;;
  148:         m68k)
  149: 		machine=m68k
  150: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  151: 		if test "$host_os" = "nextstep3"
  152: 		then
  153: 			AC_LIBOBJ(termios)
  154: 		fi
  155: 		;;
  156: 	mips*)
  157: 		machine=mips
  158: 		#dynamic native code has the following problems on MIPS:
  159: 		#
  160: 		#1) J/JAL seems relocatable, but is are only
  161: 		#relocatable within a 256MB-segment.  While we try to
  162: 		#get the linker to arrange this, there is no guarantee
  163: 		#that this will succeed (and if the user uses a lot of
  164: 		#memory, it is likely to fail).
  165: 		#
  166: 		#2) The way we generate dynamic native code may
  167: 		#violate MIPS architectural restrictions (in
  168: 		#particular, the delay slots of LW, MFLO, etc.)
  169: 		#
  170: 		#Therefore we disable dynamic native code by default:
  171: 		no_dynamic_default=1
  172: 		AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  173: 		;;
  174: 	alpha*)
  175: 		machine=alpha
  176: 		#full IEEE FP support for more uniformity across platforms:
  177: 		CFLAGS="$CFLAGS -mieee"
  178: 		;;
  179: 	power*|rs6000)
  180: 		machine=power
  181: 		$srcdir/mkinstalldirs arch/power
  182: 		AC_CHECK_FUNC(_sync_cache_range,true,AC_LIBOBJ(../arch/power/_sync_cache_range))
  183: 		#long long is broken on (at least) gcc-2.95.* for PPC
  184: 		test x$ac_cv_sizeof_long_long = x && ac_cv_sizeof_long_long=0
  185: 		;;
  186: 	*)
  187: 		AC_MSG_WARN([Using a generic machine description])
  188: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  189: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  190: 		machine=generic
  191: 		#I-cache flushing would be needed for dynamic code generation
  192: 		no_dynamic_default=1
  193: 		AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  194: esac
  195: AC_SUBST(host)
  196: AC_SUBST(ENGINE_FLAGS)
  197: 
  198: dnl the following macro produces a warning with autoconf-2.1
  199: AC_CHECK_SIZEOF(char *)
  200: case "$ac_cv_sizeof_char_p" in
  201:   2)
  202:     wordsize=16
  203:     ;;
  204:   4)
  205:     wordsize=32
  206:     ;;
  207:   8)
  208:     wordsize=64
  209:     ;;
  210: esac
  211: 
  212: AC_CHECK_SIZEOF(char)
  213: AC_CHECK_SIZEOF(short)
  214: AC_CHECK_SIZEOF(int)
  215: AC_CHECK_SIZEOF(long)
  216: AC_CHECK_SIZEOF(long long)
  217: AC_CHECK_SIZEOF(intptr_t)
  218: AC_CHECK_SIZEOF(int128_t)
  219: 
  220: AC_MSG_CHECKING([for a C type for cells])
  221: ac_cv_int_type_cell=none
  222: case "$ac_cv_sizeof_char_p" in
  223:   $ac_cv_sizeof_int)
  224:     ac_cv_int_type_cell=int
  225:     ;;
  226:   $ac_cv_sizeof_short)
  227:     ac_cv_int_type_cell=short
  228:     ;;
  229:   $ac_cv_sizeof_char)
  230:     ac_cv_int_type_cell=char
  231:     ;;
  232:   $ac_cv_sizeof_long)
  233:     ac_cv_int_type_cell=long
  234:     ;;
  235:   $ac_cv_sizeof_long_long)
  236:     ac_cv_int_type_cell="long long"
  237:     ;;
  238:   $ac_cv_sizeof_intptr_t)
  239:     ac_cv_int_type_cell="intptr_t"
  240:     ;;
  241:   $ac_cv_sizeof_int128_t)
  242:     ac_cv_int_type_cell="int128_t"
  243:     ;;
  244: esac
  245: AC_MSG_RESULT($ac_cv_int_type_cell)
  246: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  247: 
  248: AC_MSG_CHECKING([for a C type for double-cells])
  249: ac_cv_int_type_double_cell=none
  250: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  251:   $ac_cv_sizeof_short)
  252:     ac_cv_int_type_double_cell=short
  253:     ;;
  254:   $ac_cv_sizeof_int)
  255:     ac_cv_int_type_double_cell=int
  256:     ;;
  257:   $ac_cv_sizeof_long)
  258:     ac_cv_int_type_double_cell=long
  259:     ;;
  260:   $ac_cv_sizeof_long_long)
  261:     ac_cv_int_type_double_cell="long long"
  262:     ;;
  263:   $ac_cv_sizeof_intptr_t)
  264:     ac_cv_int_type_double_cell="intptr_t"
  265:     ;;
  266:   $ac_cv_sizeof_int128_t)
  267:     ac_cv_int_type_double_cell="int128_t"
  268:     ;;
  269: esac
  270: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  271: if test "$ac_cv_int_type_double_cell" = none; then
  272: 	AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
  273: 	AC_LIBOBJ(dblsub)
  274: 	AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
  275: else
  276: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  277: fi
  278: 
  279: AC_TYPE_OFF_T
  280: AC_CHECK_SIZEOF(off_t)
  281: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
  282: ac_small_off_t=$?
  283: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
  284: 
  285: # Try if GCC understands -fno-cross-jump
  286: 
  287: CFLAGS_1="$CFLAGS"
  288: CFLAGS="$CFLAGS -fno-cross-jump"
  289: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1")
  290: 
  291: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  292: AC_SUBST(asm_fs)
  293: 
  294: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  295: AC_SUBST(disasm_fs)
  296: 
  297: case "$host_os" in
  298: 	*win32|cygwin)
  299: 		DIRSEP="\\\\"
  300: 		;;
  301: 	*darwin*)
  302: 		#Darwin uses some funny preprocessor by default; eliminate it:
  303: 		AC_MSG_NOTICE([using -traditional-cpp on Darwin])
  304: 		CFLAGS="$CFLAGS -traditional-cpp"
  305: 		DIRSEP="/"
  306: 		;;
  307: 	*)
  308: 		DIRSEP="/"
  309: 		;;
  310: esac
  311: AC_SUBST(DIRSEP)
  312: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  313: 
  314: dnl Now a little support for DOS/DJGCC
  315: AC_SUBST(GFORTH_EXE)
  316: GFORTH_EXE=""
  317: AC_SUBST(GFORTHFAST_EXE)
  318: GFORTHFAST_EXE=""
  319: AC_SUBST(GFORTHITC_EXE)
  320: GFORTHITC_EXE=""
  321: AC_SUBST(GFORTHDITC_EXE)
  322: GFORTHDITC_EXE=""
  323: 
  324: PATHSEP=":"
  325: AC_SUBST(PATHSEP)
  326: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  327: 
  328: AC_SUBST(FORTHSIZES)
  329: 
  330: dnl if test "$PEEPHOLE" = "yes"
  331: dnl then
  332: dnl    PEEPHOLEFLAG="true"
  333: dnl    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  334: dnl else
  335: dnl    PEEPHOLEFLAG="false"
  336: dnl fi
  337: PEEPHOLEFLAG="true"
  338: AC_SUBST(PEEPHOLEFLAG)
  339: 
  340: dnl copy commands for systems that don't have links
  341: AC_SUBST(LINK_KERNL)
  342: LINK_KERNL=""
  343: 
  344: #if test $host_os=dos
  345: #then
  346: #  echo Configuring for DOS!!!
  347: #  MAKE_EXE="coff2exe gforth"
  348: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  349: #fi
  350: 
  351: dnl the following macro produces a warning with autoconf-2.1
  352: AC_C_BIGENDIAN
  353: AC_SUBST(KERNEL)
  354: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  355: if test $ac_cv_c_bigendian = yes; then
  356:   bytesex=b
  357:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  358: else
  359:   bytesex=l
  360:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  361: fi
  362: 
  363: #check how to do asm(".skip 16")
  364: AC_MSG_CHECKING([if and how we can waste code space])
  365: skipcode=no
  366: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  367: do
  368: 	AC_TRY_RUN(
  369: int foo(int);
  370: main()
  371: {
  372:   exit(foo(0)!=16);
  373: }
  374: int foo(int x)
  375: {
  376:   if (x) {
  377:   label1:
  378:     asm("$i");
  379:   label2:
  380:   }
  381:   return (&&label2)-(&&label1);
  382: }
  383: 	,skipcode=$i; break
  384: 	,,)
  385: done	
  386: AC_MSG_RESULT($skipcode)
  387: if test "$skipcode" = no
  388: then 
  389:     no_dynamic_default=1
  390:     AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
  391:     AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  392: else
  393:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  394: fi
  395: 
  396: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  397: 
  398: dnl Checks for programs.
  399: AC_PROG_LN_S
  400: AC_PROG_INSTALL
  401: 
  402: dnl Checks for library functions
  403: dnl This check is just for making later checks link with libm.
  404: dnl using sin here is no good idea since it is built-into gcc and typechecked
  405: AC_CHECK_LIB(m,asin)
  406: AC_CHECK_LIB(dl,dlopen)
  407: if test "$host_os" != "nextstep3"
  408: then
  409: 	AC_FUNC_MEMCMP
  410: fi
  411: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  412: AC_FUNC_FSEEKO
  413: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
  414: AC_CHECK_TYPES(stack_t)
  415: AC_DECL_SYS_SIGLIST
  416: AC_CHECK_FUNC(getopt_long,true,AC_LIBOBJ(getopt); AC_LIBOBJ(getopt1))
  417: AC_CHECK_FUNCS(expm1 log1p)
  418: AC_REPLACE_FUNCS(rint ecvt)
  419: dnl No check for select, because our replacement is no good under
  420: dnl anything but DOS
  421: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
  422: AC_FUNC_FNMATCH
  423: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
  424: AC_CHECK_FUNCS(mmap sysconf getpagesize)
  425: AM_PATH_LISPDIR
  426: 
  427: kernel_fi=kernl${wordsize}${bytesex}.fi
  428: AC_SUBST(kernel_fi)
  429: 
  430: #this breaks bindists
  431: #dnl replace srource directory by absolute value
  432: #if test $srcdir = "."; then srcdir=`pwd` 
  433: #fi
  434: 
  435: AC_SUBST(machine)
  436: AC_CONFIG_FILES([
  437: Makefile
  438: Makedist
  439: gforthmi
  440: vmgen
  441: machpc.fs
  442: engine/Makefile
  443: doc/version.texi ])
  444: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
  445: chmod +x gforthmi
  446: chmod +x vmgen
  447: test -d kernel||mkdir kernel]],[[]])
  448: AC_OUTPUT
  449: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>