File:  [gforth] / gforth / configure.in
Revision 1.94: download - view: text, annotated - select for diffs
Fri Dec 27 12:32:52 2002 UTC (16 years, 10 months ago) by anton
Branches: MAIN
CVS tags: HEAD
replaced some automake macros with autoconf macros; related changes in
  autoconf variables (e.g., @VERSION@ -> @PACKAGE_VERSION@)
gforth-prof and gforth-native are now not built by default
modernized "Automatic Remaking" section of Makefile.in
Updated bug reporting instructions
Eliminated use of old bug reporting email address

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation; either version 2
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program; if not, write to the Free Software
   19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: dnl We use some automake macros here,
   22: dnl but don't use automake for creating Makefile.in
   23: AC_INIT(gforth,0.5.9-20021227,https://savannah.gnu.org/bugs/?func=addbug&group=gforth)
   24: #snapshots have numbers major.minor.release-YYYYMMDD
   25: #note that lexicographic ordering must be heeded.
   26: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   27: UPDATED="27 December 2002"
   28: AC_SUBST(UPDATED)
   29: AC_CONFIG_HEADERS(engine/config.h)
   30: dnl AM_CYGWIN32
   31: 
   32: #default setting that may be changed later:
   33: no_dynamic_default=0
   34: 
   35: AC_ARG_ENABLE(force-reg,
   36: [  --enable-force-reg	  Use explicit register declarations if they appear in
   37: 			  the machine.h file. This can cause a good speedup,
   38: 			  but also incorrect code with some gcc versions on
   39: 			  some processors (default disabled).],
   40: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)]))
   41: 
   42: AC_ARG_WITH(debug,
   43: [  --with-debug     specifies option -g to compile with debug info (default)
   44:   --without-debug  omits the -g switch and creates smaller images on
   45:                    machines where "strip" has problems with gcc style
   46:                    debugging informations.],
   47: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   48: 
   49: PEEPHOLE="yes"
   50: AC_ARG_WITH(peephole,
   51: [  --with-peephole	Enable peephole optimization (default)
   52:   --without-peephole	disables peephole optimization. Creates smaller,
   53: 			but slower images.],
   54: PEEPHOLE="$withval")
   55: 
   56: #currently we force direct threading this way.  Eventually we should
   57: #setup in the arch and engine files right
   58: 
   59: CFLAGS=$CFLAGS
   60: 
   61: AC_PROG_CC
   62: 
   63: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
   64: 
   65: AC_SUBST(CC)
   66: AC_SUBST(DEBUGFLAG)
   67: 
   68: AC_MSG_CHECKING(gcc version)
   69: gcc_version=`$CC -v 2>&1|grep 'gcc version'|sed 's/.*gcc version //'`
   70: AC_MSG_RESULT($gcc_version)
   71: if expr "$gcc_version" \> 3.0.4 >/dev/null && expr "$gcc_version" \< 3.2.1 >/dev/null
   72: then
   73:     no_dynamic_default=1
   74:     AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
   75: fi
   76: 
   77: dnl the following macro produces a warning with autoconf-2.1
   78: AC_CHECK_SIZEOF(char *)
   79: case "$ac_cv_sizeof_char_p" in
   80:   2)
   81:     wordsize=16
   82:     ;;
   83:   4)
   84:     wordsize=32
   85:     ;;
   86:   8)
   87:     wordsize=64
   88:     ;;
   89: esac
   90: 
   91: AC_CHECK_SIZEOF(char)
   92: AC_CHECK_SIZEOF(short)
   93: AC_CHECK_SIZEOF(int)
   94: AC_CHECK_SIZEOF(long)
   95: AC_CHECK_SIZEOF(long long)
   96: 
   97: AC_MSG_CHECKING([for a C type for cells])
   98: ac_cv_int_type_cell=none
   99: case "$ac_cv_sizeof_char_p" in
  100:   $ac_cv_sizeof_int)
  101:     ac_cv_int_type_cell=int
  102:     ;;
  103:   $ac_cv_sizeof_short)
  104:     ac_cv_int_type_cell=short
  105:     ;;
  106:   $ac_cv_sizeof_char)
  107:     ac_cv_int_type_cell=char
  108:     ;;
  109:   $ac_cv_sizeof_long)
  110:     ac_cv_int_type_cell=long
  111:     ;;
  112:   $ac_cv_sizeof_long_long)
  113:     ac_cv_int_type_cell="long long"
  114:     ;;
  115: esac
  116: AC_MSG_RESULT($ac_cv_int_type_cell)
  117: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  118: 
  119: AC_MSG_CHECKING([for a C type for double-cells])
  120: ac_cv_int_type_double_cell=none
  121: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  122:   $ac_cv_sizeof_short)
  123:     ac_cv_int_type_double_cell=short
  124:     ;;
  125:   $ac_cv_sizeof_int)
  126:     ac_cv_int_type_double_cell=int
  127:     ;;
  128:   $ac_cv_sizeof_long)
  129:     ac_cv_int_type_double_cell=long
  130:     ;;
  131:   $ac_cv_sizeof_long_long)
  132:     ac_cv_int_type_double_cell="long long"
  133:     ;;
  134: esac
  135: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  136: if test "$ac_cv_int_type_double_cell" = none; then
  137: 	AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
  138: 	AC_LIBOBJ(dblsub)
  139: 	AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
  140: else
  141: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  142: fi
  143: 
  144: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  145: OLDLDFLAGS=$LDFLAGS
  146: LDFLAGS="$LDFLAGS -export-dynamic"
  147: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  148: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  149: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  150: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  151: AC_MSG_RESULT($ac_export_dynamic)
  152: 
  153: #terminology is a bit unusual here: The host is the system on which
  154: #gforth will run; the system on which configure will run is the `build'
  155: AC_CANONICAL_HOST
  156: case "$host_cpu" in
  157: 	hppa*)
  158: 		machine=hppa
  159: 		$srcdir/mkinstalldirs arch/hppa
  160: 		AC_LIBOBJ(../arch/hppa/cache)
  161: 		LDFLAGS="$LDFLAGS -Xlinker -N"
  162: 		LIBS="$LIBS -L/lib/pa1.1/"
  163: 		;;
  164: 	sparc*)
  165: 		machine=sparc
  166: 		;;
  167: 	i386)
  168: 		machine=386
  169: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  170: 		;;
  171: 	i486)
  172: 		machine=386
  173: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
  174: 		;;
  175: 	i*86)
  176: 		machine=386
  177: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  178: 		CFLAGS_1="$CFLAGS"
  179: 		CFLAGS="$CFLAGS -march=pentium"
  180: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  181: 		;;
  182: 	ia64*)
  183: 		machine=ia64
  184: 		;;
  185:         m68k)
  186: 		machine=m68k
  187: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  188: 		if test "$host_os" = "nextstep3"
  189: 		then
  190: 			AC_LIBOBJ(termios)
  191: 		fi
  192: 		;;
  193: 	mips*)
  194: 		machine=mips
  195: 		#dynamic native code has the following problems on MIPS:
  196: 		#
  197: 		#1) J/JAL seems relocatable, but is are only
  198: 		#relocatable within a 256MB-segment.  While we try to
  199: 		#get the linker to arrange this, there is no guarantee
  200: 		#that this will succeed (and if the user uses a lot of
  201: 		#memory, it is likely to fail).
  202: 		#
  203: 		#2) The way we generate dynamic native code may
  204: 		#violate MIPS architectural restrictions (in
  205: 		#particular, the delay slots of LW, MFLO, etc.)
  206: 		#
  207: 		#Therefore we disable dynamic native code by default:
  208: 		no_dynamic_default=1
  209: 		AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  210: 		#link text and data segment into the same 256M region!
  211: 		AC_MSG_CHECKING([whether the linker accepts -T])
  212: 		OLDLDFLAGS=$LDFLAGS
  213: 		LDFLAGS="$LDFLAGS -Xlinker -T -Xlinker 10000000"
  214: 		AC_TRY_LINK(,,ac_link_mips_t=yes,ac_link_mips_t=no)
  215: 		test $ac_link_mips_t = yes||LDFLAGS=$OLDLDFLAGS
  216: 		AC_MSG_RESULT($ac_link_mips_t)
  217: 		AC_MSG_CHECKING([whether the linker accepts -D])
  218: 		OLDLDFLAGS=$LDFLAGS
  219: 		LDFLAGS="$LDFLAGS -Xlinker -D -Xlinker 10400000"
  220: 		AC_TRY_LINK(,,ac_link_mips_d=yes,ac_link_mips_d=no)
  221: 		test $ac_link_mips_d = yes||LDFLAGS=$OLDLDFLAGS
  222: 		AC_MSG_RESULT($ac_link_mips_d)
  223: 		;;
  224: 	alpha*)
  225: 		machine=alpha
  226: 		#full IEEE FP support for more uniformity across platforms:
  227: 		CFLAGS="$CFLAGS -mieee"
  228: 		;;
  229: 	power*|rs6000)
  230: 		machine=power
  231: 		$srcdir/mkinstalldirs arch/power
  232: 		AC_CHECK_FUNC(_sync_cache_range,true,AC_LIBOBJ(../arch/power/_sync_cache_range))
  233: 		;;
  234: 	*)
  235: 		AC_MSG_WARN([Using a generic machine description])
  236: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  237: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  238: 		machine=generic
  239: esac
  240: AC_SUBST(host)
  241: AC_SUBST(ENGINE_FLAGS)
  242: 
  243: # Try if GCC understands -fno-cross-jump
  244: 
  245: CFLAGS_1="$CFLAGS"
  246: CFLAGS="$CFLAGS -fno-cross-jump"
  247: AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1")
  248: 
  249: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  250: AC_SUBST(asm_fs)
  251: 
  252: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  253: AC_SUBST(disasm_fs)
  254: 
  255: case "$host_os" in
  256: 	*win32)
  257: 		EXE=".exe"
  258: 		DIRSEP="\\"
  259: 		;;
  260: 	*)
  261: 		EXE=""
  262: 		DIRSEP="/"
  263: 		;;
  264: esac
  265: AC_SUBST(EXE)
  266: AC_SUBST(DIRSEP)
  267: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  268: 
  269: dnl Now a little support for DOS/DJGCC
  270: AC_SUBST(GFORTH_EXE)
  271: GFORTH_EXE=""
  272: AC_SUBST(GFORTHFAST_EXE)
  273: GFORTHFAST_EXE=""
  274: AC_SUBST(GFORTHITC_EXE)
  275: GFORTHITC_EXE=""
  276: AC_SUBST(GFORTHDITC_EXE)
  277: GFORTHDITC_EXE=""
  278: 
  279: PATHSEP=":"
  280: AC_SUBST(PATHSEP)
  281: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  282: 
  283: AC_SUBST(FORTHSIZES)
  284: 
  285: if test "$PEEPHOLE" = "yes"
  286: then
  287:    PEEPHOLEFLAG="true"
  288:    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  289: else
  290:    PEEPHOLEFLAG="false"
  291: fi
  292: AC_SUBST(PEEPHOLEFLAG)
  293: 
  294: dnl copy commands for systems that don't have links
  295: AC_SUBST(LINK_KERNL)
  296: LINK_KERNL=""
  297: 
  298: #if test $host_os=dos
  299: #then
  300: #  echo Configuring for DOS!!!
  301: #  MAKE_EXE="coff2exe gforth"
  302: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  303: #fi
  304: 
  305: dnl the following macro produces a warning with autoconf-2.1
  306: AC_C_BIGENDIAN
  307: AC_SUBST(KERNEL)
  308: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  309: if test $ac_cv_c_bigendian = yes; then
  310:   bytesex=b
  311:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  312: else
  313:   bytesex=l
  314:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  315: fi
  316: 
  317: #check how to do asm(".skip 16")
  318: AC_MSG_CHECKING([if and how we can waste code space])
  319: skipcode=no
  320: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  321: do
  322: 	AC_TRY_RUN(
  323: int foo(int);
  324: main()
  325: {
  326:   exit(foo(0)!=16);
  327: }
  328: int foo(int x)
  329: {
  330:   if (x) {
  331:   label1:
  332:     asm("$i");
  333:   label2:
  334:   }
  335:   return (&&label2)-(&&label1);
  336: }
  337: 	,skipcode=$i; break
  338: 	,,)
  339: done	
  340: AC_MSG_RESULT($skipcode)
  341: if test "$skipcode" = no
  342: then 
  343:     no_dynamic_default=1
  344:     AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
  345:     AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  346: else
  347:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  348: fi
  349: 
  350: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  351: 
  352: dnl Checks for programs.
  353: AC_PROG_LN_S
  354: dnl AM_PROG_INSTALL #performed by AM_INIT_AUTOMAKE
  355: 
  356: dnl Checks for library functions
  357: dnl This check is just for making later checks link with libm.
  358: dnl using sin here is no good idea since it is built-into gcc and typechecked
  359: AC_CHECK_LIB(m,asin)
  360: AC_CHECK_LIB(dl,dlopen)
  361: if test "$host_os" != "nextstep3"
  362: then
  363: 	AC_FUNC_MEMCMP
  364: fi
  365: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  366: AC_CHECK_FUNCS(dlopen sys_siglist getrusage fseeko ftello)
  367: AC_TYPE_OFF_T
  368: AC_DECL_SYS_SIGLIST
  369: AC_CHECK_FUNC(getopt_long,true,AC_LIBOBJ(getopt); AC_LIBOBJ(getopt1))
  370: AC_CHECK_FUNCS(expm1 log1p)
  371: AC_REPLACE_FUNCS(rint ecvt)
  372: dnl No check for select, because our replacement is no good under
  373: dnl anything but DOS
  374: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
  375: AC_FUNC_FNMATCH
  376: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
  377: AC_CHECK_FUNCS(mmap sysconf getpagesize)
  378: AM_PATH_LISPDIR
  379: 
  380: kernel_fi=kernl${wordsize}${bytesex}.fi
  381: AC_SUBST(kernel_fi)
  382: 
  383: #this breaks bindists
  384: #dnl replace srource directory by absolute value
  385: #if test $srcdir = "."; then srcdir=`pwd` 
  386: #fi
  387: 
  388: AC_SUBST(machine)
  389: dnl AC_LINK_FILES(arch/$machine,arch/machine) #no longer needed
  390: AC_OUTPUT([
  391: Makefile
  392: Makedist
  393: gforthmi
  394: vmgen
  395: machpc.fs
  396: engine/Makefile
  397: doc/version.texi ],
  398: echo timestamp > stamp-h
  399: chmod +x gforthmi
  400: chmod +x vmgen
  401: test -d kernel||mkdir kernel)
  402: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>