File:  [gforth] / gforth / blocks.fs
Revision 1.44: download - view: text, annotated - select for diffs
Sun Oct 8 11:30:55 2006 UTC (12 years, 9 months ago) by pazsan
Branches: MAIN
CVS tags: HEAD
Renamed THROW>ERROR to RETHROW

    1: \ A less simple implementation of the blocks wordset. 
    2: 
    3: \ Copyright (C) 1995,1996,1997,1998,2000,2003 Free Software Foundation, Inc.
    4: 
    5: \ This file is part of Gforth.
    6: 
    7: \ Gforth is free software; you can redistribute it and/or
    8: \ modify it under the terms of the GNU General Public License
    9: \ as published by the Free Software Foundation; either version 2
   10: \ of the License, or (at your option) any later version.
   11: 
   12: \ This program is distributed in the hope that it will be useful,
   13: \ but WITHOUT ANY WARRANTY; without even the implied warranty of
   14: \ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   15: \ GNU General Public License for more details.
   16: 
   17: \ You should have received a copy of the GNU General Public License
   18: \ along with this program; if not, write to the Free Software
   19: \ Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111, USA.
   20: 
   21: 
   22: \ A more efficient implementation would use mmap on OSs that
   23: \ provide it and many buffers on OSs that do not provide mmap.
   24: 
   25: \ Now, the replacement algorithm is "direct mapped"; change to LRU
   26: \ if too slow. Using more buffers helps, too.
   27: 
   28: \ I think I avoid the assumption 1 char = 1 here, but I have not tested this
   29: 
   30: \ 1024 constant chars/block \ mandated by the standard
   31: 
   32: require struct.fs
   33: 
   34: struct
   35:     cell%		field buffer-block   \ the block number
   36:     cell%		field buffer-fid     \ the block's fid
   37:     cell%		field buffer-dirty   \ the block dirty flag
   38:     char% chars/block * field block-buffer   \ the data
   39:     cell% 0 *		field next-buffer
   40: end-struct buffer-struct
   41: 
   42: Variable block-buffers
   43: Variable last-block
   44: 
   45: $20 Value buffers
   46: 
   47: \ limit block files to 2GB; gforth <0.6.0 erases larger block files on
   48: \ 32-bit systems
   49: $200000 Value block-limit
   50: 
   51: User block-fid
   52: User block-offset ( -- addr ) \ gforth
   53: \G User variable containing the number of the first block (default
   54: \G since 0.5.0: 0).  Block files created with Gforth versions before
   55: \G 0.5.0 have the offset 1.  If you use these files you can: @code{1
   56: \G offset !}; or add 1 to every block number used; or prepend 1024
   57: \G characters to the file.
   58: 0 block-offset !  \ store 1 here fore 0.4.0 compatibility
   59: 
   60: ' block-offset alias offset \ !! eliminate this?
   61: 
   62: : block-cold ( -- )
   63:     block-fid off  last-block off
   64:     buffer-struct buffers * %alloc dup block-buffers ! ( addr )
   65:     buffer-struct %size buffers * erase ;
   66: 
   67: :noname ( -- )
   68:     defers 'cold
   69:     block-cold
   70: ; is 'cold
   71: 
   72: block-cold
   73: 
   74: Defer flush-blocks ( -- ) \ gforth
   75: 
   76: : open-blocks ( c-addr u -- ) \ gforth
   77: \g Use the file, whose name is given by @i{c-addr u}, as the blocks file.
   78:     try ( c-addr u )
   79: 	2dup open-fpath-file throw
   80: 	rot close-file throw  2dup file-status throw bin open-file throw
   81: 	>r 2drop r>
   82:     recover ( c-addr u ior )
   83: 	>r 2dup file-status nip 0= r> and throw \ does it really not exist?
   84: 	r/w bin create-file throw
   85:     endtry
   86:     block-fid @ IF
   87: 	flush-blocks block-fid @ close-file throw
   88:     THEN
   89:     block-fid ! ;
   90: 
   91: : use ( "file" -- ) \ gforth
   92:     \g Use @i{file} as the blocks file.
   93:     name open-blocks ;
   94: 
   95: \ the file is opened as binary file, since it either will contain text
   96: \ without newlines or binary data
   97: : get-block-fid ( -- wfileid ) \ gforth
   98:     \G Return the file-id of the current blocks file. If no blocks
   99:     \G file has been opened, use @file{blocks.fb} as the default
  100:     \G blocks file.
  101:     block-fid @ 0=
  102:     if
  103: 	s" blocks.fb" open-blocks
  104:     then
  105:     block-fid @ ;
  106: 
  107: : block-position ( u -- ) \ block
  108: \G Position the block file to the start of block @i{u}.
  109:     dup block-limit u>= -35 and throw
  110:     offset @ - chars/block chars um* get-block-fid reposition-file throw ;
  111: 
  112: : update ( -- ) \ block
  113:     \G Mark the state of the current block buffer as assigned-dirty.
  114:     last-block @ ?dup IF  buffer-dirty on  THEN ;
  115: 
  116: : save-buffer ( buffer -- ) \ gforth
  117:     >r
  118:     r@ buffer-dirty @
  119:     if
  120: 	r@ buffer-block @ block-position
  121: 	r@ block-buffer chars/block  r@ buffer-fid @  write-file throw
  122: 	r@ buffer-fid @ flush-file throw
  123: 	r@ buffer-dirty off 
  124:     endif
  125:     rdrop ;
  126: 
  127: : empty-buffer ( buffer -- ) \ gforth
  128:     buffer-block off ;
  129: 
  130: : save-buffers  ( -- ) \ block
  131:     \G Transfer the contents of each @code{update}d block buffer to
  132:     \G mass storage, then mark all block buffers as assigned-clean.
  133:     block-buffers @
  134:     buffers 0 ?DO dup save-buffer next-buffer LOOP drop ;
  135: 
  136: : empty-buffers ( -- ) \ block-ext
  137:     \G Mark all block buffers as unassigned; if any had been marked as
  138:     \G assigned-dirty (by @code{update}), the changes to those blocks
  139:     \G will be lost.
  140:     block-buffers @
  141:     buffers 0 ?DO dup empty-buffer next-buffer LOOP drop ;
  142: 
  143: : flush ( -- ) \ block
  144:     \G Perform the functions of @code{save-buffers} then
  145:     \G @code{empty-buffers}.
  146:     save-buffers
  147:     empty-buffers ;
  148: 
  149: ' flush IS flush-blocks
  150: 
  151: : get-buffer ( u -- a-addr ) \ gforth
  152:     0 buffers um/mod drop buffer-struct %size * block-buffers @ + ;
  153: 
  154: : block ( u -- a-addr ) \ gforthman- block
  155:     \G If a block buffer is assigned for block @i{u}, return its
  156:     \G start address, @i{a-addr}. Otherwise, assign a block buffer
  157:     \G for block @i{u} (if the assigned block buffer has been
  158:     \G @code{update}d, transfer the contents to mass storage), read
  159:     \G the block into the block buffer and return its start address,
  160:     \G @i{a-addr}.
  161:     dup offset @ u< -35 and throw
  162:     dup get-buffer >r
  163:     dup r@ buffer-block @ <>
  164:     r@ buffer-fid @ block-fid @ <> or
  165:     if
  166: 	r@ save-buffer
  167: 	dup block-position
  168: 	r@ block-buffer chars/block get-block-fid read-file throw
  169: 	\ clear the rest of the buffer if the file is too short
  170: 	r@ block-buffer over chars + chars/block rot chars - blank
  171: 	r@ buffer-block !
  172: 	get-block-fid r@ buffer-fid !
  173:     else
  174: 	drop
  175:     then
  176:     r> dup last-block ! block-buffer ;
  177: 
  178: : buffer ( u -- a-addr ) \ block
  179:     \G If a block buffer is assigned for block @i{u}, return its
  180:     \G start address, @i{a-addr}. Otherwise, assign a block buffer
  181:     \G for block @i{u} (if the assigned block buffer has been
  182:     \G @code{update}d, transfer the contents to mass storage) and
  183:     \G return its start address, @i{a-addr}.  The subtle difference
  184:     \G between @code{buffer} and @code{block} mean that you should
  185:     \G only use @code{buffer} if you don't care about the previous
  186:     \G contents of block @i{u}. In Gforth, this simply calls
  187:     \G @code{block}.
  188:     \ reading in the block is unnecessary, but simpler
  189:     block ;
  190: 
  191: User scr ( -- a-addr ) \ block-ext s-c-r
  192:     \G @code{User} variable -- @i{a-addr} is the address of a cell containing
  193:     \G the block number of the block most recently processed by
  194:     \G @code{list}.
  195: 0 scr !
  196: 
  197: \ nac31Mar1999 moved "scr @" to list to make the stack comment correct
  198: : updated?  ( n -- f ) \ gforth
  199:     \G Return true if @code{updated} has been used to mark block @i{n}
  200:     \G as assigned-dirty.
  201:     buffer
  202:     [ 0 buffer-dirty 0 block-buffer - ] Literal + @ ;
  203: 
  204: : list ( u -- ) \ block-ext
  205:     \G Display block @i{u}. In Gforth, the block is displayed as 16
  206:     \G numbered lines, each of 64 characters.
  207:     \ calling block again and again looks inefficient but is necessary
  208:     \ in a multitasking environment
  209:     dup scr !
  210:     ." Screen " u.
  211:     scr @ updated?  0= IF ." not "  THEN  ." modified     " cr
  212:     16 0
  213:     ?do
  214: 	i 2 .r space scr @ block i 64 * chars + 64 type cr
  215:     loop ;
  216: 
  217: [IFDEF] current-input
  218: :noname  2 <> -12 and throw >in ! blk ! ;
  219:                               \ restore-input
  220: :noname  blk @ >in @ 2 ;      \ save-input
  221: :noname  2 ;                  \ source-id "*a block*"
  222: :noname  1 blk +! 1 loadline +! >in off true ;      \ refill
  223: :noname  blk @ block chars/block ;  \ source
  224: 
  225: Create block-input   A, A, A, A, A,
  226: 
  227: : load  ( i*x n -- j*x ) \ block
  228:     \G Save the current input source specification. Store @i{n} in
  229:     \G @code{BLK}, set @code{>IN} to 0 and interpret. When the parse
  230:     \G area is exhausted, restore the input source specification.
  231:     block-input 0 new-tib dup loadline ! blk !  s" * a block*" loadfilename 2!
  232:     ['] interpret catch pop-file rethrow ;
  233: [ELSE]
  234: : (source)  ( -- c-addr u )
  235:   blk @ ?dup
  236:   IF    block chars/block
  237:   ELSE  tib #tib @
  238:   THEN ;
  239: 
  240: ' (source) IS source ( -- c-addr u ) \ core
  241: \G @i{c-addr} is the address of the input buffer and @i{u} is the
  242: \G number of characters in it.
  243: 
  244: : load ( i*x n -- j*x ) \ block
  245:     \G Save the current input source specification. Store @i{n} in
  246:     \G @code{BLK}, set @code{>IN} to 0 and interpret. When the parse
  247:     \G area is exhausted, restore the input source specification.
  248:     s" * a block*" loadfilename>r
  249:     push-file
  250:     dup loadline ! blk ! >in off ['] interpret catch
  251:     pop-file
  252:     r>loadfilename
  253:     rethrow ;
  254: [THEN]
  255: 
  256: : thru ( i*x n1 n2 -- j*x ) \ block-ext
  257:     \G @code{load} the blocks @i{n1} through @i{n2} in sequence.
  258:     1+ swap ?DO  I load  LOOP ;
  259: 
  260: : +load ( i*x n -- j*x ) \ gforth
  261:     \G Used within a block to load the block specified as the
  262:     \G current block + @i{n}.
  263:     blk @ + load ;
  264: 
  265: : +thru ( i*x n1 n2 -- j*x ) \ gforth
  266:     \G Used within a block to load the range of blocks specified as the
  267:     \G current block + @i{n1} thru the current block + @i{n2}.
  268:     1+ swap ?DO  I +load  LOOP ;
  269: 
  270: : --> ( -- ) \ gforthman- gforth chain
  271:     \G If this symbol is encountered whilst loading block @i{n},
  272:     \G discard the remainder of the block and load block @i{n+1}. Used
  273:     \G for chaining multiple blocks together as a single loadable
  274:     \G unit.  Not recommended, because it destroys the independence of
  275:     \G loading.  Use @code{thru} (which is standard) or @code{+thru}
  276:     \G instead.
  277:     refill drop ; immediate
  278: 
  279: : block-included ( a-addr u -- ) \ gforth
  280:     \G Use within a block that is to be processed by @code{load}. Save
  281:     \G the current blocks file specification, open the blocks file
  282:     \G specified by @i{a-addr u} and @code{load} block 1 from that
  283:     \G file (which may in turn chain or load other blocks). Finally,
  284:     \G close the blocks file and restore the original blocks file.
  285:     block-fid @ >r block-fid off open-blocks
  286:     1 load block-fid @ close-file throw flush
  287:     r> block-fid ! ;
  288: 
  289: \ thrown out because it may provide unpleasant surprises - anton
  290: \ : include ( "name" -- )
  291: \     name 2dup dup 3 - /string s" .fb" compare
  292: \     0= IF  block-included  ELSE  included  THEN ;
  293: 
  294: get-current environment-wordlist set-current
  295: true constant block
  296: true constant block-ext
  297: set-current
  298: 
  299: : bye ( -- ) \ tools-ext
  300:   \G Return control to the host operating system (if any).
  301:   ['] flush catch drop bye ;

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>