File:  [gforth] / gforth / configure.in
Revision 1.30: download - view: text, annotated - select for diffs
Tue Mar 25 23:27:12 1997 UTC (22 years, 7 months ago) by pazsan
Branches: MAIN
CVS tags: v0-3-0, HEAD
Improved DOS/OS/2 support

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation; either version 2
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program; if not, write to the Free Software
   19: #Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
   20: 
   21: AC_INIT(engine.c)
   22: AC_CONFIG_HEADER(config.h)
   23: 
   24: AC_ARG_ENABLE(force-reg,
   25: [  --enable-force-reg	  Use explicit register declarations if they appear in
   26: 			  the machine.h file. This can cause a good speedup,
   27: 			  but also incorrect code with some gcc versions on
   28: 			  some processors (default disabled).],
   29: 
   30: AC_DEFINE(FORCE_REG))
   31: dnl this is not quite according to the autoconf manual, it causes a replacement
   32: AC_ARG_ENABLE(direct-threaded,
   33: [  --enable-direct-threaded	Force direct threading. This may not work on
   34: 				some machines and may cause slowdown on others.
   35: 				(default processor-dependent)],
   36: AC_DEFINE(DIRECT_THREADED))
   37: AC_ARG_ENABLE(indirect-threaded,
   38: [  --enable-indirect-threaded	Force indirect threading. This can cause a
   39: 				slowdown on some machines.
   40: 				(default processor-dependent)],
   41: AC_DEFINE(INDIRECT_THREADED))
   42: 
   43: AC_ARG_WITH(debug,
   44: [  --with-debug     specifies option -g to compile with debug info (default)
   45:   --without-debug  omits the -g switch and creates smaller images on
   46:                    machines where "strip" has problems with gcc style
   47:                    debugging informations.],
   48: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   49: 
   50: CFLAGS=$CFLAGS
   51: 
   52: AC_PROG_CC
   53: 
   54: if test "$GCC" = "yes"
   55: then
   56:    echo "Fine, gcc is available"
   57: else
   58:    cat <<'EOF'
   59: Gforth requires GCC-2.0 or higher (it uses GNU C extensions).
   60: It does not work with other C compilers. Please install the GNU C compiler,
   61: and try again (or search for a binary distribution for your platform).
   62: EOF
   63:    exit 1
   64: fi
   65: 
   66: AC_SUBST(CC)
   67: AC_SUBST(GCCLDFLAGS)
   68: AC_SUBST(DEBUGFLAG)
   69: 
   70: dnl the following macro produces a warning with autoconf-2.1
   71: AC_CHECK_SIZEOF(char *)
   72: case "$ac_cv_sizeof_char_p" in
   73:   2)
   74:     wordsize=16
   75:     ;;
   76:   4)
   77:     wordsize=32
   78:     ;;
   79:   8)
   80:     wordsize=64
   81:     ;;
   82: esac
   83: 
   84: AC_CHECK_SIZEOF(short)
   85: AC_CHECK_SIZEOF(int)
   86: AC_CHECK_SIZEOF(long)
   87: AC_CHECK_SIZEOF(long long)
   88: 
   89: ac_cv_int_type_cell=none
   90: case "$ac_cv_sizeof_char_p" in
   91:   $ac_cv_sizeof_short)
   92:     ac_cv_int_type_cell=short
   93:     ;;
   94:   $ac_cv_sizeof_int)
   95:     ac_cv_int_type_cell=int
   96:     ;;
   97:   $ac_cv_sizeof_long)
   98:     ac_cv_int_type_cell=long
   99:     ;;
  100:   $ac_cv_sizeof_long_long)
  101:     ac_cv_int_type_cell="long long"
  102:     ;;
  103: esac
  104: if test "$ac_cv_int_type_cell" != int; then
  105: 	echo "So, sizeof(pointer)!=sizeof(int); looks like a DOS C compiler to me."
  106: 	echo "Since you don't have a proper C on this machine, that's one more reason"
  107: 	echo "to use Forth;-)"
  108: fi
  109: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell)
  110: 
  111: ac_cv_int_type_double_cell=none
  112: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  113:   $ac_cv_sizeof_short)
  114:     ac_cv_int_type_double_cell=short
  115:     ;;
  116:   $ac_cv_sizeof_int)
  117:     ac_cv_int_type_double_cell=int
  118:     ;;
  119:   $ac_cv_sizeof_long)
  120:     ac_cv_int_type_double_cell=long
  121:     ;;
  122:   $ac_cv_sizeof_long_long)
  123:     ac_cv_int_type_double_cell="long long"
  124:     ;;
  125: esac
  126: if test "$ac_cv_int_type_double_cell" = none; then
  127: 	echo "Emulating double-cell arithmetic. This may be slow."
  128: 	echo "If you find this unacceptable, ask the GCC maintainers to provide proper"
  129: 	echo 'long longs for your machine (the GCC manual states that they \"are twice as'
  130: 	echo "long as \`long int\'\")."
  131: 	LIBOBJS="$LIBOBJS dblsub.o"
  132: 	AC_DEFINE(BUGGY_LONG_LONG)
  133: else
  134:   AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell)
  135: fi
  136: 
  137: #terminology is a bit unusual here: The host is the system on which
  138: #gforth will run; the system on which configure will run is the `build'
  139: AC_CANONICAL_HOST
  140: case "$host_cpu" in
  141: 	hppa*)
  142: 		mach_h=hppa
  143: 		LIBOBJS="cache.o"
  144: 		LDFLAGS="-Xlinker -N"
  145: 		LIBS="-L/lib/pa1.1/"
  146: 		;;
  147: 	sparc*)
  148: 		mach_h=sparc
  149: 		;;
  150: 	i386|i486|i586)
  151: 		mach_h=386
  152: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  153: 		#!! direct/indirect threading switch
  154: 		#!! -m486 flag
  155: 		;;
  156:         m68k)
  157: 		mach_h=m68k
  158: 		CFLAGS="$CFLAGS -fomit-frame-pointer -traditional-cpp"
  159: 		;;
  160: 	mips*)
  161: 		mach_h=mips
  162: 		#link text and data segment into the same 256M region!
  163: 		GCCLDFLAGS="-Xlinker -T -Xlinker 10000000 -Xlinker -D -Xlinker 10400000"
  164: 		;;
  165: 	alpha*)
  166: 		mach_h=alpha
  167: 		;;
  168: 	*)
  169: 		echo "No direct threading support for $host_cpu, using indirect threading."
  170: 		echo "Using a generic machine description."
  171: 		echo "I'll assume that C floats and doubles are represented by IEEE single and"
  172: 		echo "double numbers. If this is not so, SF@ etc. will not work correctly."
  173: 		echo "FLUSH-ICACHE will do nothing, so END-CODE may not work properly!"
  174: 		mach_h=32bit
  175: esac
  176: AC_SUBST(host)
  177: AC_SUBST(ENGINE_FLAGS)
  178: 
  179: dnl Now a little support for DOS/DJGCC
  180: AC_SUBST(GFORTH_EXE)
  181: GFORTH_EXE=""
  182: AC_SUBST(GFORTHDITC_EXE)
  183: GFORTHDITC_EXE=""
  184: 
  185: PATHSEP=":"
  186: AC_SUBST(PATHSEP)
  187: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP')
  188: 
  189: AC_SUBST(FORTHSIZES)
  190: 
  191: dnl copy commands for systems that don't have links
  192: AC_SUBST(LINK_KERNL)
  193: LINK_KERNL=""
  194: 
  195: #if test $host_os=dos
  196: #then
  197: #  echo Configuring for DOS!!!
  198: #  MAKE_EXE="coff2exe gforth"
  199: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  200: #fi
  201: 
  202: dnl the following macro produces a warning with autoconf-2.1
  203: AC_C_BIGENDIAN
  204: AC_SUBST(KERNEL)
  205: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  206: if test $ac_cv_c_bigendian = yes; then
  207:   bytesex=b
  208:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  209: else
  210:   bytesex=l
  211:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  212: fi
  213: 
  214: dnl Checks for programs.
  215: AC_PROG_LN_S
  216: AC_PROG_INSTALL
  217: 
  218: dnl Checks for library functions
  219: dnl This check is just for making later checks link with libm.
  220: dnl using sin here is no good idea since it is built-into gcc and typechecked
  221: AC_CHECK_LIB(m,asin)
  222: AC_FUNC_MEMCMP
  223: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  224: AC_CHECK_FUNCS(sys_siglist)
  225: AC_DECL_SYS_SIGLIST
  226: AC_CHECK_FUNC(getopt_long,getopt_long="",getopt_long="getopt.o getopt1.o")
  227: AC_SUBST(getopt_long)
  228: AC_CHECK_FUNCS(rint expm1 log1p)
  229: AC_REPLACE_FUNCS(ecvt)
  230: dnl No check for select, because our replacement is no good under
  231: dnl anything but DOS
  232: AC_CHECK_HEADERS(sys/mman.h)
  233: AC_CHECK_FUNCS(mmap sysconf getpagesize)
  234: 
  235: kernel_fi=kernl${wordsize}${bytesex}.fi
  236: AC_SUBST(kernel_fi)
  237: 
  238: AC_LINK_FILES(${mach_h}.h $kernel_fi,machine.h kernel.fi)
  239: AC_OUTPUT(Makefile,echo timestamp > stamp-h)
  240: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>