File:  [gforth] / gforth / configure.in
Revision 1.67: download - view: text, annotated - select for diffs
Thu Jul 20 13:29:43 2000 UTC (19 years, 4 months ago) by anton
Branches: MAIN
CVS tags: HEAD
signal handling bugfix (not yet portability tested)

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation; either version 2
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program; if not, write to the Free Software
   19: #Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
   20: 
   21: AC_INIT(engine/engine.c)
   22: 
   23: dnl We use some automake macros here,
   24: dnl but don't use automake for creating Makefile.in
   25: AM_INIT_AUTOMAKE(gforth,0.4.9-20000720)
   26: #snapshots have numbers major.minor.release-YYYYMMDD
   27: #note that lexicographic ordering bust be heeded.
   28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   29: AM_CONFIG_HEADER(engine/config.h)
   30: #AM_CYGWIN32
   31: 
   32: AC_ARG_ENABLE(force-reg,
   33: [  --enable-force-reg	  Use explicit register declarations if they appear in
   34: 			  the machine.h file. This can cause a good speedup,
   35: 			  but also incorrect code with some gcc versions on
   36: 			  some processors (default disabled).],
   37: 
   38: AC_DEFINE(FORCE_REG))
   39: dnl this is not quite according to the autoconf manual, it causes a replacement
   40: AC_ARG_ENABLE(direct-threaded,
   41: [  --enable-direct-threaded	Force direct threading. This may not work on
   42: 				some machines and may cause slowdown on others.
   43: 				(default processor-dependent)],
   44: AC_DEFINE(DIRECT_THREADED))
   45: AC_ARG_ENABLE(indirect-threaded,
   46: [  --enable-indirect-threaded	Force indirect threading. This can cause a
   47: 				slowdown on some machines.
   48: 				(default processor-dependent)],
   49: AC_DEFINE(INDIRECT_THREADED))
   50: 
   51: AC_ARG_WITH(debug,
   52: [  --with-debug     specifies option -g to compile with debug info (default)
   53:   --without-debug  omits the -g switch and creates smaller images on
   54:                    machines where "strip" has problems with gcc style
   55:                    debugging informations.],
   56: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   57: 
   58: CFLAGS=$CFLAGS
   59: 
   60: AC_PROG_CC
   61: 
   62: if test "$GCC" = "yes"
   63: then
   64:    echo "Fine, gcc is available"
   65: else
   66:    cat <<'EOF'
   67: Gforth requires GCC-2.0 or higher (it uses GNU C extensions).
   68: It does not work with other C compilers. Please install the GNU C compiler,
   69: and try again (or search for a binary distribution for your platform).
   70: EOF
   71:    exit 1
   72: fi
   73: 
   74: AC_SUBST(CC)
   75: AC_SUBST(DEBUGFLAG)
   76: 
   77: dnl the following macro produces a warning with autoconf-2.1
   78: AC_CHECK_SIZEOF(char *)
   79: case "$ac_cv_sizeof_char_p" in
   80:   2)
   81:     wordsize=16
   82:     ;;
   83:   4)
   84:     wordsize=32
   85:     ;;
   86:   8)
   87:     wordsize=64
   88:     ;;
   89: esac
   90: 
   91: AC_CHECK_SIZEOF(char)
   92: AC_CHECK_SIZEOF(short)
   93: AC_CHECK_SIZEOF(int)
   94: AC_CHECK_SIZEOF(long)
   95: AC_CHECK_SIZEOF(long long)
   96: 
   97: ac_cv_int_type_cell=none
   98: case "$ac_cv_sizeof_char_p" in
   99:   $ac_cv_sizeof_int)
  100:     ac_cv_int_type_cell=int
  101:     ;;
  102:   $ac_cv_sizeof_short)
  103:     ac_cv_int_type_cell=short
  104:     ;;
  105:   $ac_cv_sizeof_char)
  106:     ac_cv_int_type_cell=char
  107:     ;;
  108:   $ac_cv_sizeof_long)
  109:     ac_cv_int_type_cell=long
  110:     ;;
  111:   $ac_cv_sizeof_long_long)
  112:     ac_cv_int_type_cell="long long"
  113:     ;;
  114: esac
  115: if test "$ac_cv_int_type_cell" != int; then
  116: 	echo "So, sizeof(pointer)!=sizeof(int); looks like a DOS C compiler to me."
  117: 	echo "Since you don't have a proper C on this machine, that's one more reason"
  118: 	echo "to use Forth;-)"
  119: fi
  120: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell)
  121: 
  122: ac_cv_int_type_double_cell=none
  123: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  124:   $ac_cv_sizeof_short)
  125:     ac_cv_int_type_double_cell=short
  126:     ;;
  127:   $ac_cv_sizeof_int)
  128:     ac_cv_int_type_double_cell=int
  129:     ;;
  130:   $ac_cv_sizeof_long)
  131:     ac_cv_int_type_double_cell=long
  132:     ;;
  133:   $ac_cv_sizeof_long_long)
  134:     ac_cv_int_type_double_cell="long long"
  135:     ;;
  136: esac
  137: if test "$ac_cv_int_type_double_cell" = none; then
  138: 	echo "Emulating double-cell arithmetic. This may be slow."
  139: 	echo "If you find this unacceptable, ask the GCC maintainers to provide proper"
  140: 	echo 'long longs for your machine (the GCC manual states that they \"are twice as'
  141: 	echo "long as \`long int\'\")."
  142: 	LIBOBJS="$LIBOBJS dblsub.o"
  143: 	AC_DEFINE(BUGGY_LONG_LONG)
  144: else
  145:   AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell)
  146: fi
  147: 
  148: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  149: OLDLDFLAGS=$LDFLAGS
  150: LDFLAGS="$LDFLAGS -export-dynamic"
  151: AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  152: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  153: AC_MSG_RESULT($ac_export_dynamic)
  154: 
  155: #terminology is a bit unusual here: The host is the system on which
  156: #gforth will run; the system on which configure will run is the `build'
  157: AC_CANONICAL_HOST
  158: case "$host_cpu" in
  159: 	hppa*)
  160: 		machine=hppa
  161: 		$srcdir/mkinstalldirs arch/hppa
  162: 		LIBOBJS="$LIBOBJS ../arch/hppa/cache.o"
  163: 		LDFLAGS="$LDFLAGS -Xlinker -N"
  164: 		LIBS="$LIBS -L/lib/pa1.1/"
  165: 		if test "${enable_direct_threaded+set}" = ""
  166: 		then
  167: 			AC_DEFINE(DIRECT_THREADED)
  168: 		fi
  169: 		;;
  170: 	sparc*)
  171: 		machine=sparc
  172: 		;;
  173: 	i386)
  174: 		machine=386
  175: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  176: 		if test "${enable_direct_threaded+set}" = "" \
  177: 			-a "${enable_indirect_threaded+set}" = ""
  178: 		then
  179: 			echo "Using direct threaded code on 386"
  180: 			AC_DEFINE(DIRECT_THREADED)
  181: 		fi
  182: 		;;
  183: 	i486)
  184: 		machine=386
  185: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
  186: 		if test "${enable_direct_threaded+set}" = "" \
  187: 			-a "${enable_indirect_threaded+set}" = ""
  188: 		then
  189: 			echo "Using direct threaded code on 486"
  190: 			AC_DEFINE(DIRECT_THREADED)
  191: 		fi
  192: 		;;
  193: 	i586)
  194: 		machine=386
  195: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  196: 		CFLAGS_1="$CFLAGS"
  197: 		CFLAGS="$CFLAGS -mpentium"
  198: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  199: 		if test "${enable_direct_threaded+set}" = "" \
  200: 			-a "${enable_indirect_threaded+set}" = ""
  201: 		then
  202: 			echo "Using indirect threaded code on Pentium/K5/K6"
  203: 			AC_DEFINE(INDIRECT_THREADED)
  204: 		fi
  205: 		;;
  206: 	i686)
  207: 		machine=386
  208: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  209: 		CFLAGS_1="$CFLAGS"
  210: 		CFLAGS="$CFLAGS -mpentiumpro"
  211: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  212: 		if test "${enable_direct_threaded+set}" = "" \
  213: 			-a "${enable_indirect_threaded+set}" = ""
  214: 		then
  215: 			echo "Using direct threaded code on Athlon/PPro/Pentium II/Pentium III"
  216: 			AC_DEFINE(DIRECT_THREADED)
  217: 		fi
  218: 		;;
  219:         m68k)
  220: 		machine=m68k
  221: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  222: 		if test "$host_os" = "nextstep3"
  223: 		then
  224: 			LIBOBJS="$LIBOBJS termios.o"
  225: 		fi
  226: 		;;
  227: 	mips*)
  228: 		machine=mips
  229: 		#link text and data segment into the same 256M region!
  230: 		AC_MSG_CHECKING([whether the linker accepts -T])
  231: 		OLDLDFLAGS=$LDFLAGS
  232: 		LDFLAGS="$LDFLAGS -Xlinker -T -Xlinker 10000000"
  233: 		AC_TRY_LINK(,,ac_link_mips_t=yes,ac_link_mips_t=no)
  234: 		test $ac_link_mips_t = yes||LDFLAGS=$OLDLDFLAGS
  235: 		AC_MSG_RESULT($ac_link_mips_t)
  236: 		test $ac_link_mips_t = yes||(echo cannot link text and data into same 256M region, using indirect threading; AC_DEFINE(INDIRECT_THREADED))
  237: 		AC_MSG_CHECKING([whether the linker accepts -D])
  238: 		OLDLDFLAGS=$LDFLAGS
  239: 		LDFLAGS="$LDFLAGS -Xlinker -D -Xlinker 10400000"
  240: 		AC_TRY_LINK(,,ac_link_mips_d=yes,ac_link_mips_d=no)
  241: 		test $ac_link_mips_d = yes||LDFLAGS=$OLDLDFLAGS
  242: 		AC_MSG_RESULT($ac_link_mips_d)
  243: 		;;
  244: 	alpha*)
  245: 		machine=alpha
  246: 		#full IEEE FP support for more uniformity across platforms:
  247: 		CFLAGS="$CFLAGS -mieee"
  248: 		;;
  249: 	power*)
  250: 		machine=power
  251: 		$srcdir/mkinstalldirs arch/power
  252: 		AC_CHECK_FUNC(_sync_cache_range,true,LIBOBJS="$LIBOBJS ../arch/power/_sync_cache_range.o")
  253: 		#link text segment into first 32MB
  254: 		AC_MSG_CHECKING([whether the linker accepts --script=arch/power/elf32ppc.x])
  255: 		OLDLDFLAGS=$LDFLAGS
  256:                 #the -L../$srcdir helps when $srcdir is relative
  257: 		LDFLAGS="$LDFLAGS -L$srcdir -L../$srcdir -Xlinker --script=$srcdir/arch/power/elf32ppc.x"
  258: 		AC_TRY_LINK(,,ac_link_script=yes,ac_link_script=no)
  259: 		test $ac_link_script = yes||LDFLAGS=$OLDLDFLAGS
  260: 		AC_MSG_RESULT($ac_link_script)
  261: 		AC_MSG_CHECKING([whether the code is in the first 32MB])
  262: 		AC_TRY_RUN([main(){label: exit(((unsigned long)&&label)>32000000UL);}],ac_code_under_32=yes,ac_code_under_32=no,ac_code_under_32=no)
  263:                 AC_MSG_RESULT($ac_code_under_32)
  264: 		test $ac_code_under_32 = yes||(AC_MSG_WARN([Using indirect threading; please contact us (bug-gforth@gnu.org)]); AC_DEFINE(INDIRECT_THREADED))
  265: 		;;
  266: 	*)
  267: 		echo "No direct threading support for $host_cpu, using indirect threading."
  268: 		echo "Using a generic machine description."
  269: 		echo "I'll assume that C floats and doubles are represented by IEEE single and"
  270: 		echo "double numbers. If this is not so, SF@ etc. will not work correctly."
  271: 		echo "FLUSH-ICACHE will do nothing, so END-CODE may not work properly!"
  272: 		machine=generic
  273: esac
  274: AC_SUBST(host)
  275: AC_SUBST(ENGINE_FLAGS)
  276: 
  277: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  278: AC_SUBST(asm_fs)
  279: 
  280: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  281: AC_SUBST(disasm_fs)
  282: 
  283: case "$host_os" in
  284: 	*win32)
  285: 		EXE=".exe"
  286: 		;;
  287: 	*)
  288: 		EXE=""
  289: 		;;
  290: esac
  291: AC_SUBST(EXE)
  292: 
  293: dnl Now a little support for DOS/DJGCC
  294: AC_SUBST(GFORTH_EXE)
  295: GFORTH_EXE=""
  296: AC_SUBST(GFORTHFAST_EXE)
  297: GFORTHFAST_EXE=""
  298: AC_SUBST(GFORTHDITC_EXE)
  299: GFORTHDITC_EXE=""
  300: 
  301: PATHSEP=":"
  302: AC_SUBST(PATHSEP)
  303: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP')
  304: 
  305: AC_SUBST(FORTHSIZES)
  306: 
  307: dnl copy commands for systems that don't have links
  308: AC_SUBST(LINK_KERNL)
  309: LINK_KERNL=""
  310: 
  311: #if test $host_os=dos
  312: #then
  313: #  echo Configuring for DOS!!!
  314: #  MAKE_EXE="coff2exe gforth"
  315: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  316: #fi
  317: 
  318: dnl the following macro produces a warning with autoconf-2.1
  319: AC_C_BIGENDIAN
  320: AC_SUBST(KERNEL)
  321: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  322: if test $ac_cv_c_bigendian = yes; then
  323:   bytesex=b
  324:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  325: else
  326:   bytesex=l
  327:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  328: fi
  329: 
  330: dnl Checks for programs.
  331: AC_PROG_LN_S
  332: dnl AM_PROG_INSTALL #performed by AM_INIT_AUTOMAKE
  333: 
  334: dnl Checks for library functions
  335: dnl This check is just for making later checks link with libm.
  336: dnl using sin here is no good idea since it is built-into gcc and typechecked
  337: AC_CHECK_LIB(m,asin)
  338: AC_CHECK_LIB(dl,dlopen)
  339: if test "$host_os" != "nextstep3"
  340: then
  341: 	AC_FUNC_MEMCMP
  342: fi
  343: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  344: AC_CHECK_FUNCS(dlopen sys_siglist)
  345: AC_DECL_SYS_SIGLIST
  346: AC_CHECK_FUNC(getopt_long,true,LIBOBJS="$LIBOBJS getopt.o getopt1.o")
  347: AC_CHECK_FUNCS(rint expm1 log1p)
  348: AC_REPLACE_FUNCS(ecvt)
  349: dnl No check for select, because our replacement is no good under
  350: dnl anything but DOS
  351: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
  352: AC_FUNC_FNMATCH
  353: test $ac_cv_func_fnmatch_works = yes || LIBOBJS="$LIBOBJS fnmatch.o"
  354: AC_CHECK_FUNCS(mmap sysconf getpagesize)
  355: AM_PATH_LISPDIR
  356: 
  357: kernel_fi=kernl${wordsize}${bytesex}.fi
  358: AC_SUBST(kernel_fi)
  359: 
  360: dnl replace srource directory by absolute value
  361: if test $srcdir = "."; then srcdir=`pwd` 
  362: fi
  363: 
  364: AC_SUBST(machine)
  365: dnl AC_LINK_FILES(arch/$machine,arch/machine) #no longer needed
  366: AC_OUTPUT([
  367: Makefile
  368: Makedist
  369: gforthmi
  370: engine/Makefile
  371: doc/version.texi ],
  372: echo timestamp > stamp-h
  373: chmod +x gforthmi
  374: test -d kernel||mkdir kernel)
  375: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>