1: \ Compare nonrelocatable images and produce a relocatable image
2:
3: \ Copyright (C) 1996,1997,1998,2002 Free Software Foundation, Inc.
4:
5: \ This file is part of Gforth.
6:
7: \ Gforth is free software; you can redistribute it and/or
8: \ modify it under the terms of the GNU General Public License
9: \ as published by the Free Software Foundation; either version 2
10: \ of the License, or (at your option) any later version.
11:
12: \ This program is distributed in the hope that it will be useful,
13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15: \ GNU General Public License for more details.
16:
17: \ You should have received a copy of the GNU General Public License
18: \ along with this program; if not, write to the Free Software
19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
20:
21: s" address-unit-bits" environment? drop constant bits/au
22: 6 constant dodoes-tag
23:
24: : write-cell { w^ w file-id -- ior }
25: \ write a cell to the file
26: w cell file-id write-file ;
27:
28: : th ( addr1 n -- addr2 )
29: cells + ;
30:
31: : bset ( bmask c-addr -- )
32: tuck c@ or swap c! ;
33:
34: : set-bit { u addr -- }
35: \ set bit u in bit-vector addr
36: u bits/au /mod
37: >r 1 bits/au 1- rot - lshift
38: r> addr + bset ;
39:
40: : image-data { image1 image2 i-field expected-offset -- base offset }
41: image1 i-field + @ image2 i-field + @ over - { base offset }
42: offset 0=
43: if
44: ." : images have the same base address; producing only a data-relocatable image" cr
45: else
46: offset abs expected-offset <> abort" images produced by different engines"
47: ." offset=" offset . cr
48: 0 image1 i-field + ! 0 image2 i-field + !
49: endif
50: base offset ;
51:
52: : >tag ( index -- tag )
53: dup dodoes-tag 2 + > IF
54: $21 1 DO dup tag-offsets I cells + @ < IF
55: tag-offsets I 1- cells + @ - I 1- 9 lshift + negate
56: UNLOOP EXIT THEN LOOP
57: THEN -2 swap - ;
58:
59: : compare-images { image1 image2 reloc-bits size file-id -- }
60: \G compares image1 and image2 (of size cells) and sets reloc-bits.
61: \G offset is the difference for relocated addresses
62: \ this definition is certainly to long and too complex, but is
63: \ hard to factor.
64: image1 @ image2 @ over - { dbase doffset }
65: doffset 0= abort" images have the same dictionary base address"
66: ." data offset=" doffset . cr
67: ." code" image1 image2 cell 26 cells image-data { cbase coffset }
68: ." xt" image1 image2 11 cells 22 cells image-data { xbase xoffset }
69: size 0
70: u+do
71: image1 i th @ image2 i th @ { cell1 cell2 }
72: cell1 doffset + cell2 =
73: if
74: cell1 dbase - file-id write-cell throw
75: i reloc-bits set-bit
76: else
77: coffset 0<> cell1 coffset + cell2 = and
78: if
79: cell1 cbase - cell / { tag }
80: tag dodoes-tag =
81: if
82: \ make sure that the next cell will not be tagged
83: \ !! can probably be optimized away with hybrid threading
84: dbase negate image1 i 1+ th +!
85: dbase doffset + negate image2 i 1+ th +!
86: endif
87: tag >tag $4000 xor file-id write-cell throw
88: i reloc-bits set-bit
89: else
90: xoffset 0<> cell1 xoffset + cell2 = and
91: if
92: cell1 xbase - cell / { tag }
93: tag dodoes-tag =
94: if
95: \ make sure that the next cell will not be tagged
96: \ !! can probably be optimized away with hybrid threading
97: dbase negate image1 i 1+ th +!
98: dbase doffset + negate image2 i 1+ th +!
99: endif
100: tag >tag file-id write-cell throw
101: i reloc-bits set-bit
102: else
103: cell1 file-id write-cell throw
104: cell1 cell2 <>
105: if
106: 0 i th 9 u.r cell1 17 u.r cell2 17 u.r cr
107: endif
108: endif
109: endif
110: endif
111: loop ;
112:
113: : comp-image ( "image-file1" "image-file2" "new-image" -- )
114: name slurp-file { image1 size1 }
115: image1 size1 s" Gforth3" search 0= abort" not a Gforth image"
116: drop 8 + image1 - { header-offset }
117: size1 aligned size1 <> abort" unaligned image size"
118: image1 header-offset + 2 cells + @ header-offset + size1 <> abort" header gives wrong size"
119: name slurp-file { image2 size2 }
120: size1 size2 <> abort" image sizes differ"
121: name ( "new-image" ) w/o bin create-file throw { outfile }
122: size1 header-offset - 1- cell / bits/au / 1+ { reloc-size }
123: reloc-size allocate throw { reloc-bits }
124: reloc-bits reloc-size erase
125: image1 header-offset outfile write-file throw
126: base @ hex
127: image1 header-offset + image2 header-offset + reloc-bits
128: size1 header-offset - aligned cell / outfile compare-images
129: base !
130: reloc-bits reloc-size outfile write-file throw
131: outfile close-file throw ;
132:
133:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>