File:  [gforth] / gforth / blocks.fs
Revision 1.7: download - view: text, annotated - select for diffs
Tue Nov 7 18:06:32 1995 UTC (23 years, 8 months ago) by anton
Branches: MAIN
CVS tags: gforth-0_1beta, HEAD
added copyright headers
changes to loadfilename & co. to make savesystem transparent to
 assertions and ~~

    1: \ A less simple implementation of the blocks wordset. 
    2: 
    3: \ Copyright (C) 1995 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation; either version 2
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program; if not, write to the Free Software
   19: \ Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
   20: 
   21: 
   22: \ A more efficient implementation would use mmap on OSs that
   23: \ provide it and many buffers on OSs that do not provide mmap.
   24: 
   25: \ Now, the replacement algorithm is "direct mapped"; change to LRU
   26: \ if too slow. Using more buffers helps, too.
   27: 
   28: \ I think I avoid the assumption 1 char = 1 here, but I have not tested this
   29: 
   30: \ 1024 constant chars/block \ mandated by the standard
   31: 
   32: require struct.fs
   33: 
   34: struct
   35:     1           cells: field buffer-block   \ the block number
   36:     1           cells: field buffer-fid     \ the block's fid
   37:     1           cells: field buffer-dirty   \ the block dirty flag
   38:     chars/block chars: field block-buffer   \ the data
   39:     0           cells: field next-buffer
   40: end-struct buffer-struct
   41: 
   42: Variable block-buffers
   43: Variable last-block
   44: 
   45: $20 Value buffers
   46: 
   47: User block-fid
   48: 
   49: : block-cold
   50:     defers 'cold  block-fid off  last-block off
   51:     buffers buffer-struct drop * allocate throw dup block-buffers !
   52:     buffers buffer-struct drop * erase ;
   53: 
   54: ' block-cold IS 'cold
   55: 
   56: block-cold
   57: 
   58: Defer flush-file
   59: 
   60: : use-file ( addr u -- )
   61:     2dup r/w bin open-file 0<>
   62:     if
   63: 	drop r/w bin create-file throw
   64:     else
   65: 	nip nip
   66:     then
   67:     block-fid @ IF  flush-file block-fid @ close-file throw  THEN
   68:     block-fid ! ;
   69: 
   70: \ the file is opened as binary file, since it either will contain text
   71: \ without newlines or binary data
   72: : get-block-fid ( -- fid )
   73:     block-fid @ 0=
   74:     if
   75: 	s" blocks.fb" use-file
   76:     then
   77:     block-fid @ ;
   78: 
   79: : block-position ( u -- )
   80:     \ positions the block file to the start of block u
   81:     1- chars/block chars um* get-block-fid reposition-file throw ;
   82: 
   83: : update ( -- )
   84:     last-block @ ?dup IF  buffer-dirty on  THEN ;
   85: 
   86: : save-buffer ( buffer -- ) >r
   87:     r@ buffer-dirty @ r@ buffer-block @ 0<> and
   88:     if
   89: 	r@ buffer-block @ block-position
   90: 	r@ block-buffer chars/block  r@ buffer-fid @  write-file throw
   91: 	r@ buffer-dirty off
   92:     endif
   93:     rdrop ;
   94: 
   95: : empty-buffer ( buffer -- )
   96:     buffer-block off ;
   97: 
   98: : save-buffers  ( -- )    block-buffers @
   99:     buffers 0 ?DO  dup save-buffer  next-buffer  LOOP  drop ;
  100: 
  101: : empty-buffers ( -- )    block-buffers @
  102:     buffers 0 ?DO  dup empty-buffer  next-buffer  LOOP  drop ;
  103: 
  104: : flush ( -- )
  105:     save-buffers
  106:     empty-buffers ;
  107: 
  108: ' flush IS flush-file
  109: 
  110: : get-buffer ( n -- a-addr )
  111:     buffers mod buffer-struct drop * block-buffers @ + ;
  112: 
  113: : block ( u -- a-addr )
  114:     dup 0= -35 and throw
  115:     dup get-buffer >r
  116:     dup r@ buffer-block @ <>
  117:     r@ buffer-fid @ block-fid @ <> and
  118:     if
  119: 	r@ save-buffer
  120: 	dup block-position
  121: 	r@ block-buffer chars/block get-block-fid read-file throw
  122: 	\ clear the rest of the buffer if the file is too short
  123: 	r@ block-buffer over chars + chars/block rot chars - blank
  124: 	r@ buffer-block !
  125: 	get-block-fid r@ buffer-fid !
  126:     else
  127: 	drop
  128:     then
  129:     r> dup last-block ! block-buffer ;
  130: 
  131: : buffer ( u -- a-addr )
  132:     \ reading in the block is unnecessary, but simpler
  133:     block ;
  134: 
  135: User scr 0 scr !
  136: 
  137: : updated?  ( n -- f )   scr @ buffer
  138:     [ 0 buffer-dirty 0 block-buffer - ] Literal + @ ;
  139: 
  140: : list ( u -- )
  141:     \ calling block again and again looks inefficient but is necessary
  142:     \ in a multitasking environment
  143:     dup scr !
  144:     ." Screen " u.
  145:     updated?  0= IF ." not "  THEN  ." modified     " cr
  146:     16 0
  147:     ?do
  148: 	i 2 .r space scr @ block i 64 * chars + 64 type cr
  149:     loop ;
  150: 
  151: : (source)  ( -- addr len )
  152:   blk @ ?dup
  153:   IF    block chars/block
  154:   ELSE  tib #tib @
  155:   THEN ;
  156: 
  157: ' (source) IS source
  158: 
  159: : load ( i*x n -- j*x )
  160:   push-file
  161:   dup loadline ! blk ! >in off ( ['] ) interpret ( catch )
  162:   pop-file ( throw ) ;
  163: 
  164: : thru ( i*x n1 n2 -- j*x )
  165:   1+ swap 0 ?DO  I load  LOOP ;
  166: 
  167: : +load ( i*x n -- j*x )  blk @ + load ;
  168: 
  169: : +thru ( i*x n1 n2 -- j*x )
  170:   1+ swap 0 ?DO  I +load  LOOP ;
  171: 
  172: : --> ( -- )  refill drop ; immediate
  173: 
  174: : block-included ( addr u -- )
  175:     block-fid @ >r block-fid off use-file
  176:     1 load block-fid @ close-file throw flush
  177:     r> block-fid ! ;
  178: 
  179: : include ( "name" -- )
  180:     name 2dup dup 3 - /string s" .fb" compare
  181:     0= IF  block-included  ELSE  included  THEN ;
  182: 
  183: get-current environment-wordlist set-current
  184: true constant block
  185: true constant block-ext
  186: set-current
  187: 
  188: : bye  ['] flush catch drop bye ;

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>