File:  [gforth] / gforth / configure.in
Revision 1.133: download - view: text, annotated - select for diffs
Thu Aug 28 16:08:30 2003 UTC (16 years, 2 months ago) by anton
Branches: MAIN
CVS tags: HEAD
added amd64 architecture
changed some generic settings
minor changes

    1: dnl Process this file with autoconf to produce a configure script.
    2: 
    3: #Copyright (C) 1995,1996,1997,1998,2000,2003 Free Software Foundation, Inc.
    4: 
    5: #This file is part of Gforth.
    6: 
    7: #Gforth is free software; you can redistribute it and/or
    8: #modify it under the terms of the GNU General Public License
    9: #as published by the Free Software Foundation; either version 2
   10: #of the License, or (at your option) any later version.
   11: 
   12: #This program is distributed in the hope that it will be useful,
   13: #but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.#See the
   15: #GNU General Public License for more details.
   16: 
   17: #You should have received a copy of the GNU General Public License
   18: #along with this program; if not, write to the Free Software
   19: #Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: 
   22: dnl We use some automake macros here,
   23: dnl but don't use automake for creating Makefile.in
   24: AC_INIT([gforth],[0.6.2],[https://savannah.gnu.org/bugs/?func=addbug&group=gforth])
   25: AC_PREREQ(2.54)
   26: #snapshots have numbers major.minor.release-YYYYMMDD
   27: #note that lexicographic ordering must be heeded.
   28: #I.e., 0.4.1-YYYYMMDD must not exist before 0.4.1!
   29: UPDATED="August 25, 2003"
   30: AC_SUBST(UPDATED)
   31: AC_CONFIG_HEADERS(engine/config.h)
   32: 
   33: #suppress the "-g -O2" default
   34: test "$CFLAGS" || CFLAGS=-O2
   35: 
   36: #default setting that may be changed later:
   37: test "$no_dynamic_default" || no_dynamic_default=0
   38: 
   39: AC_ARG_ENABLE(force-reg,
   40: [  --enable-force-reg	  Use explicit register declarations if they appear in
   41: 			  the machine.h file. This can cause a good speedup,
   42: 			  but also incorrect code with some gcc versions on
   43: 			  some processors (default disabled).],
   44: AC_DEFINE(FORCE_REG,,[Define if you want to use explicit register declarations for better performance or for more convenient CODE words (does not work with all GCC versions on all machines)]))
   45: 
   46: AC_ARG_WITH(debug,
   47: [  --with-debug		  specifies option -g to compile with debug info
   48:   --without-debug	  omits the -g switch and creates smaller images on
   49: 			  machines where "strip" has problems with gcc style
   50: 			  debugging informations.],
   51: if test "$withval" = "yes"; then DEBUGFLAG=-g; fi)
   52: 
   53: dnl PEEPHOLE="yes"
   54: dnl AC_ARG_WITH(peephole,
   55: dnl [  --with-peephole	Enable peephole optimization (default)
   56: dnl   --without-peephole	disables peephole optimization. Creates smaller,
   57: dnl 			but slower images.],
   58: dnl PEEPHOLE="$withval")
   59: 
   60: #variables mentioned in INSTALL
   61: AC_ARG_VAR(CC, [The C compiler (must support GNU C 2.x); gcc-2.95 recommended.])
   62: AC_ARG_VAR(FORTHSIZES, [Gforth command line options for the default stack and dictionary sizes (see INSTALL).])
   63: AC_ARG_VAR(ac_cv_sizeof_char_p, [sizeof(char *)])
   64: AC_ARG_VAR(ac_cv_sizeof_char, [sizeof(char)])
   65: AC_ARG_VAR(ac_cv_sizeof_short, [sizeof(short)])
   66: AC_ARG_VAR(ac_cv_sizeof_int, [sizeof(int)])
   67: AC_ARG_VAR(ac_cv_sizeof_long, [sizeof(long)])
   68: AC_ARG_VAR(ac_cv_sizeof_long_long, [sizeof(long long)])
   69: AC_ARG_VAR(ac_cv_sizeof_intptr_t, [sizeof(intptr_t)])
   70: AC_ARG_VAR(ac_cv_sizeof_int128_t, [sizeof(int128_t)])
   71: AC_ARG_VAR(ac_cv_c_bigendian, [Is the target big-endian ("yes" or "no")?])
   72: AC_ARG_VAR(no_dynamic_default, [run gforth with --dynamic (0) or --no-dynamic (1) by default])
   73: 
   74: #set up feature test macros, so the tests get them right:
   75: # turn on all POSIX, SUSv3, and GNU features if available
   76: AC_GNU_SOURCE
   77: dnl AC_DEFINE_UNQUOTED([_GNU_SOURCE],1,[feature test macro])
   78: 
   79: dnl Don't define _POSIX_SOURCE etc. because some OSs (in particular
   80: dnl MacOSX) disable some features then (MacOSX checks for _POSIX_SOURCE,
   81: dnl but not for _XOPEN_SOURCE)
   82: dnl AC_DEFINE_UNQUOTED([_POSIX_SOURCE],1,[feature test macro])
   83: dnl AC_DEFINE_UNQUOTED([_POSIX_C_SOURCE],199506L,[feature test macro])
   84: dnl AC_DEFINE_UNQUOTED([_XOPEN_SOURCE],600,[feature test macro])
   85: # turn on large file support with 64-bit off_t where available
   86: AC_SYS_LARGEFILE
   87: dnl AC_DEFINE_UNQUOTED([_LARGEFILE_SOURCE],1,[feature test macro])
   88: dnl AC_DEFINE_UNQUOTED([_FILE_OFFSET_BITS],64,[feature test macro])
   89: 
   90: #currently we force direct threading this way.  Eventually we should
   91: #setup in the arch and engine files right
   92: 
   93: AC_PROG_CC
   94: 
   95: test "$GCC" = "yes" || AC_MSG_ERROR(Gforth uses GNU C extensions and requires GCC 2.0 or higher)
   96: 
   97: AC_SUBST(CC)
   98: AC_SUBST(DEBUGFLAG)
   99: 
  100: AC_MSG_CHECKING(make type)
  101: make_type=`make -v 2>&1|grep 'ake version'|sed 's/ version .*//'`
  102: 
  103: GNUMAKE='#'
  104: test "$make_type" = "GNU Make" && GNUMAKE=''
  105: 
  106: AC_MSG_RESULT($make_type)
  107: 
  108: AC_SUBST(GNUMAKE)
  109: 
  110: dnl gcc-3.2 seems to work fine now
  111: dnl AC_MSG_CHECKING(gcc version)
  112: dnl gcc_version=`$CC -v 2>&1|grep 'gcc version'|sed 's/.*gcc version //'`
  113: dnl AC_MSG_RESULT($gcc_version)
  114: dnl if expr "$gcc_version" \> 3.0.4 >/dev/null && expr "$gcc_version" \< 3.2.1 >/dev/null
  115: dnl then
  116: dnl    no_dynamic_default=1
  117: dnl    AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  118: dnl fi
  119: 
  120: AC_MSG_CHECKING([whether the linker accepts -export-dynamic])
  121: OLDLDFLAGS=$LDFLAGS
  122: LDFLAGS="$LDFLAGS -export-dynamic"
  123: dnl AC_TRY_LINK gives false positive on rs6000-ibm-aix4.2.1.0
  124: dnl AC_TRY_LINK(,,ac_export_dynamic=yes,ac_export_dynamic=no)
  125: AC_TRY_RUN(main(){exit(0);},ac_export_dynamic=yes,ac_export_dynamic=no,ac_export_dynamic=no)
  126: test $ac_export_dynamic = yes|| LDFLAGS=$OLDLDFLAGS
  127: AC_MSG_RESULT($ac_export_dynamic)
  128: 
  129: #terminology is a bit unusual here: The host is the system on which
  130: #gforth will run; the system on which configure will run is the `build'
  131: AC_CANONICAL_HOST
  132: case "$host_cpu" in
  133: 	hppa*)
  134: 		machine=hppa
  135: 		$srcdir/mkinstalldirs arch/hppa
  136: 		AC_LIBOBJ(../arch/hppa/cache)
  137: 		#LDFLAGS="$LDFLAGS -Xlinker -N"
  138: 		LIBS="$LIBS -L/lib/pa1.1/"
  139: 		#executing dynamically generated code produced segfaults on
  140: 		#the only HPPA machine that could waste code space, so
  141: 		#disable it by default
  142: 		no_dynamic_default=1
  143: 		AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  144: 		;;
  145: 	sparc*)
  146: 		machine=sparc
  147: 		;;
  148: 	i386)
  149: 		machine=386
  150: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  151: 		;;
  152: 	i486)
  153: 		machine=386
  154: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem -m486"
  155: 		;;
  156: 	i*86)
  157: 		machine=386
  158: 		CFLAGS="$CFLAGS -fomit-frame-pointer -fforce-addr -fforce-mem"
  159: 		CFLAGS_1="$CFLAGS"
  160: 		CFLAGS="$CFLAGS -march=pentium"
  161: 		AC_TRY_COMPILE(,,,CFLAGS="$CFLAGS_1 -m486")
  162: 		;;
  163: 	x86_64)
  164: 		machine=amd64
  165: 		;;
  166: #generic should work for IA64
  167: #	ia64*)
  168: #		machine=ia64
  169: #		;;
  170:         m68k)
  171: 		machine=m68k
  172: 		CFLAGS="$CFLAGS -fomit-frame-pointer"
  173: 		if test "$host_os" = "nextstep3"
  174: 		then
  175: 			AC_LIBOBJ(termios)
  176: 		fi
  177: 		;;
  178: 	mips*)
  179: 		machine=mips
  180: 		#dynamic native code has the following problems on MIPS:
  181: 		#
  182: 		#1) J/JAL seems relocatable, but is are only
  183: 		#relocatable within a 256MB-segment.  While we try to
  184: 		#get the linker to arrange this, there is no guarantee
  185: 		#that this will succeed (and if the user uses a lot of
  186: 		#memory, it is likely to fail).
  187: 		#
  188: 		#2) The way we generate dynamic native code may
  189: 		#violate MIPS architectural restrictions (in
  190: 		#particular, the delay slots of LW, MFLO, etc.)
  191: 		#
  192: 		#Therefore we disable dynamic native code by default:
  193: 		no_dynamic_default=1
  194: 		AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  195: 		;;
  196: 	alpha*)
  197: 		machine=alpha
  198: 		#full IEEE FP support for more uniformity across platforms:
  199: 		CFLAGS="$CFLAGS -mieee"
  200: 		;;
  201: 	power*|rs6000)
  202: 		machine=power
  203: 		$srcdir/mkinstalldirs arch/power
  204: 		AC_CHECK_FUNC(_sync_cache_range,true,AC_LIBOBJ(../arch/power/_sync_cache_range))
  205: 		#long long is broken on (at least) gcc-2.95.* for PPC
  206: 		test x$ac_cv_sizeof_long_long = x && ac_cv_sizeof_long_long=0
  207: 		;;
  208: 	*)
  209: 		AC_MSG_WARN([Using a generic machine description])
  210: 		AC_MSG_WARN([Assuming C floats and doubles are IEEE floats and doubles (for SF@ DF@ SF! DF!)])
  211: 		AC_MSG_WARN([FLUSH-ICACHE will do nothing, so END-CODE may not work properly!])
  212: 		machine=generic
  213: 		#I-cache flushing would be needed for dynamic code generation
  214: 		no_dynamic_default=1
  215: 		AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  216: esac
  217: AC_SUBST(host)
  218: 
  219: dnl the following macro produces a warning with autoconf-2.1
  220: AC_CHECK_SIZEOF(char *)
  221: case "$ac_cv_sizeof_char_p" in
  222:   2)
  223:     wordsize=16
  224:     ;;
  225:   4)
  226:     wordsize=32
  227:     ;;
  228:   8)
  229:     wordsize=64
  230:     ;;
  231: esac
  232: 
  233: AC_CHECK_SIZEOF(char)
  234: AC_CHECK_SIZEOF(short)
  235: AC_CHECK_SIZEOF(int)
  236: AC_CHECK_SIZEOF(long)
  237: AC_CHECK_SIZEOF(long long)
  238: AC_CHECK_SIZEOF(intptr_t)
  239: AC_CHECK_SIZEOF(int128_t)
  240: 
  241: AC_MSG_CHECKING([for a C type for cells])
  242: ac_cv_int_type_cell=none
  243: case "$ac_cv_sizeof_char_p" in
  244:   $ac_cv_sizeof_int)
  245:     ac_cv_int_type_cell=int
  246:     ;;
  247:   $ac_cv_sizeof_short)
  248:     ac_cv_int_type_cell=short
  249:     ;;
  250:   $ac_cv_sizeof_char)
  251:     ac_cv_int_type_cell=char
  252:     ;;
  253:   $ac_cv_sizeof_long)
  254:     ac_cv_int_type_cell=long
  255:     ;;
  256:   $ac_cv_sizeof_long_long)
  257:     ac_cv_int_type_cell="long long"
  258:     ;;
  259:   $ac_cv_sizeof_intptr_t)
  260:     ac_cv_int_type_cell="intptr_t"
  261:     ;;
  262:   $ac_cv_sizeof_int128_t)
  263:     ac_cv_int_type_cell="int128_t"
  264:     ;;
  265: esac
  266: AC_MSG_RESULT($ac_cv_int_type_cell)
  267: AC_DEFINE_UNQUOTED(CELL_TYPE,$ac_cv_int_type_cell,[an integer type that is as long as a pointer])
  268: 
  269: AC_MSG_CHECKING([for a C type for double-cells])
  270: ac_cv_int_type_double_cell=none
  271: case `expr 2 '*' "$ac_cv_sizeof_char_p"` in
  272:   $ac_cv_sizeof_short)
  273:     ac_cv_int_type_double_cell=short
  274:     ;;
  275:   $ac_cv_sizeof_int)
  276:     ac_cv_int_type_double_cell=int
  277:     ;;
  278:   $ac_cv_sizeof_long)
  279:     ac_cv_int_type_double_cell=long
  280:     ;;
  281:   $ac_cv_sizeof_long_long)
  282:     ac_cv_int_type_double_cell="long long"
  283:     ;;
  284:   $ac_cv_sizeof_intptr_t)
  285:     ac_cv_int_type_double_cell="intptr_t"
  286:     ;;
  287:   $ac_cv_sizeof_int128_t)
  288:     ac_cv_int_type_double_cell="int128_t"
  289:     ;;
  290: esac
  291: AC_MSG_RESULT($ac_cv_int_type_double_cell)
  292: if test "$ac_cv_int_type_double_cell" = none; then
  293: 	AC_MSG_WARN([Emulating double-cell arithmetic. This may be slow.])
  294: 	AC_LIBOBJ(dblsub)
  295: 	AC_DEFINE(BUGGY_LONG_LONG,,[define this if there is no working DOUBLE_CELL_TYPE on your machine])
  296: else
  297: 	AC_DEFINE_UNQUOTED(DOUBLE_CELL_TYPE,$ac_cv_int_type_double_cell,[an integer type that is twice as long as a pointer])
  298: fi
  299: 
  300: AC_TYPE_OFF_T
  301: AC_CHECK_SIZEOF(off_t)
  302: test $ac_cv_sizeof_off_t -gt $ac_cv_sizeof_char_p
  303: ac_small_off_t=$?
  304: AC_DEFINE_UNQUOTED(SMALL_OFF_T,$ac_small_off_t,[1 if off_t fits in a Cell])
  305: 
  306: ENGINE_FLAGS=
  307: AC_SUBST(ENGINE_FLAGS)
  308: 
  309: # Try if GCC understands -fno-gcse
  310: 
  311: AC_MSG_CHECKING([if $CC understands -fno-gcse])
  312: CFLAGS_1="$CFLAGS"
  313: CFLAGS="$CFLAGS -fno-gcse"
  314: AC_TRY_COMPILE(,,ac_nogcse=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-gcse",ac_nogcse=no)
  315: CFLAGS="$CFLAGS_1"
  316: AC_MSG_RESULT($ac_nogcse)
  317: 
  318: # Try if GCC understands -fno-strict-aliasing
  319: AC_MSG_CHECKING([if $CC understands -fno-strict-aliasing])
  320: CFLAGS_1="$CFLAGS"
  321: CFLAGS="$CFLAGS -fno-strict-aliasing"
  322: AC_TRY_COMPILE(,,ac_nostrictaliasing=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-strict-aliasing",ac_nostrictaliasing=no)
  323: CFLAGS="$CFLAGS_1"
  324: AC_MSG_RESULT($ac_nostrictaliasing)
  325: 
  326: # Try if GCC understands -fno-crossjumping
  327: AC_MSG_CHECKING([if $CC understands -fno-crossjumping])
  328: CFLAGS_1="$CFLAGS"
  329: CFLAGS="$CFLAGS -fno-crossjumping"
  330: AC_TRY_COMPILE(,,ac_nocrossjumping=yes;ENGINE_FLAGS="$ENGINE_FLAGS -fno-crossjumping",ac_nocrossjumping=no)
  331: CFLAGS="$CFLAGS_1"
  332: AC_MSG_RESULT($ac_nocrossjumping)
  333: 
  334: # Try if GCC understands __attribute__((unused))
  335: AC_MSG_CHECKING([how to suppress 'unused variable' warnings])
  336: AC_TRY_COMPILE(,[int __attribute__((unused)) foo;], MAYBE_UNUSED='__attribute__((unused))',)
  337: AC_DEFINE_UNQUOTED(MAYBE_UNUSED,$MAYBE_UNUSED,[attribute for possibly unused variables])
  338: AC_MSG_RESULT($MAYBE_UNUSED)
  339: 
  340: AC_CHECK_PROG(asm_fs,asm.fs,arch/$machine/asm.fs,,$srcdir/arch/$machine)
  341: AC_SUBST(asm_fs)
  342: 
  343: AC_CHECK_PROG(disasm_fs,disasm.fs,arch/$machine/disasm.fs,,$srcdir/arch/$machine)
  344: AC_SUBST(disasm_fs)
  345: 
  346: AC_PATH_PROG(INSTALL_INFO,install-info,[echo '>>>>Please make info dir entry:'],$PATH:/sbin:/usr/sbin:/usr/local/sbin)
  347: 
  348: case "$host_os" in
  349: 	*win32|cygwin)
  350: 		DIRSEP="\\\\"
  351: 		PATHSEP=";"
  352: 		;;
  353: 	*darwin*)
  354: 		#Darwin uses some funny preprocessor by default; eliminate it:
  355: 		AC_MSG_NOTICE([using -no-cpp-precomp on Darwin])
  356: 		CFLAGS="$CFLAGS -no-cpp-precomp"
  357: 		DIRSEP="/"
  358: 		PATHSEP=":"
  359: 		;;
  360: 	*)
  361: 		DIRSEP="/"
  362: 		PATHSEP=":"
  363: 		;;
  364: esac
  365: AC_SUBST(DIRSEP)
  366: AC_DEFINE_UNQUOTED(DIRSEP,'$DIRSEP',[a directory separator character])
  367: AC_SUBST(PATHSEP)
  368: AC_DEFINE_UNQUOTED(PATHSEP,'$PATHSEP',[a path separator character])
  369: 
  370: 
  371: dnl Now a little support for DOS/DJGCC
  372: AC_SUBST(GFORTH_EXE)
  373: GFORTH_EXE=""
  374: AC_SUBST(GFORTHFAST_EXE)
  375: GFORTHFAST_EXE=""
  376: AC_SUBST(GFORTHITC_EXE)
  377: GFORTHITC_EXE=""
  378: AC_SUBST(GFORTHDITC_EXE)
  379: GFORTHDITC_EXE=""
  380: 
  381: AC_SUBST(FORTHSIZES)
  382: 
  383: dnl if test "$PEEPHOLE" = "yes"
  384: dnl then
  385: dnl    PEEPHOLEFLAG="true"
  386: dnl    AC_DEFINE(HAS_PEEPHOLE,,[Define if you want to use peephole optimization])
  387: dnl else
  388: dnl    PEEPHOLEFLAG="false"
  389: dnl fi
  390: PEEPHOLEFLAG="true"
  391: AC_SUBST(PEEPHOLEFLAG)
  392: 
  393: dnl copy commands for systems that don't have links
  394: AC_SUBST(LINK_KERNL)
  395: LINK_KERNL=""
  396: 
  397: #if test $host_os=dos
  398: #then
  399: #  echo Configuring for DOS!!!
  400: #  MAKE_EXE="coff2exe gforth"
  401: #  LINK_KERNL='$(CP) kernl32l.fi kernel.fi'
  402: #fi
  403: 
  404: dnl the following macro produces a warning with autoconf-2.1
  405: AC_C_BIGENDIAN
  406: AC_SUBST(KERNEL)
  407: dnl ac_cv_c_bigendian is an undocumented variable of autoconf-2.1
  408: if test $ac_cv_c_bigendian = yes; then
  409:   bytesex=b
  410:   KERNEL="kernl16b.fi kernl16l.fi kernl32b.fi kernl32l.fi kernl64b.fi kernl64l.fi"
  411: else
  412:   bytesex=l
  413:   KERNEL="kernl16l.fi kernl16b.fi kernl32l.fi kernl32b.fi kernl64l.fi kernl64b.fi"
  414: fi
  415: 
  416: #check how to do asm(".skip 16")
  417: AC_MSG_CHECKING([if and how we can waste code space])
  418: skipcode=no
  419: for i in ".skip 16" ".block 16" ".org .+16" ".=.+16" ".space 16"
  420: do
  421: 	AC_TRY_RUN(
  422: int foo(int);
  423: main()
  424: {
  425:   exit(foo(0)!=16);
  426: }
  427: int foo(int x)
  428: {
  429:   if (x) {
  430:   label1:
  431:     asm("$i");
  432:   label2:
  433:   }
  434:   return (&&label2)-(&&label1);
  435: }
  436: 	,skipcode=$i; break
  437: 	,,)
  438: done	
  439: AC_MSG_RESULT($skipcode)
  440: if test "$skipcode" = no
  441: then 
  442:     no_dynamic_default=1
  443:     AC_DEFINE_UNQUOTED(SKIP16,((void)0),statement for skipping 16 bytes)
  444:     AC_MSG_WARN(Disabling dynamic native code generation by default (speed penalty factor ~2))
  445: else
  446:     AC_DEFINE_UNQUOTED(SKIP16,asm("$skipcode"),statement for skipping 16 bytes)
  447: fi
  448: 
  449: AC_DEFINE_UNQUOTED(NO_DYNAMIC_DEFAULT,$no_dynamic_default,default value for no_dynamic)
  450: 
  451: dnl Checks for programs.
  452: AC_PROG_LN_S
  453: AC_PROG_INSTALL
  454: 
  455: dnl Checks for library functions
  456: dnl This check is just for making later checks link with libm.
  457: dnl using sin here is no good idea since it is built-into gcc and typechecked
  458: AC_CHECK_LIB(m,asin)
  459: AC_CHECK_LIB(dl,dlopen)
  460: dnl check for ffcall libraries
  461: dnl unfortunately, these four calls are separated out into a library each.
  462: AC_CHECK_LIB(avcall,__builtin_avcall)
  463: AC_CHECK_LIB(callback,__vacall_r)
  464: AC_CHECK_LIB(vacall,vacall)
  465: AC_CHECK_LIB(trampoline,alloc_trampoline)
  466: FFCALLFLAG="false"
  467: OLDCALLFLAG="true"
  468: test $ac_cv_lib_avcall___builtin_avcall = yes && FFCALLFLAG="true" && OLDCALLFLAG="false" && AC_DEFINE(HAS_FFCALL,,[define this if you want to use the ffcall libraries])
  469: test $ac_cv_lib_avcall___builtin_avcall = no && AC_DEFINE(HAS_OLDCALL,,[define this if you want to use the old call libraries])
  470: AC_SUBST(FFCALLFLAG)
  471: AC_SUBST(OLDCALLFLAG)
  472: if test "$host_os" != "nextstep3"
  473: then
  474: 	AC_FUNC_MEMCMP
  475: fi
  476: AC_REPLACE_FUNCS(memmove strtoul pow10 strerror strsignal atanh)
  477: AC_FUNC_FSEEKO
  478: AC_CHECK_FUNCS(ftello dlopen sys_siglist getrusage)
  479: AC_CHECK_TYPES(stack_t,,,[#include <signal.h>])
  480: AC_DECL_SYS_SIGLIST
  481: AC_CHECK_FUNC(getopt_long,true,AC_LIBOBJ(getopt); AC_LIBOBJ(getopt1))
  482: AC_CHECK_FUNCS(expm1 log1p)
  483: AC_REPLACE_FUNCS(rint ecvt)
  484: dnl No check for select, because our replacement is no good under
  485: dnl anything but DOS
  486: AC_CHECK_HEADERS(sys/mman.h fnmatch.h)
  487: AC_FUNC_FNMATCH
  488: test $ac_cv_func_fnmatch_works = yes || AC_LIBOBJ(fnmatch)
  489: AC_CHECK_FUNCS(mmap sysconf getpagesize)
  490: AM_PATH_LISPDIR
  491: 
  492: kernel_fi=kernl${wordsize}${bytesex}.fi
  493: AC_SUBST(kernel_fi)
  494: 
  495: #this breaks bindists
  496: #dnl replace srource directory by absolute value
  497: #if test $srcdir = "."; then srcdir=`pwd` 
  498: #fi
  499: 
  500: AC_SUBST(machine)
  501: AC_CONFIG_FILES([
  502: Makefile
  503: Makedist
  504: gforthmi
  505: vmgen
  506: machpc.fs
  507: engine/Makefile
  508: doc/version.texi ])
  509: AC_CONFIG_COMMANDS([stamp-h],[[echo timestamp > stamp-h
  510: chmod +x gforthmi
  511: chmod +x vmgen
  512: test -d kernel||mkdir kernel]],[[]])
  513: AC_OUTPUT
  514: 

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>